blob: 11287d6d76bf375b018a6eb032382dece5ca1bf6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{8..10} pypy3 )
DISTUTILS_SINGLE_IMPL=1
DISTUTILS_USE_SETUPTOOLS=rdepend
inherit distutils-r1
DESCRIPTION="app-emulation/winetricks wrapper for Proton (Steam Play) games"
HOMEPAGE="https://github.com/Matoking/protontricks"
SRC_URI="https://github.com/Matoking/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64"
IUSE="+gui"
RDEPEND="app-emulation/winetricks
$(python_gen_cond_dep '
dev-python/vdf[${PYTHON_USEDEP}]
')
gui? ( gnome-extra/zenity
|| (
app-emulation/winetricks[gtk]
app-emulation/winetricks[kde]
)
)"
PATCHES=(
"${FILESDIR}"/${PN}-1.5.0_no-setuptools-scm.patch
)
DOCS=( CHANGELOG.md README.md )
distutils_enable_tests pytest
python_prepare_all() {
distutils-r1_python_prepare_all
echo "version = '${PV}'" > "${S}"/src/${PN}/_version.py || die "Failed to generate the version file"
}
pkg_postinst() {
elog
if ! use gui; then
ewarn "Please note that disabling USE=gui does *not* presently remove the --gui command-line option,"
ewarn "it just means using this option will fail unless gnome-extra/zenity happens to be installed."
ewarn
fi
elog "Protontricks can only find games for which a Proton prefix already exists."
elog "Make sure to run a Proton game at least once before trying to use protontricks on it."
elog
}
|
