blob: 513ad11b1401a2f52a94546cc420c5740f5a3f59 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit flag-o-matic toolchain-funcs
DESCRIPTION="MASM-compatible TASM-similar assembler (fork of Wasm)"
HOMEPAGE="https://github.com/Baron-von-Riedesel/JWasm"
SRC_URI="https://github.com/Baron-von-Riedesel/JWasm/archive/v${PV}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/JWasm-${PV}"
LICENSE="Watcom-1.0"
SLOT="0"
KEYWORDS="amd64 ~x86"
PATCHES=(
"${FILESDIR}"/${PN}-2.18-types-test.patch
"${FILESDIR}"/${PN}-2.18-makefile-dep-fix.patch
"${FILESDIR}"/${PN}-2.18-missing-includes.patch #944893
)
src_prepare() {
default
# don't strip binary
sed -i GccUnix.mak -e 's/ -s / /g' || die
}
src_compile() {
# -std=c17 and -D_POSIX_C_SOURCE=200809L are both related to bug #944893
append-cflags -std=c17
emake -f GccUnix.mak CC="$(tc-getCC) ${CFLAGS} -D_POSIX_C_SOURCE=200809L ${LDFLAGS}"
}
src_install() {
dobin build/GccUnixR/jwasm
dodoc -r README.md History.txt Html/
}
|
