blob: 7716c903c5143f7938e689b38cb0865ac2b436b8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools
DESCRIPTION="The HTML5 parsing algorithm implemented as a pure C99 library"
HOMEPAGE="https://codeberg.org/grisha/gumbo-parser"
SRC_URI="https://codeberg.org/grisha/gumbo-parser/archive/${PV}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/gumbo-parser"
LICENSE="Apache-2.0"
SLOT="0/2" # gumbo SONAME
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~ppc-macos ~x64-macos ~x64-solaris"
IUSE="doc test"
RESTRICT="!test? ( test )"
DEPEND="test? ( dev-cpp/gtest )"
BDEPEND="doc? ( app-text/doxygen )"
src_prepare() {
default
eautoreconf
}
src_compile() {
default
if use doc; then
doxygen || die "doxygen failed"
HTML_DOCS=( docs/html/. )
fi
}
src_install() {
default
use doc && doman docs/man/man3/*
find "${ED}" -name '*.la' -delete || die
}
|
