summaryrefslogtreecommitdiff
path: root/sys-apps/util-linux
diff options
context:
space:
mode:
Diffstat (limited to 'sys-apps/util-linux')
-rw-r--r--sys-apps/util-linux/Manifest5
-rw-r--r--sys-apps/util-linux/util-linux-2.40.2.ebuild454
-rw-r--r--sys-apps/util-linux/util-linux-9999.ebuild29
3 files changed, 486 insertions, 2 deletions
diff --git a/sys-apps/util-linux/Manifest b/sys-apps/util-linux/Manifest
index e9d264def2cf..3cd3be782037 100644
--- a/sys-apps/util-linux/Manifest
+++ b/sys-apps/util-linux/Manifest
@@ -17,9 +17,12 @@ DIST util-linux-2.39.4.tar.sign 833 BLAKE2B cbefaa4968ac82491c9eaa467c5e84e9b4a0
DIST util-linux-2.39.4.tar.xz 8541176 BLAKE2B 53fef6f36b802d5e4c1112376c77e5cd832280d9eaeb9a6a98b2371334a1a3a8a48f5589d16f67c623a5050ae3b16dafc43ee26a9e8cb77079f9b6a2ee6c9480 SHA512 94e0282ac9705ca666d3c3864f2656bd1a21d879339164edd2c413ae7665b1cfec01f9c58a83b3148b8c4b4e857653447e5523c3b27230b175dd39f75ac6fae0
DIST util-linux-2.40.1.tar.sign 833 BLAKE2B 2f8537cd4f52e0c203360d081a91f17c2db13c0f6054ef02f967e8fdf03099bb8c42604864003bfb911ea7804033f4020e2f56a933667fc84ac9c4b8d01e9ed5 SHA512 ab73a27fc8601041bf7b8a088586b78c49ca83cf9c8cfe5877280c0b5c607e95695512804335a8c0ac1d243e4433595f44256407fdbfb053451b8ab40d605502
DIST util-linux-2.40.1.tar.xz 8823784 BLAKE2B a51fcf9b63c033e470da4f4f0094f0f923fdeb5a649a5c59d2d44888e5e741dfd95e589247355296e050d9ec8dc4334c5898453af055abcb30082af6b835a3e3 SHA512 58ec6eb41d4b6bfc544a80e95c71b5f3798ab4d2a9435d3ee9e5edd56f9b3f09bcb154bdd70e002dc018938937e2e946ae731dcda0f86b362fc43423689e41fc
+DIST util-linux-2.40.2.tar.sign 833 BLAKE2B 10aae23d25c1364bac0034d6862df5738c7a405d52198fba1e4e9173a1b2ba9f3d994dacb881d920c3339c0f1018c7dd1c97c7752bdf0e8e634f54235c2b3f5c SHA512 e4ace52333df0c8dd7c8ffc3b813020615c456e06a6978e06c8183ec29896be5af7c25f59e65fc2c2849750d8d7b43043775b8504d6d01f626f1adf296493ce1
+DIST util-linux-2.40.2.tar.xz 8854820 BLAKE2B 8306d651f27db6665e91a937c9f1970938fec5b069636fea3c2688afddebd1a3424f0b0802a034eab049cf7692dd435cf93e82aa5f4a40cc8064d60b4ca59535 SHA512 ffe20b915a518a150401d429b0338bc7022190e4ca0ef91a6d9eea345db8c1e11ad01784163b8fcf978506f3f5cad473f29d5d4ef93a4c66a5ae0ebd9fb0c8f2
EBUILD util-linux-2.39.3-r2.ebuild 10872 BLAKE2B c44068bc288acf9c77d4c697cc8b7848e3c85ab0d548672283cc76bf34eae1bf80aa39cc9afaa7105e5ad9bf0ed0494ddbebe062e7dba6aa9ec0616ee77a7eb2 SHA512 b8cc2a20122f1c094cfbd4fb3652672cf7def1d6d9b38971f2f52511893f9de1e7774ed06c03a17c4b19d58cc564a1291833974ffe0c43778d077165f6f6f538
EBUILD util-linux-2.39.3-r7.ebuild 11231 BLAKE2B c8734054faf407fd1d7b0f077d3f84a7c59cb7698e0b6c810f164d60d186f7efbefc117cbb3bffa701a0d83f8d1d1a42ce2a081031bed9179c5bc43cd9ed9038 SHA512 94d84e7221d67e9a061c34f7cd5eff3da45b4763b813a7071f0d9be93528da38f1d378ef56a85e19948881e8540528d2cfdab7e4bfd1858f0fa09a3f7ca857b8
EBUILD util-linux-2.39.4-r1.ebuild 11171 BLAKE2B 40e06d4c563271a3e891270007d0a21e1743eab09e5385a21f6dcca02d2c6bf3a7c0620ff569b81a3e9fc48c9ee125f16a10d7baf71cf9ce3700cfc653905f59 SHA512 f0cbc998a7d908960bc0b9f767998280c09c02417d206ed833fb6ebf6bf3265212337ae7b5e6418221f50e14601b55df4a3d9b8cb0ffc02536f4223ccda0d14f
EBUILD util-linux-2.40.1-r3.ebuild 11242 BLAKE2B 7719aedf804e87e8b78a8d3eadf4ec0aeca94b4a213b34a17059003922f8efa94e0980556159c6c7e119606c1a44c092252473dbdcc3bb891b1201952f5740a5 SHA512 3d081701737757531746ed1528838dba624baf237816a5fa439dd371020e1b301036b42e534da43f05525c4de146f71ae35176a2a6465cec22b229d58ab14f98
-EBUILD util-linux-9999.ebuild 11144 BLAKE2B 6eac7c7bb6c20e7a82be199f67598f17e44b1dfa59b12e4a998db34550ac0bf65f9128cd625ced594cd01178ed416cfc85a7c6c9bd39002375da4d62b02ea69a SHA512 66dfcb2916a4882c781f49b2f7d8b2853fc4b0983bcd58c424f595d3a4f0c6bb23881bb422d3d8c46315ea74da449ee0229c02923cb066f8fdbe865fc72835d3
+EBUILD util-linux-2.40.2.ebuild 11851 BLAKE2B 8fc9679a373037aa1f1a2feb69757e6a35aba6f4d40f7c04206abe1a0d2e06293ccbfc2686aee639a1b0f031a113699215cb90b46669a887783e78c5399449b4 SHA512 6f2f04b9ce98f6469b2c7d07cab3e062861b105925153bec47df3132d8faa647c727b9cc731618e65a3c3f532b50fd11961c9e11feb0dc4c0a3c237a4eb76c28
+EBUILD util-linux-9999.ebuild 11851 BLAKE2B 8fc9679a373037aa1f1a2feb69757e6a35aba6f4d40f7c04206abe1a0d2e06293ccbfc2686aee639a1b0f031a113699215cb90b46669a887783e78c5399449b4 SHA512 6f2f04b9ce98f6469b2c7d07cab3e062861b105925153bec47df3132d8faa647c727b9cc731618e65a3c3f532b50fd11961c9e11feb0dc4c0a3c237a4eb76c28
MISC metadata.xml 1600 BLAKE2B c36342513e86655c4e4bfee627d9b516d4dc008abce3a7397d6cf3fb65f562bb58bcdc5b9d7daa801da01c77d19415b0dc6bf3407c5cca7d51327bb3689f94f6 SHA512 56b041dcbcc2c048a642bb8b44927cc0bed40de1c531f6445feaf0a87673fa19efffa3a5dabed5178b427d1fe5fdf41c2f7b8c0386f9adf1545c5ff9fa30169b
diff --git a/sys-apps/util-linux/util-linux-2.40.2.ebuild b/sys-apps/util-linux/util-linux-2.40.2.ebuild
new file mode 100644
index 000000000000..6cdf721aeeef
--- /dev/null
+++ b/sys-apps/util-linux/util-linux-2.40.2.ebuild
@@ -0,0 +1,454 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+TMPFILES_OPTIONAL=1
+
+inherit toolchain-funcs libtool flag-o-matic bash-completion-r1 \
+ pam python-r1 multilib-minimal multiprocessing systemd tmpfiles
+
+MY_PV="${PV/_/-}"
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="Various useful Linux utilities"
+HOMEPAGE="https://www.kernel.org/pub/linux/utils/util-linux/ https://github.com/util-linux/util-linux"
+
+if [[ ${PV} == 9999 ]] ; then
+ EGIT_REPO_URI="https://git.kernel.org/pub/scm/utils/util-linux/util-linux.git"
+ inherit autotools git-r3
+else
+ VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/karelzak.asc
+ inherit verify-sig
+
+ if [[ ${PV} != *_rc* ]] ; then
+ KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos"
+ fi
+
+ SRC_URI="https://www.kernel.org/pub/linux/utils/util-linux/v${PV:0:4}/${MY_P}.tar.xz"
+ SRC_URI+=" verify-sig? ( https://www.kernel.org/pub/linux/utils/util-linux/v${PV:0:4}/${MY_P}.tar.sign )"
+fi
+
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-2 GPL-3 LGPL-2.1 BSD-4 MIT public-domain"
+SLOT="0"
+IUSE="audit build caps +cramfs cryptsetup fdformat +hardlink kill +logger magic ncurses nls pam python +readline rtas selinux slang static-libs +su +suid systemd test tty-helpers udev unicode uuidd"
+
+# Most lib deps here are related to programs rather than our libs,
+# so we rarely need to specify ${MULTILIB_USEDEP}.
+RDEPEND="
+ virtual/libcrypt:=
+ audit? ( >=sys-process/audit-2.6:= )
+ caps? ( sys-libs/libcap-ng )
+ cramfs? ( sys-libs/zlib:= )
+ cryptsetup? ( >=sys-fs/cryptsetup-2.1.0 )
+ hardlink? ( dev-libs/libpcre2:= )
+ ncurses? (
+ sys-libs/ncurses:=[unicode(+)?]
+ magic? ( sys-apps/file:0= )
+ )
+ nls? ( virtual/libintl[${MULTILIB_USEDEP}] )
+ pam? ( sys-libs/pam )
+ python? ( ${PYTHON_DEPS} )
+ readline? ( sys-libs/readline:0= )
+ rtas? ( sys-libs/librtas )
+ selinux? ( >=sys-libs/libselinux-2.2.2-r4[${MULTILIB_USEDEP}] )
+ slang? ( sys-libs/slang )
+ !build? (
+ systemd? ( sys-apps/systemd )
+ udev? ( virtual/libudev:= )
+ )
+"
+BDEPEND="
+ virtual/pkgconfig
+ nls? (
+ app-text/po4a
+ sys-devel/gettext
+ )
+ test? ( app-alternatives/bc )
+"
+DEPEND="
+ ${RDEPEND}
+ virtual/os-headers
+ acct-group/root
+"
+RDEPEND+="
+ hardlink? ( !app-arch/hardlink )
+ logger? ( !>=app-admin/sysklogd-2.0[logger] )
+ kill? (
+ !sys-apps/coreutils[kill]
+ !sys-process/procps[kill]
+ )
+ su? (
+ !<sys-apps/shadow-4.7-r2
+ !>=sys-apps/shadow-4.7-r2[su]
+ )
+ uuidd? (
+ acct-user/uuidd
+ systemd? ( virtual/tmpfiles )
+ )
+ !net-wireless/rfkill
+"
+
+if [[ ${PV} == 9999 ]] ; then
+ # Required for man-page generation
+ BDEPEND+=" dev-ruby/asciidoctor"
+else
+ BDEPEND+=" verify-sig? ( >=sec-keys/openpgp-keys-karelzak-20230517 )"
+fi
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} ) su? ( pam )"
+RESTRICT="!test? ( test )"
+
+pkg_pretend() {
+ if use su && ! use suid ; then
+ elog "su will be installed as suid despite USE=-suid (bug #832092)"
+ elog "To use su without suid, see e.g. Portage's suidctl feature."
+ fi
+}
+
+src_unpack() {
+ if [[ ${PV} == 9999 ]] ; then
+ git-r3_src_unpack
+ return
+ fi
+
+ # Upstream sign the decompressed .tar
+ if use verify-sig; then
+ einfo "Unpacking ${MY_P}.tar.xz ..."
+ verify-sig_verify_detached - "${DISTDIR}"/${MY_P}.tar.sign \
+ < <(xz -cd "${DISTDIR}"/${MY_P}.tar.xz | tee >(tar -x))
+ assert "Unpack failed"
+ else
+ default
+ fi
+}
+
+src_prepare() {
+ default
+
+ if use test ; then
+ # Known-failing tests
+ local known_failing_tests=(
+ # Subtest 'options-maximum-size-8192' fails
+ hardlink/options
+
+ # Fails in sandbox
+ # re ioctl_ns: https://github.com/util-linux/util-linux/issues/2967
+ lsns/ioctl_ns
+ lsfd/mkfds-inotify
+ lsfd/mkfds-symlink
+ lsfd/mkfds-rw-character-device
+ # Fails with network-sandbox at least in nspawn
+ lsfd/option-inet
+ utmp/last-ipv6
+
+ # Flaky
+ rename/subdir
+
+ # Permission issues on /dev/random
+ lsfd/mkfds-eventpoll
+ lsfd/column-xmode
+ )
+
+ # debug prints confuse the tests which look for a diff
+ # in output
+ if has_version "=app-shells/bash-5.3_alpha*" ; then
+ known_failing_tests+=(
+ lsfd/column-ainodeclass
+ lsfd/mkfds-netlink-protocol
+ lsfd/column-type
+ lsfd/mkfds-eventfd
+ lsfd/mkfds-signalfd
+ lsfd/mkfds-mqueue
+ lsfd/mkfds-tcp6
+ lsfd/mkfds-tcp
+ lsfd/filter-floating-point-nums
+ lsfd/mkfds-unix-stream-requiring-sockdiag
+ lsfd/mkfds-unix-dgram
+ lsfd/mkfds-directory
+ lsfd/mkfds-pty
+ lsfd/mkfds-pipe-no-fork
+ lsfd/mkfds-unix-stream
+ lsfd/mkfds-ro-regular-file
+ lsfd/mkfds-timerfd
+ lsfd/mkfds-udp
+ lsfd/mkfds-udp6
+ )
+ fi
+
+ local known_failing_test
+ for known_failing_test in "${known_failing_tests[@]}" ; do
+ einfo "Removing known-failing test: ${known_failing_test}"
+ rm tests/ts/${known_failing_test} || die
+ done
+ fi
+
+ if [[ ${PV} == 9999 ]] ; then
+ po/update-potfiles
+ eautoreconf
+ else
+ elibtoolize
+ fi
+}
+
+python_configure() {
+ local myeconfargs=(
+ "${commonargs[@]}"
+ --disable-all-programs
+ --disable-bash-completion
+ --without-systemdsystemunitdir
+ --with-python
+ --enable-libblkid
+ --enable-libmount
+ --enable-pylibmount
+ )
+
+ mkdir "${BUILD_DIR}" || die
+ pushd "${BUILD_DIR}" >/dev/null || die
+ ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+ popd >/dev/null || die
+}
+
+multilib_src_configure() {
+ # The scanf test in a run-time test which fails while cross-compiling.
+ # Blindly assume a POSIX setup since we require libmount, and libmount
+ # itself fails when the scanf test fails. bug #531856
+ tc-is-cross-compiler && export scanf_cv_alloc_modifier=ms
+
+ # bug #485486
+ export ac_cv_header_security_pam_misc_h=$(multilib_native_usex pam)
+ # bug #545042
+ export ac_cv_header_security_pam_appl_h=$(multilib_native_usex pam)
+
+ # Undo bad ncurses handling by upstream. Fall back to pkg-config.
+ # bug #601530
+ export NCURSES6_CONFIG=false NCURSES5_CONFIG=false
+ export NCURSESW6_CONFIG=false NCURSESW5_CONFIG=false
+
+ # Avoid automagic dependency on ppc*
+ export ac_cv_lib_rtas_rtas_get_sysparm=$(usex rtas)
+
+ # configure args shared by python and non-python builds
+ local commonargs=(
+ --localstatedir="${EPREFIX}/var"
+ --runstatedir="${EPREFIX}/run"
+ --enable-fs-paths-extra="${EPREFIX}/usr/sbin:${EPREFIX}/bin:${EPREFIX}/usr/bin"
+ )
+
+ local myeconfargs=(
+ "${commonargs[@]}"
+ --with-bashcompletiondir="$(get_bashcompdir)"
+ --without-python
+ $(multilib_native_use_enable suid makeinstall-chown)
+ $(multilib_native_use_enable suid makeinstall-setuid)
+ $(multilib_native_use_with readline)
+ $(multilib_native_use_with slang)
+ $(multilib_native_usex ncurses "$(use_with magic libmagic)" '--without-libmagic')
+ $(multilib_native_usex ncurses "$(use_with unicode ncursesw)" '--without-ncursesw')
+ $(multilib_native_usex ncurses "$(use_with !unicode ncurses)" '--without-ncurses')
+ $(multilib_native_use_with audit)
+ $(tc-has-tls || echo --disable-tls)
+ $(use_enable nls)
+ $(use_enable nls poman)
+ $(use_enable unicode widechar)
+ $(use_enable static-libs static)
+ $(use_with ncurses tinfo)
+ $(use_with selinux)
+ $(multilib_native_use_enable uuidd)
+
+ # TODO: Wire this up (bug #931118)
+ --without-econf
+
+ # TODO: Wire this up (bug #931297)
+ # TODO: investigate build failure w/ 2.40.1_rc1
+ --disable-liblastlog2
+ --disable-pam-lastlog2
+ )
+
+ if use build ; then
+ myeconfargs+=(
+ --without-systemd
+ --without-udev
+ )
+ else
+ myeconfargs+=(
+ $(multilib_native_use_with systemd)
+ $(multilib_native_use_with udev)
+ )
+ fi
+
+ if multilib_is_native_abi ; then
+ myeconfargs+=(
+ --disable-chfn-chsh
+ --disable-login
+ --disable-newgrp
+ --disable-nologin
+ --disable-pylibmount
+ --disable-raw
+ --disable-vipw
+ --enable-agetty
+ --enable-bash-completion
+ --enable-line
+ --enable-partx
+ --enable-rename
+ --enable-rfkill
+ --enable-schedutils
+ --with-systemdsystemunitdir="$(systemd_get_systemunitdir)"
+ --with-tmpfilesdir="${EPREFIX}"/usr/lib/tmpfiles.d
+ $(use_enable caps setpriv)
+ $(use_enable cramfs)
+ $(use_enable fdformat)
+ $(use_enable hardlink)
+ $(use_enable kill)
+ $(use_enable logger)
+ $(use_enable ncurses pg)
+ $(use_enable su)
+ $(use_enable tty-helpers mesg)
+ $(use_enable tty-helpers wall)
+ $(use_enable tty-helpers write)
+ $(use_with cryptsetup)
+ )
+ if [[ ${PV} == *9999 ]] ; then
+ myeconfargs+=( --enable-asciidoc )
+ else
+ # Upstream is shipping pre-generated man-pages for releases
+ myeconfargs+=( --disable-asciidoc )
+ fi
+ else
+ myeconfargs+=(
+ --disable-all-programs
+ --disable-asciidoc
+ --disable-bash-completion
+ --without-systemdsystemunitdir
+ --disable-poman
+
+ # build libraries
+ --enable-libuuid
+ --enable-libblkid
+ --enable-libsmartcols
+ --enable-libfdisk
+ --enable-libmount
+
+ # Support uuidd for non-native libuuid
+ $(use_enable uuidd libuuid-force-uuidd)
+ )
+ fi
+
+ ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+
+ if multilib_is_native_abi && use python ; then
+ python_foreach_impl python_configure
+ fi
+}
+
+src_configure() {
+ append-lfs-flags
+ multilib-minimal_src_configure
+}
+
+python_compile() {
+ pushd "${BUILD_DIR}" >/dev/null || die
+ emake all
+ popd >/dev/null || die
+}
+
+multilib_src_compile() {
+ emake all
+
+ if multilib_is_native_abi && use python ; then
+ python_foreach_impl python_compile
+ fi
+}
+
+python_test() {
+ pushd "${BUILD_DIR}" >/dev/null || die
+ emake check TS_OPTS="--parallel=$(makeopts_jobs) --nonroot"
+ popd >/dev/null || die
+}
+
+multilib_src_test() {
+ emake check TS_OPTS="--parallel=$(makeopts_jobs) --nonroot"
+ if multilib_is_native_abi && use python ; then
+ python_foreach_impl python_test
+ fi
+}
+
+python_install() {
+ pushd "${BUILD_DIR}" >/dev/null || die
+ emake DESTDIR="${D}" install
+ python_optimize
+ popd >/dev/null || die
+}
+
+multilib_src_install() {
+ if multilib_is_native_abi && use python ; then
+ python_foreach_impl python_install
+ fi
+
+ # This needs to be called AFTER python_install call, bug #689190
+ # XXX: -j1 as temporary workaround for bug #931301
+ emake DESTDIR="${D}" install -j1
+}
+
+multilib_src_install_all() {
+ dodoc AUTHORS NEWS README* Documentation/{TODO,*.txt,releases/*}
+
+ dosym hexdump /usr/bin/hd
+ newman - hd.1 <<< '.so man1/hexdump.1'
+
+ # e2fsprogs-libs didn't install .la files, and .pc work fine
+ find "${ED}" -name "*.la" -delete || die
+
+ if use pam ; then
+ # See https://github.com/util-linux/util-linux/blob/master/Documentation/PAM-configuration.txt
+ newpamd "${FILESDIR}/runuser.pamd" runuser
+ newpamd "${FILESDIR}/runuser-l.pamd" runuser-l
+
+ newpamd "${FILESDIR}/su-l.pamd" su-l
+ fi
+
+ if use su && ! use suid ; then
+ # Always force suid su, even when USE=-suid, as su is useless
+ # for the overwhelming-majority case without suid.
+ # Users who wish to truly have a no-suid su can strip it out
+ # via e.g. Portage's suidctl or some other hook.
+ # See bug #832092
+ fperms u+s /bin/su
+ fi
+
+ if use uuidd; then
+ newinitd "${FILESDIR}/uuidd.initd" uuidd
+ fi
+
+ # Note:
+ # Bash completion for "runuser" command is provided by same file which
+ # would also provide bash completion for "su" command. However, we don't
+ # use "su" command from this package.
+ # This triggers a known QA warning which we ignore for now to magically
+ # keep bash completion for "su" command which shadow package does not
+ # provide.
+
+ local ver=$(tools/git-version-gen .tarballversion)
+ local major=$(ver_cut 1 ${ver})
+ local minor=$(ver_cut 2 ${ver})
+ local release=$(ver_cut 3 ${ver})
+ export QA_PKGCONFIG_VERSION="${major}.${minor}.${release:-0}"
+}
+
+pkg_postinst() {
+ if ! use tty-helpers ; then
+ elog "The mesg/wall/write tools have been disabled due to USE=-tty-helpers."
+ fi
+
+ if [[ -z ${REPLACING_VERSIONS} ]] ; then
+ elog "The agetty util now clears the terminal by default. You"
+ elog "might want to add --noclear to your /etc/inittab lines."
+ fi
+
+ if use systemd && use uuidd; then
+ tmpfiles_process uuidd-tmpfiles.conf
+ fi
+}
diff --git a/sys-apps/util-linux/util-linux-9999.ebuild b/sys-apps/util-linux/util-linux-9999.ebuild
index 8e74d1439e60..6cdf721aeeef 100644
--- a/sys-apps/util-linux/util-linux-9999.ebuild
+++ b/sys-apps/util-linux/util-linux-9999.ebuild
@@ -153,6 +153,32 @@ src_prepare() {
lsfd/column-xmode
)
+ # debug prints confuse the tests which look for a diff
+ # in output
+ if has_version "=app-shells/bash-5.3_alpha*" ; then
+ known_failing_tests+=(
+ lsfd/column-ainodeclass
+ lsfd/mkfds-netlink-protocol
+ lsfd/column-type
+ lsfd/mkfds-eventfd
+ lsfd/mkfds-signalfd
+ lsfd/mkfds-mqueue
+ lsfd/mkfds-tcp6
+ lsfd/mkfds-tcp
+ lsfd/filter-floating-point-nums
+ lsfd/mkfds-unix-stream-requiring-sockdiag
+ lsfd/mkfds-unix-dgram
+ lsfd/mkfds-directory
+ lsfd/mkfds-pty
+ lsfd/mkfds-pipe-no-fork
+ lsfd/mkfds-unix-stream
+ lsfd/mkfds-ro-regular-file
+ lsfd/mkfds-timerfd
+ lsfd/mkfds-udp
+ lsfd/mkfds-udp6
+ )
+ fi
+
local known_failing_test
for known_failing_test in "${known_failing_tests[@]}" ; do
einfo "Removing known-failing test: ${known_failing_test}"
@@ -363,7 +389,8 @@ multilib_src_install() {
fi
# This needs to be called AFTER python_install call, bug #689190
- emake DESTDIR="${D}" install
+ # XXX: -j1 as temporary workaround for bug #931301
+ emake DESTDIR="${D}" install -j1
}
multilib_src_install_all() {
generated by cgit v1.2.3 (git 2.25.1) at 2024-07-07 13:05:29 +0000