2 files changed, 144 insertions, 0 deletions
diff --git a/sci-libs/gmsh/Manifest b/sci-libs/gmsh/Manifest
index 9c2539daebc9..109061ff497a 100644
--- a/sci-libs/gmsh/Manifest
+++ b/sci-libs/gmsh/Manifest
@@ -7,4 +7,5 @@ DIST gmsh-4.13.1-source.tgz 18383962 BLAKE2B bf0d002b7d0fa187b47440f167fc02ad41a
 EBUILD gmsh-4.11.1-r3.ebuild 3113 BLAKE2B dce0182a83b100cd3028c338dab8c6d925420f2e46faf5a0ce88cb15e9ff40937078f536b977b6b2537084c2b639d81aa0829543201279b1a5b86da92dbda1b6 SHA512 9e4f4141fbb7de0ddfce6bdc5f08c914111591611f65749a1bbd2e4fc85cf17240247c6ffc098168d1b51d15c205f91d125cf2c107f9d7d171e0d9fd44b1e126
 EBUILD gmsh-4.12.2-r2.ebuild 3069 BLAKE2B 6e1068a7ab1e48a416c6fba8653dafa08d1318cbb73c90d8e8947d4c5a38b645e4116b47ced263f17287f0020e5e1fae8923365899616ad639e6a0d7cfa1c06c SHA512 f9aa6007672bd78c14222c414232461f88b73847c93cf7bf3e57706f73a6d4bfd6402ad3f601206e34f0eaae65ab206eaca4ae99255b34cb12aef9a4756c5524
 EBUILD gmsh-4.13.1-r1.ebuild 3069 BLAKE2B 9ae3283caf14c2c39cc3396a577df6b0073e25045a2d72e5ddab5575d22afbe81d22f2824607284fd1c673f7f360c30c84b5103578180f7cac793a30fd988cab SHA512 118faccfc47e9560a144749ecb26d8b479333b2f8ab3a50fb6a7f7e99d8039b7c9c09fe6f913125ffe677bb7ec8cc27b7f32e23f1c0800815f989eec11294573
+EBUILD gmsh-4.13.1-r2.ebuild 3212 BLAKE2B a36fa5a1c420cdb808b137795961e116f79ce3d6f524ac46fe1091c2843082374080aa0fec5b671a6c430b44547ab2cf210206825387e8dfb0eccdeede117578 SHA512 fd85b33a5cebfacfd6f78e752308dbde9f4ba86656c73177ffff2b4aecb75ddec8e88f950265f34efd7b71ac6b560a0dee5dfc7cdaa3e9f69751df2b5ef8b065
 MISC metadata.xml 1271 BLAKE2B 7ea0644b5ffb89478ba859f0bbd33fa5fcc8ebb57e64f2ca6ccba8123e23b4a7a44626d5fb1bd416d99071557652b247e90cc05b11d50bdded732f41f2acc524 SHA512 013798cf979fcb7fb954490970abdfc6ebbe23e8263a22cf8791af21f593aa46b7348e7673fa7fa318ce3cb8436c2d58435911984b40be3dafda40253ebcc71c
diff --git a/sci-libs/gmsh/gmsh-4.13.1-r2.ebuild b/sci-libs/gmsh/gmsh-4.13.1-r2.ebuild
new file mode 100644
index 000000000000..c12bdced483b
--- /dev/null
+++ b/sci-libs/gmsh/gmsh-4.13.1-r2.ebuild
@@ -0,0 +1,143 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit cmake desktop fortran-2 python-r1 toolchain-funcs xdg-utils
+
+DESCRIPTION="Three-dimensional finite element mesh generator"
+HOMEPAGE="https://gmsh.info https://gitlab.onelab.info/gmsh/gmsh"
+SRC_URI="https://gmsh.info/src/${P}-source.tgz"
+S="${WORKDIR}/${P}-source"
+
+LICENSE="
+	GPL-2+ free-noncomm
+	alglib? ( MIT )
+	gmm? ( LGPL-2.1+ )
+	metis? ( Apache-2.0 )
+	netgen? ( LGPL-2.1+ )
+	voro? ( BSD )
+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+## cgns is not compiling ATM, maybe fix cgns lib first
+IUSE="+alglib +blas cgns eigen examples +gmm jpeg med metis mpi mumps netgen opencascade petsc pdf png python shared slepc X voro zlib"
+
+REQUIRED_USE="
+	^^ ( blas eigen )
+	mumps? ( blas )
+	slepc? ( petsc )
+	python? ( shared ${PYTHON_REQUIRED_USE} )
+	"
+
+RDEPEND="
+	virtual/fortran
+	X? ( x11-libs/fltk:1=[xft(+)] )
+	alglib? ( sci-libs/alglib )
+	blas? (
+		virtual/blas
+		virtual/lapack
+		sci-libs/fftw:3.0
+	)
+	cgns? (
+		sci-libs/cgnslib
+		sci-libs/hdf5:=[mpi=]
+	)
+	eigen? ( dev-cpp/eigen )
+	gmm? ( sci-mathematics/gmm )
+	jpeg? ( media-libs/libjpeg-turbo )
+	med? (
+		sci-libs/med[mpi=]
+		sci-libs/hdf5:=[mpi=]
+	)
+	metis? ( >=sci-libs/metis-5.2.0 )
+	mpi? ( virtual/mpi[cxx] )
+	mumps? ( sci-libs/mumps[mpi=] )
+	opencascade? ( sci-libs/opencascade:* )
+	pdf? ( app-text/poppler:= )
+	png? ( media-libs/libpng:0 )
+	petsc? ( sci-mathematics/petsc[mpi=] )
+	python? ( ${PYTHON_DEPS} )
+	slepc? ( sci-mathematics/slepc[mpi=] )
+	voro? ( sci-libs/voro++ )
+	zlib? ( sys-libs/zlib )
+	"
+
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	python? ( dev-lang/swig:0 )
+	"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.9.5-opencascade.patch
+	"${FILESDIR}"/${PN}-4.11.1-metis-5-2.patch
+)
+
+pkg_setup() {
+	fortran-2_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=( )
+
+	use blas && \
+		mycmakeargs+=(-DCMAKE_Fortran_COMPILER=$(tc-getF77))
+
+	mycmakeargs+=(
+		-DENABLE_ALGLIB="$(usex alglib)"
+		-DENABLE_BLAS_LAPACK="$(usex blas)"
+		-DENABLE_BUILD_DYNAMIC="$(usex shared)"
+		-DENABLE_CGNS="$(usex cgns)"
+		-DENABLE_EIGEN="$(usex eigen)"
+		-DENABLE_FLTK="$(usex X)"
+		-DENABLE_GMM="$(usex gmm)"
+		-DENABLE_GRAPHICS="$(usex X)"
+		-DENABLE_MED="$(usex med)"
+		-DENABLE_MPI="$(usex mpi)"
+		-DENABLE_METIS="$(usex metis)"
+		-DENABLE_MUMPS="$(usex mumps)"
+		-DENABLE_NETGEN="$(usex netgen)"
+		-DENABLE_OCC="$(usex opencascade)"
+		-DENABLE_PETSC="$(usex petsc)"
+		-DENABLE_POPPLER="$(usex pdf)"
+		-DENABLE_SLEPC="$(usex slepc)"
+		-DENABLE_PRIVATE_API="$(usex shared)"
+		-DENABLE_SYSTEM_CONTRIB="YES"
+		-DENABLE_VOROPP="$(usex voro)"
+		-DENABLE_WRAP_PYTHON="$(usex python)")
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	if use examples ; then
+		dodoc -r examples tutorials
+		docompress -x /usr/share/doc/${PF}/{examples,tutorials}
+	fi
+
+	if use python; then
+		python_foreach_impl python_domodule api/gmsh.py
+	fi
+
+	if use X ; then
+		newicon -s 64 "/${S}/utils/icons/gmsh-no-text.png" gmsh.png
+		make_desktop_entry "/usr/bin/gmsh" "Gmsh ${PV}" "gmsh" "Science;Math"
+	fi
+}
+
+pkg_postinst() {
+	if use X ; then
+		xdg_icon_cache_update
+	fi
+}
+
+pkg_postrm() {
+	if use X ; then
+		xdg_icon_cache_update
+	fi
+}