1 files changed, 63 insertions, 0 deletions
diff --git a/sys-apps/pkgcore/pkgcore-0.12.16-r1.ebuild b/sys-apps/pkgcore/pkgcore-0.12.16-r1.ebuild
new file mode 100644
index 000000000000..b060b26f7101
--- /dev/null
+++ b/sys-apps/pkgcore/pkgcore-0.12.16-r1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+inherit distutils-r1
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/pkgcore/pkgcore"
+	inherit git-r3
+else
+	KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~x64-macos"
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+fi
+
+DESCRIPTION="a framework for package management"
+HOMEPAGE="https://github.com/pkgcore/pkgcore"
+
+LICENSE="BSD MIT"
+SLOT="0"
+
+RDEPEND="
+	>=app-shells/bash-5.0
+	dev-python/lxml[${PYTHON_USEDEP}]
+"
+if [[ ${PV} == *9999 ]]; then
+	RDEPEND+=" ~dev-python/snakeoil-9999[${PYTHON_USEDEP}]"
+else
+	RDEPEND+=" >=dev-python/snakeoil-0.10.0[${PYTHON_USEDEP}]"
+fi
+BDEPEND="
+	test? (
+		>=dev-python/pytest-6[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)
+"
+
+distutils_enable_tests setup.py
+
+src_prepare() {
+	# force Gentoo's prefix
+	sed -e "/INSTALL_PREFIX =/s@= .*\$@= '${EPREFIX}/usr'@" -i setup.py || die
+
+	distutils-r1_src_prepare
+}
+
+src_test() {
+	# With PYTHONDONTWRITEBYTECODE=, python will try rebuild all sorts of modules.
+	# https://bugs.gentoo.org/840266
+	local -x SANDBOX_PREDICT=${SANDBOX_PREDICT}
+	addpredict /
+
+	local -x PYTHONDONTWRITEBYTECODE=
+	distutils-r1_src_test
+}
+
+python_install_all() {
+	local DOCS=( NEWS.rst )
+	[[ ${PV} == *9999 ]] || doman man/*
+	distutils-r1_python_install_all
+}