1 files changed, 61 insertions, 0 deletions
diff --git a/sci-libs/onnx/onnx-1.14.1-r1.ebuild b/sci-libs/onnx/onnx-1.14.1-r1.ebuild
new file mode 100644
index 000000000000..331b32483cf4
--- /dev/null
+++ b/sci-libs/onnx/onnx-1.14.1-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+DISTUTILS_USE_PEP517=setuptools
+DISTUTILS_OPTIONAL=1
+DISTUTILS_EXT=1
+PYTHON_COMPAT=( python3_{9..11} )
+inherit distutils-r1 cmake
+
+DESCRIPTION="Open Neural Network Exchange (ONNX)"
+HOMEPAGE="https://github.com/onnx/onnx"
+SRC_URI="https://github.com/onnx/${PN}/archive/refs/tags/v${PV}.tar.gz
+	-> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv"
+IUSE="python"
+RESTRICT="test"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	python? (
+		${PYTHON_DEPS}
+		dev-python/protobuf-python[${PYTHON_USEDEP}]
+		dev-python/pybind11[${PYTHON_USEDEP}]
+	)
+	dev-libs/protobuf:=
+"
+DEPEND="${RDEPEND}"
+
+BDEPEND="python? (
+	${DISTUTILS_DEPS}
+)"
+
+PATCHES=( "${FILESDIR}"/${PN}-1.14.0-cxx_14.patch )
+
+src_prepare() {
+	cmake_src_prepare
+	use python && distutils-r1_src_prepare
+}
+
+src_configure() {
+	mycmakeargs=(
+		-DONNX_USE_PROTOBUF_SHARED_LIBS=ON
+		-DONNX_USE_LITE_PROTO=ON
+	)
+	cmake_src_configure
+	use python && distutils-r1_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	use python && CMAKE_ARGS="${mycmakeargs[@]}" distutils-r1_src_compile
+}
+
+src_install() {
+	cmake_src_install
+	use python && distutils-r1_src_install
+}