1 files changed, 61 insertions, 0 deletions
diff --git a/net-vpn/networkmanager-wireguard/networkmanager-wireguard-0_pre20181128.ebuild b/net-vpn/networkmanager-wireguard/networkmanager-wireguard-0_pre20181128.ebuild
new file mode 100644
index 000000000000..0769e9ac9da7
--- /dev/null
+++ b/net-vpn/networkmanager-wireguard/networkmanager-wireguard-0_pre20181128.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+EGIT_COMMIT="61646ade26750c52626a44b025cb1b165681c662"
+MY_PN="${PN/network/network-}"
+
+DESCRIPTION="NetworkManager WireGuard plugin"
+HOMEPAGE="https://github.com/max-moser/network-manager-wireguard"
+SRC_URI="https://github.com/max-moser/${MY_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+glib +gtk +nls"
+
+RDEPEND="
+	net-misc/networkmanager
+	net-vpn/wireguard
+	glib? ( dev-libs/glib )
+	gtk? (
+		app-crypt/libsecret
+		gnome-extra/nm-applet
+		x11-libs/gtk+:3
+	)
+"
+
+DEPEND="${RDEPEND}"
+
+BDEPEND="
+	virtual/pkgconfig
+	nls? (
+		dev-util/intltool
+		sys-devel/gettext
+	)
+"
+
+S="${WORKDIR}/${MY_PN}-${EGIT_COMMIT}"
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-lto
+		--disable-more-warnings
+		--disable-static
+		$(use_with glib	libnm-glib)
+		$(use_with gtk gnome)
+		$(use_enable nls)
+		--with-dist-version="Gentoo"
+	)
+
+	econf "${myeconfargs[@]}"
+}