1 files changed, 58 insertions, 0 deletions
diff --git a/net-misc/seafile-client/seafile-client-8.0.2-r1.ebuild b/net-misc/seafile-client/seafile-client-8.0.2-r1.ebuild
new file mode 100644
index 000000000000..d2c2f9add43a
--- /dev/null
+++ b/net-misc/seafile-client/seafile-client-8.0.2-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+RELEASE_COMMIT="837be8efd5cab4aea8fc1138ab91e93539a4e010"
+
+inherit cmake xdg-utils
+
+DESCRIPTION="Seafile desktop client"
+HOMEPAGE="https://www.seafile.com/ https://github.com/haiwen/seafile-client/"
+SRC_URI="https://github.com/haiwen/${PN}/archive/${RELEASE_COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="shibboleth test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="dev-db/sqlite:3
+	dev-libs/jansson:=
+	dev-libs/libevent:=
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtwidgets:5
+	dev-libs/openssl:=
+	net-libs/libsearpc
+	~net-misc/seafile-${PV}
+	shibboleth? ( dev-qt/qtwebengine:5[widgets] )"
+DEPEND="${RDEPEND}
+	test? ( dev-qt/qttest:5 )"
+BDEPEND="dev-qt/linguist-tools:5"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-select-qt5.patch"
+	"${FILESDIR}/${PN}-7.0.9-qt-5.15.patch"
+	"${FILESDIR}/${PN}-8.0.1-glib-2.68.0.patch"
+)
+
+S="${WORKDIR}/${PN}-${RELEASE_COMMIT}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_SHIBBOLETH_SUPPORT="$(usex shibboleth)"
+		-DBUILD_TESTING="$(usex test)"
+	)
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}