1 files changed, 36 insertions, 0 deletions
diff --git a/sci-libs/brial/brial-1.2.11.ebuild b/sci-libs/brial/brial-1.2.11.ebuild
new file mode 100644
index 000000000000..aa41242e9a0b
--- /dev/null
+++ b/sci-libs/brial/brial-1.2.11.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="A C++ library for polynomials over boolean rings"
+HOMEPAGE="https://github.com/BRiAl/BRiAl"
+SRC_URI="https://github.com/BRiAl/BRiAl/releases/download/${PV}/${P}.tar.bz2"
+
+# The top-level license is GPL2+, but cudd/LICENSE is BSD.
+LICENSE="BSD GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="png"
+
+BDEPEND="virtual/pkgconfig"
+DEPEND="dev-libs/boost
+	sci-libs/m4ri[png=]"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	tc-export PKG_CONFIG
+
+	# with-boost-libdir added to deal with some rather quirky setups
+	# see https://github.com/cschwan/sage-on-gentoo/issues/551
+	econf \
+		--with-boost="${ESYSROOT}"/usr \
+		--with-boost-libdir="${ESYSROOT}"/usr/$(get_libdir)
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+}