1 files changed, 68 insertions, 0 deletions
diff --git a/sys-apps/pkgcore/pkgcore-0.10.8.ebuild b/sys-apps/pkgcore/pkgcore-0.10.8.ebuild
new file mode 100644
index 000000000000..7351db9305d0
--- /dev/null
+++ b/sys-apps/pkgcore/pkgcore-0.10.8.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python3_{6,7,8} )
+DISTUTILS_IN_SOURCE_BUILD=1
+inherit distutils-r1
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/pkgcore/pkgcore.git"
+	inherit git-r3
+else
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+fi
+
+DESCRIPTION="a framework for package management"
+HOMEPAGE="https://github.com/pkgcore/pkgcore"
+
+LICENSE="BSD MIT"
+SLOT="0"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="dev-python/lxml[${PYTHON_USEDEP}]"
+if [[ ${PV} == *9999 ]]; then
+	RDEPEND+=" ~dev-python/snakeoil-9999[${PYTHON_USEDEP}]"
+else
+	RDEPEND+=" >=dev-python/snakeoil-0.8.4[${PYTHON_USEDEP}]"
+fi
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( $(python_gen_any_dep '
+		dev-python/setuptools[${PYTHON_USEDEP}]
+		dev-python/snakeoil[${PYTHON_USEDEP}]
+		dev-python/docutils[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	') )
+	!doc? (
+		$(python_gen_any_dep 'dev-python/setuptools[${PYTHON_USEDEP}]')
+	)
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )
+"
+
+python_check_deps() {
+	has_version "dev-python/setuptools[${PYTHON_USEDEP}]" || return 1
+	has_version "dev-python/snakeoil[${PYTHON_USEDEP}]" || return 1
+	if use doc; then
+		has_version "dev-python/docutils[${PYTHON_USEDEP}]" &&
+		has_version "dev-python/sphinx[${PYTHON_USEDEP}]"
+	fi
+}
+
+python_compile_all() {
+	use doc && esetup.py build_docs
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	local DOCS=( AUTHORS NEWS.rst )
+	esetup.py install_docs \
+		--docdir="${ED%/}/usr/share/doc/${PF}" \
+		--mandir="${ED%/}/usr/share/man"
+	distutils-r1_python_install_all
+}