1 files changed, 59 insertions, 0 deletions
diff --git a/sci-libs/camd/camd-3.0.3.ebuild b/sci-libs/camd/camd-3.0.3.ebuild
new file mode 100644
index 000000000000..b45cf3bd3ee6
--- /dev/null
+++ b/sci-libs/camd/camd-3.0.3.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake-multilib
+
+Sparse_PV="7.0.0"
+Sparse_P="SuiteSparse-${Sparse_PV}"
+DESCRIPTION="Library to order a sparse matrix prior to Cholesky factorization"
+HOMEPAGE="https://people.engr.tamu.edu/davis/suitesparse.html"
+SRC_URI="https://github.com/DrTimothyAldenDavis/SuiteSparse/archive/refs/tags/v${Sparse_PV}.tar.gz -> ${Sparse_P}.gh.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+DEPEND=">=sci-libs/suitesparseconfig-${Sparse_PV}"
+RDEPEND="${DEPEND}"
+BDEPEND="doc? ( virtual/latex-base )"
+
+S="${WORKDIR}/${Sparse_P}/${PN^^}"
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DNSTATIC=ON
+		-DDEMO=$(usex test)
+	)
+	cmake_src_configure
+}
+
+multilib_src_test() {
+	# Run demo files
+	local demofiles=(
+		camd_demo
+		camd_l_demo
+		camd_demo2
+		camd_simple
+	)
+	for i in ${demofiles[@]}; do
+		./"${i}" > "${i}.out" || die "failed to run test ${i}"
+		diff "${S}/Demo/${i}.out" "${i}.out" || die "failed testing ${i}"
+	done
+	einfo "All tests passed"
+}
+
+multilib_src_install() {
+	if use doc; then
+		pushd "${S}/Doc"
+		emake clean
+		rm -rf *.pdf
+		emake
+		popd
+		DOCS="${S}/Doc/*.pdf"
+	fi
+	cmake_src_install
+}