blob: cbd7e151297432b045c5067013ca40839501da13 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools flag-o-matic
MY_P="${P/_/-}"
MY_PV="${PV/_rc/-pre}"
DESCRIPTION="GNU Midnight Commander is a text based file manager"
HOMEPAGE="https://midnight-commander.org"
SRC_URI="https://github.com/MidnightCommander/mc/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/${PN}-${MY_PV}"
LICENSE="GPL-3"
SLOT="0"
IUSE="+edit gpm sftp +slang spell test unicode X"
REQUIRED_USE="spell? ( edit )"
RESTRICT="!test? ( test )"
DEPEND="
>=dev-libs/glib-2.30.0:2
gpm? ( sys-libs/gpm )
kernel_linux? ( sys-fs/e2fsprogs[tools(+)] )
sftp? ( net-libs/libssh2 )
slang? ( >=sys-libs/slang-2 )
!slang? ( sys-libs/ncurses:=[unicode(+)?] )
spell? ( app-text/aspell )
X? (
x11-libs/libX11
x11-libs/libICE
x11-libs/libXau
x11-libs/libXdmcp
x11-libs/libSM
)
"
RDEPEND="
${DEPEND}
spell? ( app-dicts/aspell-en )
"
# Force nls so xgettext is installed. Will revert this.
BDEPEND="
sys-devel/gettext
app-arch/xz-utils
virtual/pkgconfig
test? ( dev-libs/check )
"
PATCHES=(
"${FILESDIR}"/${PN}-4.8.26-ncurses-mouse.patch
"${FILESDIR}"/${PN}-4.8.29-gentoo-tools.patch
)
# This is a check for AIX, on Linux mc uses statvfs() regardless of whether
# LFS64 interfaces are available in libc or not.
QA_CONFIG_IMPL_DECL_SKIP=(
statvfs64
)
src_prepare() {
default
# Bug #906194, #922483
if use elibc_musl; then
eapply "${FILESDIR}"/${PN}-4.8.30-musl-tests.patch
eapply "${FILESDIR}"/${PN}-4.8.31-musl-tests.patch
fi
eautoreconf
# Copied from autogen.sh
xgettext --keyword=_ --keyword=N_ --keyword=Q_ --output=- \
`find . -name '*.[ch]'` | sed -ne '/^#:/{s/#://;s/:[0-9]*/\
/g;s/ //g;p;}' | \
grep -v '^$' | sort | uniq >po/POTFILES.in || die
}
src_configure() {
[[ ${CHOST} == *-solaris* ]] && append-ldflags "-lnsl -lsocket"
local myeconfargs=(
--enable-charset
--enable-vfs
--with-screen=$(usex slang 'slang' "ncurses$(usex unicode 'w' '')")
$(use_enable kernel_linux vfs-undelfs)
# Today mclib does not expose any headers and is linked to
# single 'mc' binary. Thus there is no advantage of having
# a library. Let's avoid shared library altogether
# as it also conflicts with sci-libs/mc: bug #685938
--disable-mclib
--enable-nls
$(use_enable sftp vfs-sftp)
$(use_enable spell aspell)
$(use_enable test tests)
$(use_with gpm gpm-mouse)
$(use_with X x)
$(use_with edit internal-edit)
)
econf "${myeconfargs[@]}"
}
src_test() {
# Bug #759466
if [[ ${EUID} == 0 ]] ; then
ewarn "You are emerging ${PN} as root with 'userpriv' disabled."
ewarn "Expect some test failures, or emerge with 'FEATURES=userpriv'!"
fi
# This test fails. Disable for now
# https://midnight-commander.org/ticket/4567
rm tests/src/vfs/extfs/helpers-list/data/iso9660.xorriso.* || die
# CK_FORK=no to avoid using fork() in check library
# as mc mocks fork() itself: bug #644462.
#
# VERBOSE=1 to make test failures contain detailed
# information.
CK_FORK=no emake check VERBOSE=1
}
src_install() {
emake DESTDIR="${D}" install
dodoc AUTHORS NEWS README
# fix bug #334383
if use kernel_linux && [[ ${EUID} == 0 ]] ; then
fowners root:tty /usr/libexec/mc/cons.saver
fperms g+s /usr/libexec/mc/cons.saver
fi
}
pkg_postinst() {
elog "${PN} extension scripts depend on many external tools, install them as needed"
elog
if use spell && ! has_version app-dicts/aspell-en ; then
elog "'spell' USE flag is enabled however app-dicts/aspell-en is not installed."
elog "You should manually set 'spell_language' in the Misc section of ~/.config/mc/ini"
elog "It has to be set to one of your installed aspell dictionaries or 'NONE'"
elog
fi
elog "To enable exiting to latest working directory,"
elog "put this into your ~/.bashrc:"
elog ". ${EPREFIX}/usr/libexec/mc/mc.sh"
}
|
