blob: d6371903efc2fd91ceaaa6d047ac598f96555d8a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{9..11} )
DISTUTILS_USE_PEP517=setuptools
inherit distutils-r1 bash-completion-r1
KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
inherit pypi
DESCRIPTION="Deduplicating backup program with compression and authenticated encryption"
HOMEPAGE="https://borgbackup.readthedocs.io/"
LICENSE="BSD"
SLOT="0"
# Unfortunately we have a file conflict with app-office/borg, bug #580402
# borgbackup is *very* picky about which msgpack it work with,
# check setup.py on bumps.
RDEPEND="
!!app-office/borg
dev-libs/xxhash
app-arch/lz4
app-arch/zstd
virtual/acl
dev-python/pyfuse3[${PYTHON_USEDEP}]
~dev-python/msgpack-1.0.5[${PYTHON_USEDEP}]
dev-libs/openssl:0=
"
DEPEND="
dev-python/setuptools-scm[${PYTHON_USEDEP}]
dev-python/packaging[${PYTHON_USEDEP}]
>=dev-python/cython-0.29.29[${PYTHON_USEDEP}]
dev-python/pkgconfig[${PYTHON_USEDEP}]
${RDEPEND}
"
BDEPEND=">=dev-python/cython-0.29.29[${PYTHON_USEDEP}]"
src_install() {
distutils-r1_src_install
doman docs/man/*
dobashcomp scripts/shell_completions/bash/borg
insinto /usr/share/zsh/site-functions
doins scripts/shell_completions/zsh/_borg
insinto /usr/share/fish/vendor_completions.d
doins scripts/shell_completions/fish/borg.fish
}
|
