blob: 4424afdbdfdc2f5e2113ca8feee1c8d5015f8849 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit elisp
DESCRIPTION="Mode for editing (and running) Haskell programs in Emacs"
HOMEPAGE="https://haskell.github.io/haskell-mode/
https://www.haskell.org/haskellwiki/Emacs#Haskell-mode"
if [[ ${PV} == *9999* ]] ; then
inherit git-r3
EGIT_REPO_URI="https://github.com/haskell/${PN}.git"
else
[[ ${PV} == *_p20230616 ]] && COMMIT=41c0cf61591279a22ac511f925c041c40969bdb8
SRC_URI="https://github.com/haskell/${PN}/archive/${COMMIT}.tar.gz
-> ${P}.tar.gz"
S="${WORKDIR}"/${PN}-${COMMIT}
KEYWORDS="amd64 ppc ~sparc x86"
fi
LICENSE="GPL-3+ FDL-1.2+"
SLOT="0"
RESTRICT="test" # Tests fail.
BDEPEND="sys-apps/texinfo"
DOCS=( NEWS README.md )
ELISP_TEXINFO="doc/haskell-mode.texi"
SITEFILE="50${PN}-gentoo.el"
src_prepare() {
# We install the logo in SITEETC, not in SITELISP
# https://github.com/haskell/haskell-mode/issues/102
sed -i -e "/defconst haskell-process-logo/{n;" \
-e "s:(.*\"\\(.*\\)\".*):\"${SITEETC}/${PN}/\\1\":}" \
haskell-process.el || die
eapply_user
}
src_compile() {
elisp_src_compile
elisp-make-autoload-file haskell-site-file.el
}
src_test() {
emake check-ert
}
src_install() {
elisp_src_install
insinto "${SITEETC}"/${PN}
doins logo.svg
}
|