1 files changed, 50 insertions, 0 deletions
diff --git a/sci-mathematics/easycrypt/easycrypt-2023.09.ebuild b/sci-mathematics/easycrypt/easycrypt-2023.09.ebuild
new file mode 100644
index 000000000000..938be55dac7e
--- /dev/null
+++ b/sci-mathematics/easycrypt/easycrypt-2023.09.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit dune
+
+DESCRIPTION="Computer-Aided Cryptographic Proofs"
+HOMEPAGE="https://github.com/EasyCrypt/easycrypt/"
+
+if [[ "${PV}" == *9999* ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/EasyCrypt/${PN}.git"
+else
+	SRC_URI="https://github.com/EasyCrypt/${PN}/archive/r${PV}.tar.gz
+		-> ${P}.tar.gz"
+	S="${WORKDIR}/${PN}-r${PV}"
+
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="MIT"
+SLOT="0/${PV}"
+IUSE="+ocamlopt"
+
+RDEPEND="
+	>=dev-lang/ocaml-4.08.0:=[ocamlopt?]
+	>=sci-mathematics/why3-1.6:= <sci-mathematics/why3-1.7:=
+
+	dev-ml/batteries:=
+	dev-ml/camlp-streams:=
+	dev-ml/camlzip:=
+	dev-ml/dune-build-info:=
+	dev-ml/dune-site:=
+	dev-ml/ocaml-inifiles:=
+	dev-ml/pcre-ocaml:=
+	dev-ml/yojson:=
+	dev-ml/zarith:=
+"
+DEPEND="
+	${RDEPEND}
+"
+
+src_prepare() {
+	local theories="[\"$(ocamlc -where)/easycrypt/theories\"]"
+	sed -i "s|EcRelocate\.Sites\.theories|${theories}|g" src/ec.ml || die
+
+	default
+}