blob: 68a61542736b3a5f240c4c6685a2c3a5d146bc2e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
|
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit java-pkg-2 toolchain-funcs
DESCRIPTION="A language with a focus on simplicity, safety and correctness"
HOMEPAGE="https://fuzion-lang.dev/
https://github.com/tokiwa-software/fuzion/"
if [[ "${PV}" == *9999* ]] ; then
inherit git-r3
EGIT_REPO_URI="https://github.com/tokiwa-software/${PN}"
else
SRC_URI="https://github.com/tokiwa-software/${PN}/archive/refs/tags/v${PV}.tar.gz
-> ${P}.gh.tar.gz"
KEYWORDS="~amd64 ~x86"
fi
LICENSE="GPL-3"
SLOT="0"
IUSE="test"
RESTRICT="!test? ( test )"
RDEPEND="
>=virtual/jre-21:*
dev-libs/boehm-gc
"
DEPEND="
virtual/jdk:21
"
BDEPEND="
test? (
llvm-core/clang:*
)
"
PATCHES=( "${FILESDIR}/fuzion-0.092-Makefile.patch" )
DOCS=( README.md release_notes.md )
src_prepare() {
default #780585
java-pkg-2_src_prepare
# Remove bad tests.
local -a bad_tests=(
catch_postcondition
nom
onesCount
process
)
local bad_test=""
for bad_test in "${bad_tests[@]}" ; do
rm -r "${S}/tests/${bad_test}" \
|| die "failed to remove test ${bad_tests}"
done
rm -rf "${S}/tests/"{compile_,reg_issue,mod_,sockets}* || die
}
src_compile() {
emake -j1 CC="$(tc-getCC)" CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}"
}
src_test() {
emake -j1 run_tests_jvm
}
src_install() {
# Remove unnecessary files from build directory. bug #893450
local toremove=""
local toremove_path=""
for toremove in tests run_tests.{failures,results} ; do
toremove_path="${S}/build/${toremove}"
if [[ -e "${toremove_path}" ]] ; then
rm -r "${toremove_path}" \
|| die "failed to remove ${toremove_path}"
fi
done
insinto "/usr/share/${PN}"
doins -r build/.
insopts -m755
doins -r build/bin
local exe=""
for exe in fz fzjava ; do
dosym -r "/usr/share/${PN}/bin/${exe}" "/usr/bin/${exe}"
done
einstalldocs
}
|
