summaryrefslogtreecommitdiff
path: root/sys-cluster/ceph
diff options
context:
space:
mode:
Diffstat (limited to 'sys-cluster/ceph')
-rw-r--r--sys-cluster/ceph/Manifest3
-rw-r--r--sys-cluster/ceph/ceph-15.2.15-r2.ebuild (renamed from sys-cluster/ceph/ceph-15.2.15.ebuild)11
-rw-r--r--sys-cluster/ceph/ceph-16.2.6-r4.ebuild460
3 files changed, 469 insertions, 5 deletions
diff --git a/sys-cluster/ceph/Manifest b/sys-cluster/ceph/Manifest
index 426ee4be0219..d5c7a6e2c034 100644
--- a/sys-cluster/ceph/Manifest
+++ b/sys-cluster/ceph/Manifest
@@ -50,7 +50,8 @@ DIST ceph-15.2.15.tar.gz 148584988 BLAKE2B 6ff629846a74c9b30c7e5d54731e2c85c6794
DIST ceph-16.2.5.tar.gz 155933825 BLAKE2B 3c8f3f1663b91d4de1e3736317add0b88d9083db5ab2fc3e2e913278977deec076bd4410e309f4e47ccc169d74356c2ab1221c94532cc45ee75ec73673fc42a0 SHA512 5c32f9aa817ecfa788725bcfe5743756853ca9b3f9ee453242110f1b5e1bdd1feaef79ad9ccf2b185445c9644bcecb1355e151a2255bfd27edc9818e0d6d4c4a
DIST ceph-16.2.6.tar.gz 156087762 BLAKE2B e2595d1a958200e4f1877e4597c53319a9eee2e95606ea1b3ba2966a0d17f1cfcf52e05cca59752cc6ac383e32d944c380920d111aec840631235aef273a4de1 SHA512 f01e29088ae566d4111c21b5d0c173ddb02badaa0d8272f7f1548eb8e66a95dc7052b3945d9fb342e6c97a65c57648fda394317340d1f4236a57af7580073658
EBUILD ceph-14.2.22-r1.ebuild 10462 BLAKE2B ac59404f02b137daea912fc891a3a77e420829b79656161268190402e5020e1a4ce19400c2a97fedb5148347f26cce24fad8e70629c3ba2e29f68665002016bd SHA512 283caeefb71e9911a735b6fb9db7314f263627da58650b3a68d26857b5f4dd7d489bf305289c7bab15a814178b1d5130142e0e85f0d4f7e2cd5c33a90117920c
-EBUILD ceph-15.2.15.ebuild 10770 BLAKE2B 3d079cf7f1ebc1fd6d5ea02b360cfa90715f098d4d5b667dcb940582f4dd1e4610e0203480cfc0098c2c9eb3c623c40c5eda6cb5774a988ccb479412fc0db41b SHA512 405ce9a34e2df9fe6610e5f2a126719908fcfb4782e1478ce2d10a2b7d4daa12f9e2c20149637cf14a91576c6c92fdd17f537f37b1f69fd44ccbd376a353d13e
+EBUILD ceph-15.2.15-r2.ebuild 10872 BLAKE2B 7ff08b83e79b39cc4a727af6f57765afa4ec10ad672a67c9496cceec59f9e913ed8ed9492a91eed3eb44a18460d9776fd089e2428f7eaae73550798b07fedf2d SHA512 c1e4519c0218e6a1a40cd9a46759716768d9d14bd76719372e3f11f967310c4d9f1a62ac649778b3d154a0ecf3b778f59bf40b31a1389c5475bce9d947f611cf
EBUILD ceph-16.2.5.ebuild 12020 BLAKE2B 07add334a77f2da4c6c5f2b0fe564aea99d0a3d6be09360155873179e29271fc0844a62f33c279eaa9ad35b8b86f6b7d3dd96f21ecbf0ce2070193870ca14270 SHA512 15ae3d05777b333d4ec8ff5d80ed81e384fc2313b533d9a2b71c889543d0072ed1e65b2acc1ecb52a1af79cccb5e6a670c50785e7b94674ce54fe87a14578842
EBUILD ceph-16.2.6-r2.ebuild 12161 BLAKE2B fc64f1581df911862e1666e37316dfb8e011e791b103edd318641b992c8663581dc49104090ac10dfdb3b39cb5c77362ab44cc50219ff46e10352291435fdebe SHA512 48c00c0a0a233d2ab4f2720d4dd686db8c025f0724cb488f803e4c8991188da38df954c7f32d2954dbe4963364e34bf14879309082878edc20edfd122297ca88
+EBUILD ceph-16.2.6-r4.ebuild 12228 BLAKE2B 84a5f1e7df6fac047889b1d4537046eed3bfc5a00d366553e20c01bad82b91e78ca1cefc5b5789760316b5c6e1dc6466fb28d5fdc5d6a7b80b9fd6498db13c5d SHA512 604d1179fd1109c618846543a1e8b8c09d4dba0d3083c15a1d871eb3e923be33bbd715f37d271db21ae8f0aa6c4b4f9f83701c833153b61fad3f6cacf280b646
MISC metadata.xml 2319 BLAKE2B ed789868b8ce45fcdfd0125b296511c109815fa86c92e36371e32450a84a2b2415d8dcbdcbf7858f34a8db412157ae1242b66ef533272e6fa432532a1cac7c65 SHA512 36c8dae7ef1dc91d6f60279a61db96f3712ecf8c7a5844b8389105f2a1f8008a8744556d1addde5a50321153727bf8cd51d07142eeebcc87ab2ee86335ebad26
diff --git a/sys-cluster/ceph/ceph-15.2.15.ebuild b/sys-cluster/ceph/ceph-15.2.15-r2.ebuild
index 164f014af636..e9c79f993c8f 100644
--- a/sys-cluster/ceph/ceph-15.2.15.ebuild
+++ b/sys-cluster/ceph/ceph-15.2.15-r2.ebuild
@@ -9,7 +9,8 @@ CMAKE_MAKEFILE_GENERATOR=emake
DISTUTILS_OPTIONAL=1
inherit check-reqs bash-completion-r1 cmake distutils-r1 flag-o-matic \
- python-r1 udev readme.gentoo-r1 toolchain-funcs systemd tmpfiles
+ python-r1 udev readme.gentoo-r1 toolchain-funcs systemd tmpfiles \
+ multiprocessing
if [[ ${PV} == *9999* ]]; then
inherit git-r3
@@ -30,7 +31,7 @@ CPU_FLAGS_X86=(sse{,2,3,4_1,4_2} ssse3)
IUSE="babeltrace +cephfs custom-cflags diskprediction dpdk fuse grafana jemalloc
kafka kerberos ldap lttng +mgr numa pmdk rabbitmq +radosgw rbd-rwl +ssl spdk
- system-boost systemd +tcmalloc test uring xfs zfs"
+ +system-boost systemd +tcmalloc test uring xfs zfs"
IUSE+=" $(printf "cpu_flags_x86_%s\n" ${CPU_FLAGS_X86[@]})"
DEPEND="
@@ -39,7 +40,8 @@ DEPEND="
virtual/libudev:=
app-arch/bzip2:=
app-arch/lz4:=
- >=app-arch/snappy-1.1.9:=
+ app-arch/snappy:=
+ || ( >=app-arch/snappy-1.1.9-r1 <app-arch/snappy-1.1.9 )
app-arch/zstd:=
app-shells/bash:0
app-misc/jq:=
@@ -89,6 +91,7 @@ DEPEND="
rbd-rwl? ( dev-libs/pmdk:= )
ssl? ( dev-libs/openssl:= )
system-boost? ( >=dev-libs/boost-1.72:=[threads(+),context,python,${PYTHON_USEDEP}] )
+ !system-boost? ( <sys-libs/glibc-2.34 )
uring? ( sys-libs/liburing:= )
xfs? ( sys-fs/xfsprogs:= )
zfs? ( sys-fs/zfs:= )
@@ -99,7 +102,7 @@ BDEPEND="
x86? ( dev-lang/yasm )
app-arch/cpio
>=dev-util/cmake-3.5.0
- <=dev-python/cython-0.29.24[${PYTHON_USEDEP}]
+ dev-python/cython[${PYTHON_USEDEP}]
dev-python/sphinx
dev-util/cunit
dev-util/gperf
diff --git a/sys-cluster/ceph/ceph-16.2.6-r4.ebuild b/sys-cluster/ceph/ceph-16.2.6-r4.ebuild
new file mode 100644
index 000000000000..5e495f15ee5b
--- /dev/null
+++ b/sys-cluster/ceph/ceph-16.2.6-r4.ebuild
@@ -0,0 +1,460 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+DISTUTILS_OPTIONAL=1
+LUA_COMPAT=( lua5-3 )
+
+CMAKE_MAKEFILE_GENERATOR=emake
+
+inherit check-reqs bash-completion-r1 cmake distutils-r1 flag-o-matic \
+ lua-single python-r1 udev readme.gentoo-r1 toolchain-funcs \
+ systemd tmpfiles multiprocessing
+
+if [[ ${PV} == *9999* ]]; then
+ inherit git-r3
+ EGIT_REPO_URI="https://github.com/ceph/ceph.git"
+ SRC_URI=""
+else
+ SRC_URI="https://download.ceph.com/tarballs/${P}.tar.gz"
+ KEYWORDS="~amd64 ~arm64 ~ppc64"
+fi
+
+DESCRIPTION="Ceph distributed filesystem"
+HOMEPAGE="https://ceph.com/"
+
+LICENSE="Apache-2.0 LGPL-2.1 CC-BY-SA-3.0 GPL-2 GPL-2+ LGPL-2+ LGPL-2.1 LGPL-3 GPL-3 BSD Boost-1.0 MIT public-domain"
+SLOT="0"
+
+CPU_FLAGS_X86=(avx2 avx512f pclmul sse{,2,3,4_1,4_2} ssse3)
+
+IUSE="babeltrace +cephfs custom-cflags diskprediction dpdk fuse grafana
+ jemalloc jaeger kafka kerberos ldap lttng +mgr numa pmdk rabbitmq
+ +radosgw rbd-rwl rbd-ssd rgw-lua +ssl spdk +sqlite +system-boost systemd
+ +tcmalloc test uring xfs zbd zfs"
+IUSE+=" $(printf "cpu_flags_x86_%s\n" ${CPU_FLAGS_X86[@]})"
+
+DEPEND="
+ ${LUA_DEPS}
+ acct-group/ceph
+ acct-user/ceph
+ virtual/libudev:=
+ app-arch/bzip2:=
+ app-arch/lz4:=
+ app-arch/snappy
+ || ( >=app-arch/snappy-1.1.9-r1 <app-arch/snappy-1.1.9 )
+ app-arch/zstd:=
+ app-shells/bash:0
+ app-misc/jq:=
+ dev-libs/crypto++:=
+ dev-cpp/gflags:=
+ <dev-libs/leveldb-1.23:=[snappy,tcmalloc(-)?]
+ dev-libs/libaio:=
+ dev-libs/libfmt:=
+ dev-libs/libnl:3=
+ dev-libs/libxml2:=
+ dev-libs/libevent:=
+ <dev-libs/rocksdb-6.15:=
+ dev-libs/xmlsec:=[openssl]
+ dev-cpp/yaml-cpp:=
+ dev-libs/nss:=
+ dev-libs/protobuf:=
+ net-dns/c-ares:=
+ net-libs/gnutls:=
+ sys-auth/oath-toolkit:=
+ sys-apps/coreutils
+ sys-apps/grep
+ sys-apps/hwloc:=
+ sys-apps/keyutils:=
+ sys-apps/util-linux:=
+ sys-apps/sed
+ sys-apps/util-linux
+ sys-libs/libcap-ng:=
+ sys-libs/ncurses:0=
+ sys-libs/zlib:=
+ sys-process/numactl:=
+ virtual/libcrypt:=
+ x11-libs/libpciaccess:=
+ babeltrace? ( dev-util/babeltrace )
+ fuse? ( sys-fs/fuse:0= )
+ jemalloc? ( dev-libs/jemalloc:= )
+ !jemalloc? ( >=dev-util/google-perftools-2.6.1:= )
+ jaeger? ( dev-cpp/nlohmann_json:= )
+ kafka? ( dev-libs/librdkafka:= )
+ kerberos? ( virtual/krb5 )
+ ldap? ( net-nds/openldap:= )
+ lttng? ( dev-util/lttng-ust:= )
+ pmdk? ( dev-libs/pmdk:= )
+ rabbitmq? ( net-libs/rabbitmq-c:= )
+ radosgw? (
+ dev-libs/icu:=
+ dev-libs/expat:=
+ dev-libs/openssl:=
+ net-misc/curl:=[curl_ssl_openssl]
+ )
+ rbd-rwl? ( dev-libs/pmdk:= )
+ ssl? ( dev-libs/openssl:= )
+ sqlite? ( dev-db/sqlite:= )
+ system-boost? ( >=dev-libs/boost-1.72:=[threads(+),context,python,${PYTHON_USEDEP}] )
+ uring? ( sys-libs/liburing:= )
+ xfs? ( sys-fs/xfsprogs:= )
+ zbd? ( sys-block/libzbd:= )
+ zfs? ( sys-fs/zfs:= )
+ ${PYTHON_DEPS}
+"
+BDEPEND="
+ amd64? ( dev-lang/nasm )
+ x86? ( dev-lang/yasm )
+ app-arch/cpio
+ >=dev-util/cmake-3.5.0
+ dev-python/cython[${PYTHON_USEDEP}]
+ dev-python/setuptools[${PYTHON_USEDEP}]
+ dev-python/sphinx
+ dev-util/cunit
+ dev-util/gperf
+ dev-util/ragel
+ dev-util/valgrind
+ sys-apps/coreutils
+ sys-apps/findutils
+ sys-apps/grep
+ sys-apps/sed
+ sys-apps/which
+ sys-devel/bc
+ sys-devel/patch
+ virtual/pkgconfig
+ jaeger? (
+ sys-devel/bison
+ sys-devel/flex
+ )
+ test? (
+ dev-python/coverage[${PYTHON_USEDEP}]
+ dev-python/virtualenv[${PYTHON_USEDEP}]
+ dev-python/requests-mock[${PYTHON_USEDEP}]
+ sys-apps/grep[pcre]
+ sys-fs/btrfs-progs
+ )
+"
+RDEPEND="
+ ${DEPEND}
+ app-admin/sudo
+ net-misc/socat
+ sys-apps/gptfdisk
+ sys-apps/nvme-cli
+ >=sys-apps/smartmontools-7.0
+ sys-block/parted
+ sys-fs/cryptsetup
+ sys-fs/lsscsi
+ sys-fs/lvm2[-device-mapper-only(-)]
+ virtual/awk
+ dev-python/bcrypt[${PYTHON_USEDEP}]
+ dev-python/cherrypy[${PYTHON_USEDEP}]
+ dev-python/python-dateutil[${PYTHON_USEDEP}]
+ dev-python/flask[${PYTHON_USEDEP}]
+ dev-python/jinja[${PYTHON_USEDEP}]
+ dev-python/pecan[${PYTHON_USEDEP}]
+ dev-python/prettytable[${PYTHON_USEDEP}]
+ dev-python/pyopenssl[${PYTHON_USEDEP}]
+ dev-python/pyyaml[${PYTHON_USEDEP}]
+ dev-python/requests[${PYTHON_USEDEP}]
+ dev-python/werkzeug[${PYTHON_USEDEP}]
+ mgr? (
+ dev-python/jsonpatch[${PYTHON_USEDEP}]
+ dev-python/more-itertools[${PYTHON_USEDEP}]
+ dev-python/numpy[${PYTHON_USEDEP}]
+ dev-python/pyjwt[${PYTHON_USEDEP}]
+ dev-python/routes[${PYTHON_USEDEP}]
+ diskprediction? (
+ >=dev-python/scipy-1.4.0[${PYTHON_USEDEP}]
+ )
+ sci-libs/scikit-learn[${PYTHON_USEDEP}]
+ dev-python/six[${PYTHON_USEDEP}]
+ )
+"
+# diskprediction needs older scipy not compatible with py38
+# bug #724438
+REQUIRED_USE="
+ ${PYTHON_REQUIRED_USE}
+ ${LUA_REQUIRED_USE}
+ ?? ( jemalloc tcmalloc )
+ jaeger? ( !system-boost )
+ diskprediction? ( mgr )
+ kafka? ( radosgw )
+ mgr? ( cephfs )
+ rabbitmq? ( radosgw )
+"
+RESTRICT="!test? ( test )"
+
+# the tests need root access
+RESTRICT="test? ( userpriv )"
+
+# distribution tarball does not include everything needed for tests
+RESTRICT+=" test"
+
+# create a non-debug release
+CMAKE_BUILD_TYPE=RelWithDebInfo
+
+# false positives unless all USE flags are on
+CMAKE_WARN_UNUSED_CLI=no
+
+PATCHES=(
+ "${FILESDIR}/ceph-12.2.0-use-provided-cpu-flag-values.patch"
+ "${FILESDIR}/ceph-14.2.0-cflags.patch"
+ "${FILESDIR}/ceph-12.2.4-boost-build-none-options.patch"
+ "${FILESDIR}/ceph-16.2.2-cflags.patch"
+ "${FILESDIR}/ceph-16.2.2-no-virtualenvs.patch"
+ "${FILESDIR}/ceph-13.2.2-dont-install-sysvinit-script.patch"
+ "${FILESDIR}/ceph-14.2.0-dpdk-cflags.patch"
+ "${FILESDIR}/ceph-14.2.0-cython-0.29.patch"
+ "${FILESDIR}/ceph-16.2.0-rocksdb-cmake.patch"
+ "${FILESDIR}/ceph-15.2.3-spdk-compile.patch"
+ "${FILESDIR}/ceph-16.2.0-spdk-tinfo.patch"
+ "${FILESDIR}/ceph-16.2.0-jaeger-system-boost.patch"
+ "${FILESDIR}/ceph-16.2.0-liburing.patch"
+ "${FILESDIR}/ceph-16.2.2-system-zstd.patch"
+)
+
+check-reqs_export_vars() {
+ CHECKREQS_DISK_BUILD="6G"
+
+ if use system-boost; then
+ CHECKREQS_DISK_USR="350M"
+ else
+ CHECKREQS_DISK_USR="510M"
+ fi
+
+ export CHECKREQS_DISK_BUILD CHECKREQS_DISK_USR
+}
+
+pkg_pretend() {
+ check-reqs_export_vars
+ check-reqs_pkg_pretend
+}
+
+pkg_setup() {
+ python_setup
+ lua_setup
+ check-reqs_export_vars
+ check-reqs_pkg_setup
+}
+
+src_prepare() {
+ cmake_src_prepare
+
+ if use system-boost; then
+ find "${S}" -name '*.cmake' -or -name 'CMakeLists.txt' -print0 \
+ | xargs --null sed -r \
+ -e 's|Boost::|boost_|g' \
+ -e 's|Boost_|boost_|g' \
+ -e 's|[Bb]oost_boost|boost_system|g' -i || die
+ fi
+
+ if ! use systemd; then
+ find "${S}"/src/ceph-volume/ceph_volume -name '*.py' -print0 \
+ | xargs --null sed \
+ -e '/^from ceph_volume.systemd import systemctl/ d' \
+ -i || die
+ fi
+
+ sed -r -e "s:DESTINATION .+\\):DESTINATION $(get_bashcompdir)\\):" \
+ -i src/bash_completion/CMakeLists.txt || die
+
+ sed -e "s:objdump -p:$(tc-getOBJDUMP) -p:" -i CMakeLists.txt || die
+
+ if ! use diskprediction; then
+ rm -rf src/pybind/mgr/diskprediction_local || die
+ fi
+
+ # force lua version to use selected version
+ local lua_version
+ lua_version=$(ver_cut 1-2 $(lua_get_version))
+ sed -i "s:find_package(Lua [0-9][.][0-9] REQUIRED):find_package(Lua ${lua_version} EXACT REQUIRED):" src/CMakeLists.txt
+
+ # remove tests that need root access
+ rm src/test/cli/ceph-authtool/cap*.t || die
+}
+
+ceph_src_configure() {
+ local flag
+ local mycmakeargs=(
+ -DWITH_BABELTRACE=$(usex babeltrace)
+ -DWITH_BLUESTORE_PMEM=$(usex pmdk)
+ -DWITH_CEPHFS=$(usex cephfs)
+ -DWITH_CEPHFS_SHELL=$(usex cephfs)
+ -DWITH_DPDK=$(usex dpdk)
+ -DWITH_SPDK=$(usex spdk)
+ -DWITH_FUSE=$(usex fuse)
+ -DWITH_LTTNG=$(usex lttng)
+ -DWITH_GSSAPI=$(usex kerberos)
+ -DWITH_GRAFANA=$(usex grafana)
+ -DWITH_MGR=$(usex mgr)
+ -DWITH_MGR_DASHBOARD_FRONTEND=OFF
+ -DWITH_NUMA=$(usex numa)
+ -DWITH_OPENLDAP=$(usex ldap)
+ -DWITH_PYTHON3=3
+ -DWITH_RADOSGW=$(usex radosgw)
+ -DWITH_RADOSGW_AMQP_ENDPOINT=$(usex rabbitmq)
+ -DWITH_RADOSGW_KAFKA_ENDPOINT=$(usex kafka)
+ -DWITH_RADOSGW_LUA_PACKAGES=$(usex rgw-lua "$(usex radosgw)" "NO")
+ -DWITH_RBD_RWL=$(usex rbd-rwl)
+ -DWITH_RBD_SSD_CACHE=$(usex rbd-ssd)
+ -DWITH_SSL=$(usex ssl)
+ -DWITH_SYSTEMD=$(usex systemd)
+ -DWITH_TESTS=$(usex test)
+ -DWITH_LIBURING=$(usex uring)
+ -DWITH_SYSTEM_LIBURING=$(usex uring)
+ -DWITH_LIBCEPHSQLITE=$(usex sqlite)
+ -DWITH_XFS=$(usex xfs)
+ -DWITH_ZBD=$(usex zbd)
+ -DWITH_ZFS=$(usex zfs)
+ -DENABLE_SHARED="ON"
+ -DALLOCATOR=$(usex tcmalloc 'tcmalloc' "$(usex jemalloc 'jemalloc' 'libc')")
+ -DWITH_SYSTEM_PMDK=$(usex pmdk 'YES' "$(usex rbd-rwl)")
+ -DWITH_SYSTEM_BOOST=$(usex system-boost)
+ -DBOOST_J=$(makeopts_jobs)
+ -DWITH_SYSTEM_ROCKSDB=ON
+ -DWITH_RDMA=OFF
+ -DWITH_TBB=OFF
+ -DSYSTEMD_UNITDIR=$(systemd_get_systemunitdir)
+ -DCMAKE_INSTALL_SYSTEMD_SERVICEDIR=$(systemd_get_systemunitdir)
+ -DEPYTHON_VERSION="${EPYTHON#python}"
+ -DCMAKE_INSTALL_DOCDIR="${EPREFIX}/usr/share/doc/${PN}-${PVR}"
+ -DCMAKE_INSTALL_SYSCONFDIR="${EPREFIX}/etc"
+ -Wno-dev
+ )
+
+ # this breaks when re-configuring for python impl
+ [[ ${EBUILD_PHASE} == configure ]] && mycmakeargs+=(-DWITH_JAEGER=$(usex jaeger))
+
+ if use amd64 || use x86; then
+ for flag in ${CPU_FLAGS_X86[@]}; do
+ case "${flag}" in
+ avx*)
+ local var=${flag%f}
+ mycmakeargs+=("$(usex cpu_flags_x86_${flag} "-DHAVE_NASM_X64_${var^^}=1")")
+ ;;
+ *) mycmakeargs+=("$(usex cpu_flags_x86_${flag} "-DHAVE_INTEL_${flag^^}=1")");;
+ esac
+ done
+ fi
+
+ # needed for >=glibc-2.32
+ has_version '>=sys-libs/glibc-2.32' && mycmakeargs+=(-DWITH_REENTRANT_STRSIGNAL:BOOL=ON)
+
+ rm -f "${BUILD_DIR:-${S}}/CMakeCache.txt" \
+ || die "failed to remove cmake cache"
+
+ cmake_src_configure
+
+ # bug #630232
+ sed -i "s:\"${T//:\\:}/${EPYTHON}/bin/python\":\"${PYTHON}\":" \
+ "${BUILD_DIR:-${S}}"/include/acconfig.h \
+ || die "sed failed"
+}
+
+src_configure() {
+ use custom-cflags || strip-flags
+ ceph_src_configure
+}
+
+python_compile() {
+ local CMAKE_USE_DIR="${S}"
+ ceph_src_configure
+
+ pushd "${BUILD_DIR}/src/pybind" >/dev/null || die
+ emake VERBOSE=1 clean
+ emake VERBOSE=1 all
+
+ # python modules are only compiled with "make install" so we need to do this to
+ # prevent doing a bunch of compilation in src_install
+ DESTDIR="${T}" emake VERBOSE=1 install
+ popd >/dev/null || die
+}
+
+src_compile() {
+ cmake_build VERBOSE=1 all
+
+ # we have to do this here to prevent from building everything multiple times
+ python_copy_sources
+ python_foreach_impl python_compile
+}
+
+src_test() {
+ make check || die "make check failed"
+}
+
+python_install() {
+ local CMAKE_USE_DIR="${S}"
+ pushd "${BUILD_DIR}/src/pybind" >/dev/null || die
+ DESTDIR="${ED}" emake VERBOSE=1 install
+ popd >/dev/null || die
+
+ python_optimize
+}
+
+src_install() {
+ cmake_src_install
+ python_foreach_impl python_install
+
+ find "${ED}" -name '*.la' -type f -delete || die
+
+ exeinto /usr/$(get_libdir)/ceph
+ newexe "${BUILD_DIR}/bin/init-ceph" init-ceph
+
+ insinto /etc/logrotate.d/
+ newins "${FILESDIR}"/ceph.logrotate-r2 ${PN}
+
+ keepdir /var/lib/${PN}{,/tmp} /var/log/${PN}/stat
+
+ fowners -R ceph:ceph /var/log/ceph
+
+ newinitd "${FILESDIR}/rbdmap.initd-r1" rbdmap
+ newinitd "${FILESDIR}/${PN}.initd-r12" ${PN}
+ newconfd "${FILESDIR}/${PN}.confd-r5" ${PN}
+
+ insinto /etc/sudoers.d
+ doins sudoers.d/*
+
+ insinto /etc/sysctl.d
+ newins "${FILESDIR}"/sysctld 90-${PN}.conf
+
+ use tcmalloc && newenvd "${FILESDIR}"/envd-tcmalloc 99${PN}-tcmalloc
+
+ # units aren't installed by the build system unless systemd is enabled
+ # so no point installing these with the USE flag disabled
+ if use systemd; then
+ systemd_install_serviced "${FILESDIR}/ceph-mds_at.service.conf" \
+ "ceph-mds@.service"
+
+ systemd_install_serviced "${FILESDIR}/ceph-osd_at.service.conf" \
+ "ceph-osd@.service"
+
+ fi
+
+ udev_dorules udev/*.rules
+ newtmpfiles "${FILESDIR}"/ceph-tmpfilesd ${PN}.conf
+
+ readme.gentoo_create_doc
+
+ python_setup
+
+ # bug #630232
+ sed -i -r "s:${T//:/\\:}/${EPYTHON}:/usr:" "${ED}"/usr/bin/ceph{,-crash} \
+ || die "sed failed"
+
+ python_fix_shebang "${ED}"/usr/{,s}bin/
+
+ # python_fix_shebang apparently is not idempotent
+ local shebang_regex='(/usr/lib/python-exec/python[0-9]\.[0-9]/python)[0-9]\.[0-9]'
+ grep -r -E -l --null "${shebang_regex}" "${ED}"/usr/{s,}bin/ \
+ | xargs --null --no-run-if-empty -- sed -i -r "s:${shebang_regex}:\1:" || die
+
+ local -a rados_classes=( "${ED}/usr/$(get_libdir)/rados-classes"/* )
+ dostrip -x "${rados_classes[@]#${ED}}"
+}
+
+pkg_postinst() {
+ readme.gentoo_print_elog
+ tmpfiles_process ${PN}.conf
+}
generated by cgit v1.2.3 (git 2.25.1) at 2024-12-29 14:23:42 +0000