summaryrefslogtreecommitdiff
path: root/net-wireless/gnuradio
diff options
context:
space:
mode:
Diffstat (limited to 'net-wireless/gnuradio')
-rw-r--r--net-wireless/gnuradio/Manifest5
-rw-r--r--net-wireless/gnuradio/gnuradio-3.10.9.2-r4.ebuild (renamed from net-wireless/gnuradio/gnuradio-3.10.9.2-r2.ebuild)4
-rw-r--r--net-wireless/gnuradio/gnuradio-3.10.9.2-r5.ebuild254
-rw-r--r--net-wireless/gnuradio/gnuradio-9999.ebuild4
4 files changed, 261 insertions, 6 deletions
diff --git a/net-wireless/gnuradio/Manifest b/net-wireless/gnuradio/Manifest
index 35c389b75a1f..0544b167ce89 100644
--- a/net-wireless/gnuradio/Manifest
+++ b/net-wireless/gnuradio/Manifest
@@ -1,5 +1,6 @@
AUX PR7093.patch 3317 BLAKE2B d369dfa91c8de3c62d1c14be52f5ad9491bf10f8fb904295bb92497a43150bcf9d1576442f3087b439e54fb4dac572d421e3cac95d71d01604cf329284e7ff5a SHA512 01758de8ecb721fcaadd31d478551420290b5e59c9b8fa3d421d4170665915c21e50ed765a9647b81d4f6acf71099c98628b823a66897b4f5e57df3c3b2643ba
DIST gnuradio-3.10.9.2.tar.gz 4413832 BLAKE2B 69443e9b6893c6cb9db1678c28ac0fd01fe57e81438903612f7f65908fede257dab06a98fa90da25fe8caa6befb731ba51759509ace10a5541cae3e9d055a5db SHA512 5eca8dd21def7354ab8bd3b98a5780f80bc71b0dd8f556a50def157964e121c7ba6a8a8dc96584f6b15a6b2d7e0391fe77f5c72ba31c1c5b49a76306dd6f78cd
-EBUILD gnuradio-3.10.9.2-r2.ebuild 6757 BLAKE2B 5c22e40e9cc0ff6c120636a557cb1701ddb59546f746fb429e8a027a60946b650b9163e685e839ed6671c664f2f8d7ff7234d76025a48b729d7110bf868c3484 SHA512 030735ff375c8e1967f3a0e13af85bab26a05fda5d32b78817fa10679e2090cb22f98f592e98e8e29488609b105e8574324d8dab9513dc785b492b297196089f
-EBUILD gnuradio-9999.ebuild 6718 BLAKE2B 7a14301346e1793d47eb7a47810841de038053263c1ec0f0a1fa7d64540708cdf98d27fde46c12c8352e57c6dab75e367ab306d3ec2088ea372fc51dacb4b111 SHA512 6e9c48c7c730a2274c45a4b9b7331a57041e19d40711af7f37095c09535f6b18e003a1ae91aafff0e76084a6692101a5dbc86ac0782ee70382cdb41350d6f761
+EBUILD gnuradio-3.10.9.2-r4.ebuild 6714 BLAKE2B 7967f69ea02aeb7cffc3caa6747f0161819c089db77e2bf72233d011a04436d7d9b5bfea4259f7f6e7b34263b67ac6ff0df8d7358fc086da72b4de40ce31d040 SHA512 d758532032da8b77fa08af1bfe5f29d6478eb75b4c56827a040ed5c5412f72e3ffbcf748108e6b52547c7ae13baebc4246902082932a191d32f1977e8daa049a
+EBUILD gnuradio-3.10.9.2-r5.ebuild 7116 BLAKE2B 653439d09775342de9cfdd43f501c60b4a91a00e2643c9066e2e5f467dd0a09763a02f5ce2b11fb0d3acd4e024a8021ac8e3f49256fdbd152461ecfb3e96aacb SHA512 923e13616608965df1ce78b44c0b3cc91d5c623741c455ebe979538c3cf3b53d093e949de95d355f4bce0226e77c748caec0402e4f72644d8475927a50585f15
+EBUILD gnuradio-9999.ebuild 6675 BLAKE2B fad563acf07851d285129195c48c5846aa94b348a63531cc087985e63d18820b53b94b87e7327e8360a1f44091f381b5ea476b9fb42ae71346d9747b74b5e619 SHA512 c7a611592ebcf67a4330112b6b991ba81f223c07851d00232d6ce0b3a6c28407b1b0e4dd58da78a9574cd83a3f39f317781d6ecf104ca1b9a77b6d46a29703e5
MISC metadata.xml 1869 BLAKE2B de75463e64f4f3352d8959d795de15d9345e52f491f61fc824db738bccc4e2ae0487d988c22c17149f80cda5478a5bfbda03a6c5239970423371a2a76f374003 SHA512 69477d22de9e60b7f7420b14437265771391320d7c362d51b81fb573671568cf6b6b39ba50be1ad7c8bb07ed219998cf474e19b663f4a65b0e2cc69feef017a0
diff --git a/net-wireless/gnuradio/gnuradio-3.10.9.2-r2.ebuild b/net-wireless/gnuradio/gnuradio-3.10.9.2-r4.ebuild
index e18205314679..8f673a36f670 100644
--- a/net-wireless/gnuradio/gnuradio-3.10.9.2-r2.ebuild
+++ b/net-wireless/gnuradio/gnuradio-3.10.9.2-r4.ebuild
@@ -89,12 +89,12 @@ RDEPEND="${PYTHON_DEPS}
dev-qt/qtwidgets:5
)
soapy? (
- $(python_gen_cond_dep 'net-wireless/soapysdr:=[${PYTHON_USEDEP}]')
+ net-wireless/soapysdr:=[${PYTHON_SINGLE_USEDEP}]
)
sdl? ( >=media-libs/libsdl-1.2.0 )
trellis? ( dev-python/scipy )
uhd? (
- $(python_gen_cond_dep '>=net-wireless/uhd-3.9.6:=[${PYTHON_SINGLE_USEDEP}]')
+ >=net-wireless/uhd-3.9.6:=[${PYTHON_SINGLE_USEDEP}]
)
utils? (
$(python_gen_cond_dep 'dev-python/click[${PYTHON_USEDEP}]
diff --git a/net-wireless/gnuradio/gnuradio-3.10.9.2-r5.ebuild b/net-wireless/gnuradio/gnuradio-3.10.9.2-r5.ebuild
new file mode 100644
index 000000000000..6aac60293382
--- /dev/null
+++ b/net-wireless/gnuradio/gnuradio-3.10.9.2-r5.ebuild
@@ -0,0 +1,254 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{9..12} )
+
+CMAKE_BUILD_TYPE="None"
+inherit cmake desktop python-single-r1 virtualx xdg-utils
+
+DESCRIPTION="Toolkit that provides signal processing blocks to implement software radios"
+HOMEPAGE="https://www.gnuradio.org/"
+LICENSE="GPL-3"
+SLOT="0/${PV}"
+
+if [[ ${PV} =~ "9999" ]]; then
+ EGIT_REPO_URI="https://github.com/gnuradio/gnuradio.git"
+ EGIT_BRANCH="maint-3.10"
+ inherit git-r3
+else
+ SRC_URI="https://github.com/gnuradio/gnuradio/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+ KEYWORDS="amd64 ~arm ~riscv ~x86"
+fi
+
+IUSE="+audio +alsa +analog +digital channels ctrlport doc dtv examples fec +filter grc iio jack modtool network oss performance-counters portaudio +qt5 sdl soapy test trellis uhd vocoder +utils wavelet zeromq"
+
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+ audio? ( || ( alsa oss jack portaudio ) )
+ alsa? ( audio )
+ jack? ( audio )
+ oss? ( audio )
+ portaudio? ( audio )
+ analog? ( filter )
+ channels? ( filter analog qt5 )
+ digital? ( filter analog )
+ dtv? ( filter analog fec )
+ modtool? ( utils )
+ qt5? ( filter )
+ test? ( channels )
+ trellis? ( analog digital )
+ uhd? ( filter analog )
+ vocoder? ( filter analog )
+ wavelet? ( analog )
+"
+
+RDEPEND="${PYTHON_DEPS}
+ $(python_gen_cond_dep 'dev-libs/boost:=[python,${PYTHON_USEDEP}]')
+ dev-libs/gmp:=
+ dev-libs/log4cpp:=
+ $(python_gen_cond_dep 'dev-python/jsonschema[${PYTHON_USEDEP}]')
+ dev-libs/spdlog:=
+ dev-libs/libfmt:=
+ sci-libs/fftw:3.0=
+ sci-libs/volk:=
+ media-libs/libsndfile
+ sys-libs/libunwind
+ alsa? ( media-libs/alsa-lib:= )
+ ctrlport? (
+ $(python_gen_cond_dep 'dev-python/thrift[${PYTHON_USEDEP}]')
+ )
+ fec? (
+ sci-libs/gsl:=
+ dev-python/scipy
+ )
+ filter? (
+ dev-python/scipy
+ $(python_gen_cond_dep 'dev-python/pyqtgraph[${PYTHON_USEDEP}]')
+ )
+ grc? (
+ $(python_gen_cond_dep 'dev-python/mako[${PYTHON_USEDEP}]
+ dev-python/numpy[${PYTHON_USEDEP}]
+ dev-python/pygobject:3[${PYTHON_USEDEP}]
+ dev-python/pyyaml[${PYTHON_USEDEP}]')
+ x11-libs/gtk+:3[introspection]
+ x11-libs/pango[introspection]
+ )
+ iio? (
+ net-libs/libiio:=
+ net-libs/libad9361-iio:=
+ )
+ jack? ( virtual/jack )
+ portaudio? ( >=media-libs/portaudio-19_pre )
+ qt5? (
+ $(python_gen_cond_dep 'dev-python/PyQt5[opengl,${PYTHON_USEDEP}]')
+ dev-qt/qtcore:5
+ dev-qt/qtgui:5
+ x11-libs/qwt:6=[qt5(+)]
+ dev-qt/qtwidgets:5
+ )
+ soapy? (
+ net-wireless/soapysdr:=[${PYTHON_SINGLE_USEDEP}]
+ )
+ sdl? ( >=media-libs/libsdl-1.2.0 )
+ trellis? ( dev-python/scipy )
+ uhd? (
+ >=net-wireless/uhd-3.9.6:=[${PYTHON_SINGLE_USEDEP}]
+ )
+ utils? (
+ $(python_gen_cond_dep 'dev-python/click[${PYTHON_USEDEP}]
+ dev-python/click-plugins[${PYTHON_USEDEP}]
+ dev-python/mako[${PYTHON_USEDEP}]
+ dev-python/matplotlib[${PYTHON_USEDEP}]')
+ )
+ vocoder? (
+ media-sound/gsm
+ >=media-libs/codec2-0.8.1:=
+ )
+ wavelet? (
+ sci-libs/gsl:=
+ sci-libs/lapack
+ )
+ zeromq? ( >=net-libs/zeromq-2.1.11:= )
+"
+
+DEPEND="${RDEPEND}
+ app-text/docbook-xml-dtd:4.2
+ $(python_gen_cond_dep 'dev-python/pybind11[${PYTHON_USEDEP}]')
+ virtual/pkgconfig
+ doc? (
+ >=app-text/doxygen-1.5.7.1
+ <dev-libs/mathjax-3
+ )
+ grc? ( x11-misc/xdg-utils )
+ modtool? ( $(python_gen_cond_dep 'dev-python/pygccxml[${PYTHON_USEDEP}]') )
+ oss? ( virtual/os-headers )
+ test? (
+ >=dev-util/cppunit-1.9.14
+ dev-python/pyzmq
+ )
+ zeromq? ( net-libs/cppzmq )
+"
+
+PATCHES=( "${FILESDIR}/PR7093.patch" )
+
+src_prepare() {
+ xdg_environment_reset #534582
+
+ use !alsa && sed -i 's#version.h#version-nonexistent.h#' cmake/Modules/FindALSA.cmake
+ use !jack && sed -i 's#jack.h#jack-nonexistent.h#' cmake/Modules/FindJACK.cmake
+ use !oss && sed -i 's#soundcard.h#oss-nonexistent.h#g' cmake/Modules/FindOSS.cmake
+ use !portaudio && sed -i 's#portaudio.h#portaudio-nonexistent.h#g' cmake/Modules/FindPORTAUDIO.cmake
+
+ # remove empty test case (see https://github.com/gnuradio/gnuradio/commit/21df528)
+ # fails with Python 3.12
+ rm "${S}"/gr-digital/python/digital/qa_digital.py || die
+ # fix test failure due to deprecated syntax for numpy
+ # see https://github.com/gnuradio/gnuradio/commit/a306e11
+ sed -i -e "s/np.alltrue/np.all/g" \
+ "${S}"/gnuradio-runtime/python/pmt/qa_pmt_to_python.py || die
+ cmake_src_prepare
+}
+
+src_configure() {
+ local mycmakeargs=(
+ -DENABLE_DEFAULT=OFF
+ -DENABLE_GNURADIO_RUNTIME=ON
+ -DENABLE_PYTHON=ON
+ -DENABLE_GR_BLOCKS=ON
+ -DENABLE_GR_ANALOG="$(usex analog)"
+ -DENABLE_GR_AUDIO=ON
+ -DENABLE_GR_CHANNELS="$(usex channels)"
+ -DENABLE_GR_CTRLPORT="$(usex ctrlport)"
+ -DENABLE_GR_DIGITAL="$(usex digital)"
+ -DENABLE_DOXYGEN="$(usex doc)"
+ -DENABLE_GR_DTV="$(usex dtv)"
+ -DENABLE_GR_FEC="$(usex fec)"
+ -DENABLE_GR_FFT=ON
+ -DENABLE_GR_FILTER="$(usex filter)"
+ -DENABLE_GRC="$(usex grc)"
+ -DENABLE_GR_IIO="$(usex iio)"
+ -DENABLE_GR_MODTOOL="$(usex modtool)"
+ -DENABLE_GR_BLOCKTOOL="$(usex modtool)"
+ -DENABLE_GR_NETWORK="$(usex network)"
+ -DENABLE_GR_PDU=ON
+ -DENABLE_PERFORMANCE_COUNTERS="$(usex performance-counters)"
+ -DENABLE_TESTING="$(usex test)"
+ -DENABLE_GR_QTGUI="$(usex qt5)"
+ -DENABLE_GR_SOAPY="$(usex soapy)"
+ -DENABLE_GR_TRELLIS="$(usex trellis)"
+ -DENABLE_GR_UHD="$(usex uhd)"
+ -DENABLE_GR_UTILS="$(usex utils)"
+ -DENABLE_GR_VIDEO_SDL="$(usex sdl)"
+ -DENABLE_GR_VOCODER="$(usex vocoder)"
+ -DENABLE_GR_WAVELET="$(usex wavelet)"
+ -DENABLE_GR_ZEROMQ="$(usex zeromq)"
+ -DSYSCONFDIR="${EPREFIX}"/etc
+ -DPYTHON_EXECUTABLE="${PYTHON}"
+ -DGR_PYTHON_DIR="$(python_get_sitedir)"
+ -DGR_PKG_DOC_DIR="${EPREFIX}/usr/share/doc/${PF}"
+ -DMATHJAX2_ROOT="${EPREFIX}/usr/share/mathjax"
+ )
+ cmake_src_configure
+}
+
+src_install() {
+ cmake_src_install
+
+ if use examples ; then
+ dodir /usr/share/doc/${PF}/
+ mv "${ED}"/usr/share/${PN}/examples "${ED}"/usr/share/doc/${PF}/ || die
+ docompress -x /usr/share/doc/${PF}/examples
+ else
+ # It seems that the examples are always installed
+ rm -rf "${ED}"/usr/share/${PN}/examples || die
+ fi
+
+ if use doc || use examples; then
+ #this doesn't appear useful
+ rm -rf "${ED}"/usr/share/doc/${PF}/xml || die
+ fi
+
+ # Remove duplicated icons, MIME and desktop files and installation script
+ rm -rf "${ED}"/usr/share/${PN}/grc/freedesktop || die
+ rm -f "${ED}"/usr/libexec/${PN}/grc_setup_freedesktop || die
+
+ # Install icons, menu items and mime-types for GRC
+ if use grc ; then
+ local fd_path="${S}/grc/scripts/freedesktop"
+ insinto /usr/share/mime/packages
+ doins "${fd_path}/${PN}-grc.xml"
+
+ domenu "${fd_path}/${PN}-grc.desktop"
+ for size in 16 24 32 48 64 128 256; do
+ newicon -s $size "${fd_path}/"grc-icon-$size.png ${PN}-grc.png
+ done
+ fi
+
+ python_fix_shebang "${ED}"
+ # Remove incorrectly byte-compiled Python files and replace
+ find "${ED}"/usr/lib* -name "*.py[co]" -exec rm {} \; || die
+ python_optimize
+}
+
+src_test() {
+ # skip test which needs internet
+ virtx cmake_src_test -E metainfo_test --output-on-failure
+}
+
+pkg_postinst() {
+ if use grc ; then
+ xdg_desktop_database_update
+ xdg_icon_cache_update
+ xdg_mimeinfo_database_update
+ fi
+}
+
+pkg_postrm() {
+ if use grc ; then
+ xdg_desktop_database_update
+ xdg_icon_cache_update
+ xdg_mimeinfo_database_update
+ fi
+}
diff --git a/net-wireless/gnuradio/gnuradio-9999.ebuild b/net-wireless/gnuradio/gnuradio-9999.ebuild
index 04191082fbfe..ce5367b7d75a 100644
--- a/net-wireless/gnuradio/gnuradio-9999.ebuild
+++ b/net-wireless/gnuradio/gnuradio-9999.ebuild
@@ -89,12 +89,12 @@ RDEPEND="${PYTHON_DEPS}
dev-qt/qtwidgets:5
)
soapy? (
- $(python_gen_cond_dep 'net-wireless/soapysdr:=[${PYTHON_USEDEP}]')
+ net-wireless/soapysdr:=[${PYTHON_SINGLE_USEDEP}]
)
sdl? ( >=media-libs/libsdl-1.2.0 )
trellis? ( dev-python/scipy )
uhd? (
- $(python_gen_cond_dep '>=net-wireless/uhd-3.9.6:=[${PYTHON_SINGLE_USEDEP}]')
+ >=net-wireless/uhd-3.9.6:=[${PYTHON_SINGLE_USEDEP}]
)
utils? (
$(python_gen_cond_dep 'dev-python/click[${PYTHON_USEDEP}]
generated by cgit v1.2.3 (git 2.25.1) at 2024-11-05 21:35:07 +0000