blob: 877601fbf5ebeff056490e4f078858017ce6981b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit toolchain-funcs
DESCRIPTION="PkZip cipher breaker"
HOMEPAGE="https://www.unix-ag.uni-kl.de/~conrad/krypto/pkcrack.html"
SRC_URI="https://www.unix-ag.uni-kl.de/~conrad/krypto/pkcrack/${P}.tar.gz"
LICENSE="pkcrack"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="test"
RESTRICT="!test? ( test )"
RDEPEND="!<app-text/html-xml-utils-5.3"
BDEPEND="test? ( app-arch/zip[crypt] )"
DOCS=(
doc/KNOWN_BUGS
doc/appnote.iz.txt
doc/README.W32
doc/pkzip.ps.gz
doc/CHANGES
doc/LIESMICH
doc/README.html
doc/README
)
PATCHES=(
"${FILESDIR}/${P}-build.patch"
"${FILESDIR}/${P}-gcc14-build.patch"
)
src_compile() {
cd src || die
emake CC="$(tc-getCC)" CFLAGS="${CFLAGS} ${LDFLAGS}" all
}
src_test() {
cd test || die
emake CC="$(tc-getCC)" CFLAGS="${CFLAGS} ${LDFLAGS}" all
}
src_install() {
einstalldocs
cd src || die
dobin pkcrack zipdecrypt findkey makekey
newbin extract "${PN}-extract"
}
pkg_postinst() {
ewarn "Due to file collision, extract utility was renamed to ${PN}-extract,"
ewarn "see bug#247394"
}
|