10 files changed, 452 insertions, 39 deletions
diff --git a/sys-libs/Manifest.gz b/sys-libs/Manifest.gz
index f0ee859ac395..16195a295fee 100644
--- a/sys-libs/Manifest.gz
+++ b/sys-libs/Manifest.gz
diff --git a/sys-libs/ncurses-compat/Manifest b/sys-libs/ncurses-compat/Manifest
index 43759ea6db77..446733aca758 100644
--- a/sys-libs/ncurses-compat/Manifest
+++ b/sys-libs/ncurses-compat/Manifest
@@ -137,5 +137,5 @@ DIST ncurses-6.4.tar.gz.sig 438 BLAKE2B e6a78b8d0cbce1577205b49b0260394094632cef
 DIST ncurses-6.4_p20230408-patches.tar.xz 80472 BLAKE2B 0ba8156ebd4f1691fec7bc1b800ef39ce6a4210573c027dd437919cdcd7c995830116da06c69f31c65923845a4d5c88e974673fac38acce5813f7d6cdc646e3e SHA512 32960e2cc4cd9dc60c38b49f46c5ce2c02179479abb66ca29f63cd06475ae8e26299a78b5f06762d114aefbbca3ba6fbebe7093a58106eeaa40cf500d21633a4
 DIST ncurses-6.4_p20240330-patches.tar.xz 63796 BLAKE2B 3e6618ba0b37268d10a16cf26c2810e55c17ded97079af3753e34f2d12575f979a2e55cfd308abf783e35e39d4a848b89f435b4886d3633007ccb522b8dc2e51 SHA512 1bbf1978f9287f68bf6a8596f06d4d0523564bf3d2f6b3bd9746081a2fa0c76e36862beca62a4157d51cac0df61e456ddb6cacfae10b92344fe80cd752f72c38
 EBUILD ncurses-compat-6.4_p20230401.ebuild 9855 BLAKE2B 415fe12deea6175f395c202646cdeed1596a4de842ee9bccfaf1757fc34a3658adf53113d9cf73b854405132241d9ba8afbdcb68dce7a288341502d39d834cab SHA512 78232fa71408fd20a7fc57c470df4249a0b066c2cb0f69f0cb4b879c08d39c2b30a4811bf4213752159b1e43a8f6c3e51f2f12738888f322def513faf50db43f
-EBUILD ncurses-compat-6.4_p20240330.ebuild 10499 BLAKE2B 40794f36cd1f98e6cd3bd26ad0ee1c2f2bf55fd4ccf256238fb724a161346c1f45661825b97a3119886e0626ada0602164822d78bedd1ab5825ee279cc2eeee9 SHA512 157f350e2f7446bcaeb1e76a7eeaae0fe20c2521f762c6f0e0028b59c28d05df4a346cf98ca4892061213f88d165091463fb622fbd716c432f086a93410d0f35
+EBUILD ncurses-compat-6.4_p20240330.ebuild 10492 BLAKE2B 184d547206db9f60a5145c770c4e90c8419e5c720863a7fda4cd589281a889ca67f7ecb26038bf50d0772aa844dfed844cb007c9b5827372d1a255a69e2da9b0 SHA512 dd4cf16b3c4882ff5901139c123d63f5678c2e224ac8bece8ade26fd081b7e72ac6330c1851d4b3e6bb686801677e5397737c05cd4607f236eb3a3b74fdc1d66
 MISC metadata.xml 949 BLAKE2B 02d84363ace3523a818cf986afab5b7ddc3034d8fd1e365c054f802e944601ea4b4d579a27d06ddef9045730f05d5b901eb688bd7a53e341363feb7065318420 SHA512 3489cb9d8f931f74e898bed2d7bf6ca29934b9a5ebf3f58b8d3f1b68c87fc3cb7804cfefce2b1369ec0b6bf2e7ec22dc43e07920d99d4fc9edec0a970bf7be87
diff --git a/sys-libs/ncurses-compat/ncurses-compat-6.4_p20240330.ebuild b/sys-libs/ncurses-compat/ncurses-compat-6.4_p20240330.ebuild
index 0bef02b79d0c..2cbd2c12aced 100644
--- a/sys-libs/ncurses-compat/ncurses-compat-6.4_p20240330.ebuild
+++ b/sys-libs/ncurses-compat/ncurses-compat-6.4_p20240330.ebuild
@@ -154,7 +154,7 @@ S="${WORKDIR}/${MY_P}"
 LICENSE="MIT"
 # The subslot reflects the SONAME.
 SLOT="5/5"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86"
 IUSE="gpm +stack-realign tinfo unicode"
 
 DEPEND="gpm? ( sys-libs/gpm[${MULTILIB_USEDEP}] )"
diff --git a/sys-libs/ncurses/Manifest b/sys-libs/ncurses/Manifest
index 38df71800404..7251dc550833 100644
--- a/sys-libs/ncurses/Manifest
+++ b/sys-libs/ncurses/Manifest
@@ -142,8 +142,11 @@ DIST ncurses-6.4_p20230408-patches.tar.xz 80472 BLAKE2B 0ba8156ebd4f1691fec7bc1b
 DIST ncurses-6.4_p20230527-patches.tar.xz 63080 BLAKE2B 9db4ac28c8936d3a9c6f3ca5cb8a4c92aa79ee4ce49789bcfc9c031a0454bf6f55a0544bc4a3dbb5c243ed9b2d0792afb98622a6a14b11675b7988100a650eb5 SHA512 3eacda173e8a177cd201ca3fef65311ac92e7e5af4039dc8a5792beae7db1d37efd06f5a55c249eebb771d1245995ff3a206a45794936b6b4299151666dbeade
 DIST ncurses-6.4_p20240330-patches.tar.xz 63796 BLAKE2B 3e6618ba0b37268d10a16cf26c2810e55c17ded97079af3753e34f2d12575f979a2e55cfd308abf783e35e39d4a848b89f435b4886d3633007ccb522b8dc2e51 SHA512 1bbf1978f9287f68bf6a8596f06d4d0523564bf3d2f6b3bd9746081a2fa0c76e36862beca62a4157d51cac0df61e456ddb6cacfae10b92344fe80cd752f72c38
 DIST ncurses-6.4_p20240413-patches.tar.xz 63760 BLAKE2B 6a91d453cca3705ca54b3a6f2ef00250d655168c1697726db4b581a1597cbc143479b8794e176d5e4154c794f99ea33c3fe1eb26605789930fc82649a2da3c93 SHA512 59239503a9400e054641428528799aa9c13b12669b31f32b2ff18cb60882698801e04dcdf75ece8357c7a4c3b899a729aa973090ec12a20de72cb80a916878b8
+DIST ncurses-6.5.tar.gz 3688489 BLAKE2B d0a05c218b5f320ba9abe2f322787baef1d15d764e503c81d49772b54b2927d28ecbeb500c8e514996226b41f69445b4de44ff423cec25b61847307fe61682ec SHA512 fc5a13409d2a530a1325776dcce3a99127ddc2c03999cfeb0065d0eee2d68456274fb1c7b3cc99c1937bc657d0e7fca97016e147f93c7821b5a4a6837db821e8
+DIST ncurses-6.5.tar.gz.sig 438 BLAKE2B 5789b47932ec97d3863c7a65306369f0a36cb5b1a35c1e009b5174f50941edceafc22e6f07db3843a096773663a0ca602c0ecb9465e6042d9a78d76ae5008215 SHA512 96ce61a3d529e48e249acecbf4bb9eae2d9f2f67506e92ffa3182f5e98040c38babf0c2c15d92fc5d96e1181e72be1b29fdbff7bee859dfe2ae387f9b8883092
 EBUILD ncurses-6.4_p20230401.ebuild 13386 BLAKE2B 1e8285544f4eeb665a79988329e82fca9ad7ff1488ae8637294b5ecdc4b8aea3d5a4043d792bd05ef41d2111ae3c73d0d09a14b2fb606c9060ff267c0658e514 SHA512 f22355b4a8d30d403ddb1140c65c05d5ad5854791da6bf55309ba7c90f28f14cdf324b1e81e23bb9f4f607af8fea9d65b9ff8c909cba81ed04cffb53d257d347
 EBUILD ncurses-6.4_p20230527.ebuild 13534 BLAKE2B 6f66941cfa56e0033c3fb8b51805a9fe1f2a7d7ae94b640a6e69093ebdcb0c3c79cbde4bf56205bdb1f26a8601ed7d2c31b9cdf6c132779f39ab99e52c9b1a4e SHA512 ed972ae8c20b0d723bc957ee7bd71529b3b9ae8d2a796d9f600939ccde5e1c640cd08c259ffc17cd03e2316d72a1e6cab5c5e5727b571a0a8cf127a0a5b46602
-EBUILD ncurses-6.4_p20240330.ebuild 14061 BLAKE2B 15a772cb1354bac6500cbed1617adec51be0b3479a37d855c72c2e2b6946335f6b865ae65ec0044a5c13e3ac9f62eaed2968bb96db8b89559c0297831fe5b8e9 SHA512 37b5382b95a6ae9985a812d7e9ad0b2816b95ffdb248441955ab1fb2c67b1a0d9077beb71b9ce17befda6a43b75560f5ece027d9f85fac42270fc2da30a3257c
-EBUILD ncurses-6.4_p20240414.ebuild 14247 BLAKE2B a9a35523584e251e8853d553b9fb76e9089838977906c71182d94dc8214a91cc8be26b34f4340de74913d061e85a836bc454ab9bc6ae653f8f76e0d372463d99 SHA512 3e171e6851a9eeaa44dcc9ecfd05603fde3ca3b32875717fe89f03b9ddcdced568f959a6de9b5a30dddb531918e487dfac86444c34fa9f88aa43b85278a4ca6c
+EBUILD ncurses-6.4_p20240330.ebuild 14054 BLAKE2B 964d1aea4b68e96f2c4628050aeca2e61063bf31d3ccea50290d7a85695b57f8a33e3541fa53c7955f698864a253face706d8f025bc9b449f9324a9f81b1698b SHA512 3878a7dc84cb19d775fd64278a5da98ffb8fb7f85e49fdcf6cd6b51624d03b3071b48a7184f8adb87051f8d0e52a67c0fcc00d8eac44e25411fbc5118c7aab32
+EBUILD ncurses-6.4_p20240414.ebuild 14240 BLAKE2B c31e688299816283172a76555432a6923a4d9b271c4ecde9a675086db75c620d54eb0608cede764313d5275e7964e22f7330f514abb9dcec83c462f381a9395f SHA512 afb9e0371ce19583c176eab0521b4edf0724ea8493c2a4a4a64049545fd611d16ec3b2d734d5304d4553fcfbc226c8ae3cadee1b7f03e8fc2c3cc9f5f5106eff
+EBUILD ncurses-6.5-r1.ebuild 13759 BLAKE2B 58973ddcdaab9a09312a287f64cbc558071e59b0038404c881ffe7211567cf1d72185b175955204e4ea8547df6ed86bb52a48b03178fb4e91622c5248d860161 SHA512 24c385134cd8879c3ff7dc6d1b2ad6945588f2b49f70cea3414187d012fd7bfc6f8e177c1289537297819bdc8a596d365ff53d388569ba4fe8492d9d75a6d4e3
 MISC metadata.xml 1094 BLAKE2B a65bbb9584f77fb07fff735e6471ef48a5d63e7fa79112bf75df67f2f94e816706165fdd42a482708a7fd2ab3b3e308f9766eac0b39c3a4e31dcff5b3db25d57 SHA512 adf0f939a1e14c964bfb44ab80b1b8c1ee897a036a994848ba3e40280ab3a73ddb3beef540c905efd623e71b890c4c91e0b7c24651561d0e2bb2a4c86f039dba
diff --git a/sys-libs/ncurses/ncurses-6.4_p20240330.ebuild b/sys-libs/ncurses/ncurses-6.4_p20240330.ebuild
index e4fb6c71f0fe..e2ad9e3b5d83 100644
--- a/sys-libs/ncurses/ncurses-6.4_p20240330.ebuild
+++ b/sys-libs/ncurses/ncurses-6.4_p20240330.ebuild
@@ -150,7 +150,7 @@ S="${WORKDIR}/${MY_P}"
 LICENSE="MIT"
 # The subslot reflects the SONAME.
 SLOT="0/6"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
 IUSE="ada +cxx debug doc gpm minimal profile split-usr +stack-realign static-libs test tinfo trace"
 RESTRICT="!test? ( test )"
 
diff --git a/sys-libs/ncurses/ncurses-6.4_p20240414.ebuild b/sys-libs/ncurses/ncurses-6.4_p20240414.ebuild
index 3d26b093679b..06032ce23c15 100644
--- a/sys-libs/ncurses/ncurses-6.4_p20240414.ebuild
+++ b/sys-libs/ncurses/ncurses-6.4_p20240414.ebuild
@@ -152,7 +152,7 @@ S="${WORKDIR}/${MY_P}"
 LICENSE="MIT"
 # The subslot reflects the SONAME.
 SLOT="0/6"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
 IUSE="ada +cxx debug doc gpm minimal profile split-usr +stack-realign static-libs test tinfo trace"
 RESTRICT="!test? ( test )"
 
diff --git a/sys-libs/ncurses/ncurses-6.5-r1.ebuild b/sys-libs/ncurses/ncurses-6.5-r1.ebuild
new file mode 100644
index 000000000000..f4d21fed91c1
--- /dev/null
+++ b/sys-libs/ncurses/ncurses-6.5-r1.ebuild
@@ -0,0 +1,425 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# sys-libs/ncurses-compat can be bumped with sys-libs/ncurses as upstream
+# provide a configure option for the ABI version.
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/thomasdickey.asc
+inherit flag-o-matic toolchain-funcs multilib multilib-minimal preserve-libs usr-ldscript verify-sig
+
+MY_PV="${PV:0:3}"
+MY_P="${PN}-${MY_PV}"
+DESCRIPTION="Console display library"
+HOMEPAGE="https://www.gnu.org/software/ncurses/ https://invisible-island.net/ncurses/"
+# Keep invisible-mirror.net here as some users reported 403 forbidden with invisible-island.net
+SRC_URI="
+	mirror://gnu/ncurses/${MY_P}.tar.gz
+	https://invisible-island.net/archives/${PN}/${MY_P}.tar.gz
+	https://invisible-mirror.net/archives/${PN}/${MY_P}.tar.gz
+	verify-sig? ( mirror://gnu/ncurses/${MY_P}.tar.gz.sig )
+"
+
+GENTOO_PATCH_DEV=sam
+GENTOO_PATCH_PV=6.4_p20240413
+GENTOO_PATCH_NAME=${PN}-${GENTOO_PATCH_PV}-patches
+
+# Populated below in a loop. Do not add patches manually here.
+UPSTREAM_PATCHES=()
+
+if [[ ${PV} == *_p* ]] ; then
+	# Sometimes, after releases, there's no megapatch available yet.
+	#
+	# From upstream README at e.g. https://invisible-island.net/archives/ncurses/6.3/:
+	#
+	#	"At times (generally to mark a relatively stable point), I create a rollup
+	#	patch, which consists of all changes from the release through the current date."
+	#
+	# Also, from https://lists.gnu.org/archive/html/bug-ncurses/2019-08/msg00039.html,
+	# the patches are considered to be acceptable to use after some testing. They
+	# are both for development but also bug fixes.
+	#
+	# This array should contain a list of all the snapshots since the last
+	# release if there's no megapatch available yet.
+	PATCH_DATES=(
+		#20240101
+
+		# Latest patch is just _pN = $(ver_cut 4)
+		$(ver_cut 4)
+	)
+
+	if [[ -z ${PATCH_DATES[@]} ]] ; then
+		SRC_URI+=" https://invisible-island.net/archives/${PN}/${PV/_p*}/${MY_P/_p/-}.patch.sh.gz"
+		SRC_URI+=" verify-sig? ( https://invisible-island.net/archives/${PN}/${PV/_p*}/${MY_P/_p/-}.patch.sh.gz.asc"
+
+		# If we have a rollup patch, use that instead of the individual ones.
+		UPSTREAM_PATCHES+=( patch.sh )
+	else
+		# We use a mirror as well because we've had reports of 403 forbidden for some users.
+		upstream_url_base="https://invisible-island.net/archives/${PN}/${PV/_p*}/${MY_P}-"
+		upstream_m_url_base="https://invisible-mirror.net/archives/${PN}/${PV/_p*}/${MY_P}-"
+
+		# Prefix each date with the upstream location (https://invisible-island.net/archives/${PN}/${PV/_p*}/${MY_P})
+		mangled_patches=( "${PATCH_DATES[@]/#/${upstream_url_base}}" )
+		# Suffix each with .patch.gz
+		mangled_patches=( "${mangled_patches[@]/%/.patch.gz}" )
+		mangled_patches_sig=( "${mangled_patches[@]/%/.asc}" )
+		# Repeat for .patch.gz.asc for verify-sig
+		SRC_URI+=" ${mangled_patches[@]}"
+		SRC_URI+=" verify-sig? ( ${mangled_patches_sig[@]} )"
+
+		# For all of the URLs, chuck in invisible-island.net too:
+		SRC_URI+=" ${mangled_patches[@]/${upstream_url_base}/${upstream_m_url_base}}"
+		SRC_URI+=" verify-sig? ( ${mangled_patches_sig[@]/${upstream_url_base}/${upstream_m_url_base}} )"
+
+		UPSTREAM_PATCHES=( "${PATCH_DATES[@]/%/.patch}" )
+
+		unset upstream_url_base upstream_m_url_base mangled_patches mangled_patches_sig
+	fi
+fi
+
+SRC_URI+=" https://dev.gentoo.org/~${GENTOO_PATCH_DEV}/distfiles/${CATEGORY}/${PN}/${GENTOO_PATCH_NAME}.tar.xz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+# The subslot reflects the SONAME.
+SLOT="0/6"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="ada +cxx debug doc gpm minimal profile split-usr +stack-realign static-libs test tinfo trace"
+RESTRICT="!test? ( test )"
+
+# TODO: ncurses allows (and we take advantage of this, even) passing
+# the SONAME for dlopen() use, so only the header is needed at build time.
+# Maybe we should bundle a copy of gpm.h so we can move gpm to PDEPEND
+# which would be far nicer UX-wise.
+DEPEND="gpm? ( sys-libs/gpm[${MULTILIB_USEDEP}] )"
+# Block the older ncurses that installed all files w/SLOT=5, bug #557472
+RDEPEND="
+	${DEPEND}
+	!<=sys-libs/ncurses-5.9-r4:5
+	!<sys-libs/slang-2.3.2_pre23
+	!<x11-terms/rxvt-unicode-9.06-r3
+	!<x11-terms/st-0.6-r1
+"
+BDEPEND="verify-sig? ( sec-keys/openpgp-keys-thomasdickey )"
+
+PATCHES=(
+	"${UPSTREAM_PATCHES[@]/#/${WORKDIR}/${MY_P}-}"
+
+	# When rebasing Gentoo's patchset, please use git from a clean
+	# src_prepare with upstream patches already applied. git am --reject
+	# the existing patchset and rebase as required. This makes it easier
+	# to manage future rebasing & adding new patches.
+	#
+	# For the same reasons, please include the original configure.in changes,
+	# NOT just the generated results!
+	"${WORKDIR}"/${GENTOO_PATCH_NAME}
+)
+
+src_unpack() {
+	# Avoid trying to verify our own patchset tarball, there's no point
+	if use verify-sig ; then
+		local file
+		for file in ${A} ; do
+			if [[ ${file} == ${MY_P}.tar.gz ]] ; then
+				verify-sig_verify_detached "${DISTDIR}"/${file} "${DISTDIR}"/${file}.sig
+			else
+				[[ ${file} == @(*${GENTOO_PATCH_NAME}.tar.xz|*.asc|*.sig) ]] && continue
+
+				verify-sig_verify_detached "${DISTDIR}"/${file} "${DISTDIR}"/${file}.asc
+			fi
+		done
+	fi
+
+	default
+}
+
+src_configure() {
+	# bug #115036
+	unset TERMINFO
+
+	tc-export_build_env BUILD_{CC,CXX,CPP}
+
+	# bug #214642
+	BUILD_CPPFLAGS+=" -D_GNU_SOURCE"
+
+	# Build the various variants of ncurses -- narrow, wide, and threaded. #510440
+	# Order matters here -- we want unicode/thread versions to come last so that the
+	# binaries in /usr/bin support both wide and narrow.
+	# The naming is also important as we use these directly with filenames and when
+	# checking configure flags.
+	NCURSES_TARGETS=(
+		ncurses
+		ncursesw
+		ncursest
+		ncursestw
+	)
+
+	# When installing ncurses, we have to use a compatible version of tic.
+	# This comes up when cross-compiling, doing multilib builds, upgrading,
+	# or installing for the first time.  Build a local copy of tic whenever
+	# the host version isn't available. bug #249363, bug #557598
+	if ! has_version -b "~sys-libs/${P}:0" ; then
+		local lbuildflags="-static"
+
+		# some toolchains don't quite support static linking
+		local dbuildflags="-Wl,-rpath,${WORKDIR}/lib"
+		case ${CHOST} in
+			*-darwin*)  dbuildflags=     ;;
+			*-solaris*) dbuildflags="-Wl,-R,${WORKDIR}/lib" ;;
+		esac
+		echo "int main() {}" | \
+			$(tc-getCC) -o x -x c - ${lbuildflags} -pipe >& /dev/null \
+			|| lbuildflags="${dbuildflags}"
+
+		# We can't re-use the multilib BUILD_DIR because we run outside of it.
+		BUILD_DIR="${WORKDIR}" \
+		CC=${BUILD_CC} \
+		CXX=${BUILD_CXX} \
+		CPP=${BUILD_CPP} \
+		CHOST=${CBUILD} \
+		CFLAGS=${BUILD_CFLAGS} \
+		CXXFLAGS=${BUILD_CXXFLAGS} \
+		CPPFLAGS=${BUILD_CPPFLAGS} \
+		LDFLAGS="${BUILD_LDFLAGS} ${lbuildflags}" \
+		do_configure cross --without-shared --with-normal --with-progs --without-ada
+	fi
+	multilib-minimal_src_configure
+}
+
+multilib_src_configure() {
+	if [[ ${ABI} == x86 ]] ; then
+		# For compatibility with older binaries at slight performance cost.
+		# bug #616402
+		use stack-realign && append-flags -mstackrealign
+	fi
+
+	local t
+	for t in "${NCURSES_TARGETS[@]}" ; do
+		do_configure "${t}"
+	done
+}
+
+do_configure() {
+	local target=$1
+	shift
+
+	mkdir "${BUILD_DIR}/${target}" || die
+	cd "${BUILD_DIR}/${target}" || die
+
+	local conf=(
+		# We need the basic terminfo files in /etc, bug #37026.  We will
+		# add '--with-terminfo-dirs' and then populate /etc/terminfo in
+		# src_install() ...
+		--with-terminfo-dirs="${EPREFIX}/etc/terminfo:${EPREFIX}/usr/share/terminfo"
+
+		# Enable installation of .pc files.
+		--enable-pc-files
+		# This path is used to control where the .pc files are installed.
+		--with-pkg-config-libdir="${EPREFIX}/usr/$(get_libdir)/pkgconfig"
+
+		# Now the rest of the various standard flags.
+		--with-shared
+		--enable-fvisibility
+		# (Originally disabled until bug #245417 is sorted out, but now
+		# just keeping it off for good, given nobody needed it until now
+		# (2022) and we're trying to phase out bdb.)
+		--without-hashed-db
+		$(use_with ada)
+		$(use_with cxx)
+		$(use_with cxx cxx-binding)
+		--with-cxx-shared
+		$(use_with debug)
+		$(use_with profile)
+		# The configure script uses ldd to parse the linked output which
+		# is flaky for cross-compiling/multilib/ldd versions/etc...
+		$(use_with gpm gpm libgpm.so.1)
+
+		# bug #930806
+		--disable-setuid-environ
+		# TODO: Maybe do these for USE=hardened
+		#--disable-root-access
+		#--disable-root-environ
+
+		--disable-term-driver
+		--disable-termcap
+		--enable-symlinks
+		--with-manpage-format=normal
+		--enable-const
+		--enable-colorfgbg
+		--enable-hard-tabs
+		--enable-echo
+		$(use_enable !ada warnings)
+		$(use_with debug assertions)
+		$(use_enable !debug leaks)
+		$(use_with debug expanded)
+		$(use_with !debug macros)
+		$(multilib_native_with progs)
+		$(use_with test tests)
+		$(use_with trace)
+		$(use_with tinfo termlib)
+		--disable-stripping
+		--disable-pkg-ldflags
+	)
+
+	if [[ ${target} == ncurses*w ]] ; then
+		conf+=( --enable-widec )
+	else
+		conf+=( --disable-widec )
+	fi
+	if [[ ${target} == ncursest* ]] ; then
+		conf+=( --with-{pthread,reentrant} )
+	else
+		conf+=( --without-{pthread,reentrant} )
+	fi
+
+	# Make sure each variant goes in a unique location.
+	if [[ ${target} == "ncurses" ]] ; then
+		# "ncurses" variant goes into "${EPREFIX}"/usr/include
+		# It is needed on Prefix because the configure script appends
+		# "ncurses" to "${prefix}/include" if "${prefix}" is not /usr.
+		conf+=( --enable-overwrite )
+	else
+		conf+=( --includedir="${EPREFIX}"/usr/include/${target} )
+	fi
+	# See comments in src_configure.
+	if [[ ${target} != "cross" ]] ; then
+		local cross_path="${WORKDIR}/cross"
+		[[ -d ${cross_path} ]] && export TIC_PATH="${cross_path}/progs/tic"
+	fi
+
+	ECONF_SOURCE="${S}" econf "${conf[@]}" "$@"
+}
+
+src_compile() {
+	# See comments in src_configure.
+	if ! has_version -b "~sys-libs/${P}:0" ; then
+		BUILD_DIR="${WORKDIR}" do_compile cross -C progs tic$(get_exeext)
+	fi
+
+	multilib-minimal_src_compile
+}
+
+multilib_src_compile() {
+	local t
+	for t in "${NCURSES_TARGETS[@]}" ; do
+		do_compile "${t}"
+	done
+}
+
+do_compile() {
+	local target=$1
+	shift
+
+	cd "${BUILD_DIR}/${target}" || die
+
+	# A little hack to fix parallel builds ... they break when
+	# generating sources so if we generate the sources first (in
+	# non-parallel), we can then build the rest of the package
+	# in parallel.  This is not really a perf hit since the source
+	# generation is quite small.
+	emake -j1 sources
+
+	# For some reason, sources depends on pc-files which depends on
+	# compiled libraries which depends on sources which ...
+	# Manually delete the pc-files file so the install step will
+	# create the .pc files we want.
+	rm -f misc/pc-files || die
+	emake "$@"
+}
+
+multilib_src_install() {
+	local target
+	for target in "${NCURSES_TARGETS[@]}" ; do
+		emake -C "${BUILD_DIR}/${target}" DESTDIR="${D}" install
+	done
+
+	# Move main libraries into /.
+	if multilib_is_native_abi ; then
+		gen_usr_ldscript -a \
+			"${NCURSES_TARGETS[@]}" \
+			$(usex tinfo 'tinfow tinfo' '')
+	fi
+
+	# Don't delete '*.dll.a', needed for linking, bug #631468
+	if ! use static-libs; then
+		find "${ED}"/usr/ -name '*.a' ! -name '*.dll.a' -delete || die
+	fi
+
+	# Build fails to create this ...
+	# -FIXME-
+	# Ugly hackaround for riscv having two parts libdir (bug #689240)
+	# Replace this hack with an official solution once we have one...
+	# -FIXME-
+	dosym $(sed 's@[^/]\+@..@g' <<< $(get_libdir))/share/terminfo \
+		/usr/$(get_libdir)/terminfo
+
+	# Remove obsolete libcurses symlink that is created by the build
+	# system. Technically, this could be also achieved
+	# via --disable-overwrite but it also moves headers implicitly,
+	# and we do not want to do this yet.
+	# bug #836696
+	rm "${ED}"/usr/$(get_libdir)/libcurses* || die
+}
+
+multilib_src_install_all() {
+	local terms=(
+		# Dumb/simple values that show up when using the in-kernel VT.
+		ansi console dumb linux
+		vt{52,100,102,200,220}
+		# [u]rxvt users used to be pretty common.  Probably should drop this
+		# since upstream is dead and people are moving away from it.
+		rxvt{,-unicode}{,-256color}
+		# xterm users are common, as is terminals re-using/spoofing it.
+		xterm xterm-{,256}color
+		# screen is common (and reused by tmux).
+		screen{,-256color}
+		screen.xterm-256color
+	)
+	if use split-usr ; then
+		local x
+		# We need the basic terminfo files in /etc for embedded/recovery, bug #37026
+		einfo "Installing basic terminfo files in /etc..."
+		for x in "${terms[@]}"; do
+			local termfile=$(find "${ED}"/usr/share/terminfo/ -name "${x}" 2>/dev/null)
+			local basedir=$(basename "$(dirname "${termfile}")")
+
+			if [[ -n ${termfile} ]] ; then
+				dodir "/etc/terminfo/${basedir}"
+				mv "${termfile}" "${ED}/etc/terminfo/${basedir}/" || die
+				dosym "../../../../etc/terminfo/${basedir}/${x}" \
+					"/usr/share/terminfo/${basedir}/${x}"
+			fi
+		done
+
+		echo "CONFIG_PROTECT_MASK=\"/etc/terminfo\"" | newenvd - 50ncurses
+
+		use minimal && rm -r "${ED}"/usr/share/terminfo*
+		# Because ncurses5-config --terminfo returns the directory we keep it
+		# bug #245374
+		keepdir /usr/share/terminfo
+	elif use minimal ; then
+		# Keep only the basic terminfo files
+		find "${ED}"/usr/share/terminfo/ \
+			\( -type f -o -type l \) ${terms[*]/#/! -name } -delete , \
+			-type d -empty -delete || die
+	fi
+
+	cd "${S}" || die
+	dodoc ANNOUNCE MANIFEST NEWS README* TO-DO doc/*.doc
+	if use doc ; then
+		docinto html
+		dodoc -r doc/html/
+	fi
+}
+
+pkg_preinst() {
+	preserve_old_lib /$(get_libdir)/libncurses.so.5
+	preserve_old_lib /$(get_libdir)/libncursesw.so.5
+}
+
+pkg_postinst() {
+	preserve_old_lib_notify /$(get_libdir)/libncurses.so.5
+	preserve_old_lib_notify /$(get_libdir)/libncursesw.so.5
+}
diff --git a/sys-libs/snapd-glib/Manifest b/sys-libs/snapd-glib/Manifest
index a48588dc6a61..3677379d7147 100644
--- a/sys-libs/snapd-glib/Manifest
+++ b/sys-libs/snapd-glib/Manifest
@@ -1,8 +1,7 @@
 AUX snapd-glib-1.65-install-missing-header.patch 372 BLAKE2B b2cd1bc66ff14d3adfb62f15f69b85e5be5c8f658835ac657ef7645d4256876f2fd7d6ae760c7b6fc25dd714f6e4cc497bbabd5445ca253101c351aac8170977 SHA512 7c2afe6558afbf94ce208eb0367f6e9f499f4f409555ba2357b7ab2af53c1b04a42fd1925cfef1c6701ac205d1696f5dad68fb009ce31008d7229e31e957287b
 DIST snapd-glib-1.63.tar.xz 187676 BLAKE2B a212f826ee35ef5458b716ce64d8f4b32474f991938bc314fcdb0feb5c803f93880a517fe5e1550bc82bc4992bee7467dc0d8cf5cb260712e83b8a1fe6b75743 SHA512 94a2f46e4e066270ea5492cb00fd44da247686a354cbe6766fe3e8974e6bb51f4cf1ca95027533417ec8c8117fc9d3866cb173a113b89d789b6ba518489a314f
-DIST snapd-glib-1.64.tar.xz 195580 BLAKE2B 1c6e958033c2b98dd72b5bfb6f1a44739a79d5d9a289fded9756cf3031a1fe62cccbf3ba4ce4c4f34d3c7e48b945b481ff6c3ae245d205a49e37845dd3efbb27 SHA512 a3fa101bcc64b750c170ccd433dbbfaa306354dc6c66d5ab62911c866b7e65f6aefc7e9c82f84f5d16b8b96174edf4bef771a4839ef6e5acd15399a84b93aec4
 DIST snapd-glib-1.65.tar.xz 205948 BLAKE2B e5253cd6f8ac908236a89bf8fa3ec2252d2e4bb0875c6860b63808663d80d59d0a5397a5170ac959492e720e1c8fe77d9674a6469cc58556073cf93888da9a8b SHA512 6bae381c6b5a83312004026228ee76e7b8722a5a561c991ceda35aaf104eaf84451f5a7ba299cad6b1f82e3dbcb16cc4780ac393cadb2ca58478b59a809fc613
 EBUILD snapd-glib-1.63.ebuild 1149 BLAKE2B dd24a67001aad8070a2d59d74b7c6631f81f887d098379a59cbd8cbca79fec6af48e72494f44d382d195b889df4734216eb1a99a7d38a070d3f08a9d2c0c0ee1 SHA512 6767b4e61361089372012b35c8cfc57bf622b66d2a0a52fdffbacd81bdc3704696a69676dddda2d029c8ce8fc1988d2646be249e09e8a72d9bd847407063ab08
-EBUILD snapd-glib-1.64.ebuild 1150 BLAKE2B d766bca4abdb1fc8913e483159e6831e060a148bdc51ae60144072671b83b27ea6be416f0fec150bf148742f570a0d70d817b0fbfc3bb9d440e4ce20a6437031 SHA512 b883fd6d734203d4ed35f1c9a98331236f7d74ffacb77d20985f114a63eb73f9f91ca9aba8da4784782bb62b9393668e5dcf56cd34cb861ef64e6fffd53cbb57
-EBUILD snapd-glib-1.65-r1.ebuild 1570 BLAKE2B 56dc163a4e4f591e99a21c5fdb4647627d1840df0d12df5c4bc9da0f8fc56889119ec32cf77c729fca362b23a1b68a5d06ea231f033bc030f685787608e71890 SHA512 5b937d97cb209fa87996aa0858d38f3edb042641de26167c5e0451660917ac1b485c6b2aafe943cf8d139055e46c2ebfb87c90cb789f4305748ae9778de89ecc
+EBUILD snapd-glib-1.65-r102.ebuild 1254 BLAKE2B a252fdbd88b007e7fb3acb2050d1bba6e7e14a3a037395ba77a446b3c23bda23c010bb7e4810a5cddc409343732e1b46d53d0934eaa8563ed8b12294f8b7ab25 SHA512 861e6fa507d58f6132fb0975dce2727c01b63b74b1f5130d3f4dfbc98d4c0e2f1089f562b3ae61d2da95e31f12f86af15cdbd146fa59704c51ddbc3bb4e69f76
+EBUILD snapd-glib-1.65-r2.ebuild 1276 BLAKE2B c485f68cfba4a389569abf763a6e43007a24096aea45f9d4aaf2ed4d859f9f279cfff811d44942689eb39192271e67a82ebd19346fc2db2e96b3cec51600cdbb SHA512 02499703bf964b59fdfe670ccaf0c854212fe38b36569d93037155b0a1c3b7957ee6d0ca7cf87dc090364eeb98c3db77c241d4b4e0b0ee9842165a8ad6068477
 MISC metadata.xml 406 BLAKE2B ee1d1cdc33311cea7a3bcc4288fb8ec0148327eaa6fc59fd7c18ff3b34d9624a9e42a85f47254205a3d078651012d52ddc5f2dbf693f0250afc4194e389ba4be SHA512 1331657e9efe50b9901b2acc60694edf2c9f518a37f2a0d346969b78ceffe75d88a0503bb43fdac9a75eb81706440d99d8ce3eb6b9b112163438474b823338e1
diff --git a/sys-libs/snapd-glib/snapd-glib-1.65-r1.ebuild b/sys-libs/snapd-glib/snapd-glib-1.65-r102.ebuild
index 558bca6c7442..4a9410b58007 100644
--- a/sys-libs/snapd-glib/snapd-glib-1.65-r1.ebuild
+++ b/sys-libs/snapd-glib/snapd-glib-1.65-r102.ebuild
@@ -13,16 +13,15 @@ LICENSE="LGPL-3"
 SLOT="0/1"
 KEYWORDS="~amd64"
 
-IUSE="doc introspection qml qt5 qt6 vala"
+IUSE="doc introspection qml qt6 vala"
 REQUIRED_USE="
-	qml? ( || ( qt5 qt6 ) )
+	qml? ( qt6 )
 	vala? ( introspection )
 "
 
 BDEPEND="
 	virtual/pkgconfig
 	sys-devel/gettext
-	qt5? ( dev-qt/linguist-tools:5 )
 	qt6? ( dev-qt/qttools:6[linguist] )
 "
 
@@ -34,14 +33,8 @@ DEPEND="
 	doc? ( dev-util/gtk-doc )
 	introspection? ( dev-libs/gobject-introspection )
 	qml? (
-		qt5? ( dev-qt/qtdeclarative:5 )
 		qt6? ( dev-qt/qtdeclarative:6 )
 	)
-	qt5? (
-		dev-qt/qtcore:5
-		dev-qt/qtnetwork:5
-		dev-qt/qtwidgets:5
-	)
 	qt6? (
 		dev-qt/qtbase:6[network,widgets]
 	)
@@ -66,26 +59,11 @@ src_configure() {
 		"$(meson_use doc docs)"
 		"$(meson_use introspection)"
 		"$(meson_use qml qml-bindings)"
+		"$(meson_use qt6)"
 		"$(meson_use vala vala-bindings)"
 		-Dsoup2=false
+		-Dqt5=false
 	)
 
-	if use qt5; then
-		emesonargs+=(
-			-Dqt5=true
-			-Dqt6=false
-		)
-	elif use qt6; then
-		emesonargs+=(
-			-Dqt5=false
-			-Dqt6=true
-		)
-	else
-		emesonargs+=(
-			-Dqt5=false
-			-Dqt6=false
-		)
-	fi
-
 	meson_src_configure
 }
diff --git a/sys-libs/snapd-glib/snapd-glib-1.64.ebuild b/sys-libs/snapd-glib/snapd-glib-1.65-r2.ebuild
index 8728ba207b25..be44bfbc7a6a 100644
--- a/sys-libs/snapd-glib/snapd-glib-1.64.ebuild
+++ b/sys-libs/snapd-glib/snapd-glib-1.65-r2.ebuild
@@ -1,4 +1,4 @@
-# Copyright 2019-2023 Gentoo Authors
+# Copyright 2019-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -32,12 +32,14 @@ DEPEND="
 	net-libs/libsoup:3.0
 	doc? ( dev-util/gtk-doc )
 	introspection? ( dev-libs/gobject-introspection )
-	qml? ( dev-qt/qtdeclarative:5 )
+	qml? (
+		qt5? ( dev-qt/qtdeclarative:5 )
+	)
 	qt5? (
 		dev-qt/qtcore:5
 		dev-qt/qtnetwork:5
 		dev-qt/qtwidgets:5
-		)
+	)
 	vala? ( $(vala_depend) )
 "
 
@@ -45,6 +47,11 @@ RDEPEND="${DEPEND}
 	app-containers/snapd
 "
 
+PATCHES=(
+	# https://github.com/snapcore/snapd-glib/pull/152
+	"${FILESDIR}/${P}-install-missing-header.patch"
+)
+
 pkg_setup() {
 	vala_setup
 }
@@ -54,9 +61,10 @@ src_configure() {
 		"$(meson_use doc docs)"
 		"$(meson_use introspection)"
 		"$(meson_use qml qml-bindings)"
-		"$(meson_use qt5 qt-bindings)"
+		"$(meson_use qt5)"
 		"$(meson_use vala vala-bindings)"
 		-Dsoup2=false
+		-Dqt6=false
 	)
 
 	meson_src_configure