1 files changed, 70 insertions, 0 deletions
diff --git a/sys-apps/kbd/kbd-2.1.0.ebuild b/sys-apps/kbd/kbd-2.1.0.ebuild
new file mode 100644
index 000000000000..12711a24eca6
--- /dev/null
+++ b/sys-apps/kbd/kbd-2.1.0.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit autotools git-r3
+	EGIT_REPO_URI="https://git.kernel.org/pub/scm/linux/kernel/git/legion/kbd.git"
+	EGIT_BRANCH="master"
+else
+	SRC_URI="https://www.kernel.org/pub/linux/utils/kbd/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sh ~sparc ~x86"
+fi
+
+DESCRIPTION="Keyboard and console utilities"
+HOMEPAGE="http://kbd-project.org/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="nls pam test"
+
+RDEPEND="
+	app-arch/gzip
+	pam? (
+		!app-misc/vlock
+		virtual/pam
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	test? ( dev-libs/check )
+"
+
+src_unpack() {
+	if [[ ${PV} == "9999" ]] ; then
+		git-r3_src_unpack
+	else
+		default
+	fi
+
+	# Rename conflicting keymaps to have unique names, bug #293228
+	cd "${S}"/data/keymaps/i386 || die
+	mv fgGIod/trf.map fgGIod/trf-fgGIod.map || die
+	mv olpc/es.map olpc/es-olpc.map || die
+	mv olpc/pt.map olpc/pt-olpc.map || die
+	mv qwerty/cz.map qwerty/cz-qwerty.map || die
+}
+
+src_prepare() {
+	default
+	if [[ ${PV} == "9999" ]] ; then
+		eautoreconf
+	fi
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable nls)
+		$(use_enable pam vlock)
+		$(use_enable test tests)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	docinto html
+	dodoc docs/doc/*.html
+}