1 files changed, 0 insertions, 70 deletions
diff --git a/sys-apps/usb_modeswitch/usb_modeswitch-2.6.0.ebuild b/sys-apps/usb_modeswitch/usb_modeswitch-2.6.0.ebuild
deleted file mode 100644
index 77ada0145c06..000000000000
--- a/sys-apps/usb_modeswitch/usb_modeswitch-2.6.0.ebuild
+++ /dev/null
@@ -1,70 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit linux-info toolchain-funcs udev systemd
-
-MY_PN=${PN/_/-}
-MY_P=${MY_PN}-${PV/_p*}
-#DATA_VER=${PV/*_p}
-DATA_VER="20191128"
-
-DESCRIPTION="A tool for controlling 'flip flop' (multiple devices) USB gear like UMTS sticks"
-HOMEPAGE="https://www.draisberghof.de/usb_modeswitch/ https://www.draisberghof.de/usb_modeswitch/device_reference.txt"
-SRC_URI="https://www.draisberghof.de/${PN}/${MY_P}.tar.bz2
-	https://www.draisberghof.de/${PN}/${MY_PN}-data-${DATA_VER}.tar.bz2"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="amd64 arm ~arm64 x86"
-IUSE=""
-
-RDEPEND="
-	virtual/udev
-	virtual/libusb:1
-"
-DEPEND="${RDEPEND}"
-BDEPEND="
-	virtual/pkgconfig
-"
-
-S=${WORKDIR}/${MY_P}
-
-CONFIG_CHECK="~USB_SERIAL"
-
-PATCHES=( "${FILESDIR}/usb_modeswitch.sh-tmpdir.patch" )
-
-src_prepare() {
-	default
-	sed -i -e '/install.*BIN/s:-s::' Makefile || die
-}
-
-src_compile() {
-	emake CC="$(tc-getCC)"
-}
-
-src_install() {
-	emake \
-		DESTDIR="${D}" \
-		SYSDIR="${D}/$(systemd_get_systemunitdir)" \
-		UDEVDIR="${D}/${EPREFIX}$(get_udevdir)" \
-		install
-
-	# Even if we set SYSDIR above, the Makefile is causing automagic detection of `systemctl` binary,
-	# which is why we need to force the .service file to be installed:
-	systemd_dounit ${PN}@.service
-
-	dodoc ChangeLog README
-
-	pushd ../${MY_PN}-data-${DATA_VER} &>/dev/null || die
-	emake \
-		DESTDIR="${D}" \
-		RULESDIR="${D}/${EPREFIX}$(get_udevdir)/rules.d" \
-		files-install db-install
-	docinto data
-	dodoc ChangeLog README
-	popd &>/dev/null || die
-
-	keepdir /var/lib/${PN}
-}