1 files changed, 39 insertions, 0 deletions
diff --git a/net-misc/minissdpd/minissdpd-1.5.20211105.ebuild b/net-misc/minissdpd/minissdpd-1.5.20211105.ebuild
new file mode 100644
index 000000000000..b07a95967646
--- /dev/null
+++ b/net-misc/minissdpd/minissdpd-1.5.20211105.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit toolchain-funcs verify-sig
+
+DESCRIPTION="MiniSSDP Daemon"
+HOMEPAGE="http://miniupnp.free.fr/"
+SRC_URI="http://miniupnp.free.fr/files/${P}.tar.gz
+	verify-sig? ( http://miniupnp.free.fr/files/${P}.tar.gz.sig )"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="net-libs/libnfnetlink"
+RDEPEND="${DEPEND}
+	|| ( net-misc/miniupnpd net-libs/miniupnpc )"
+BDEPEND="
+	verify-sig? ( app-crypt/openpgp-keys-miniupnp )"
+
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/miniupnp.asc
+
+src_configure() {
+	sed -i -e '/#define HAVE_IP_MREQN/{s:/[*]::;s:[*]/::;}' config.h || die
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)"
+}
+
+src_install() {
+	emake DESTDIR="${ED}" install
+	# note: we overwrite upstream's init.d
+	newinitd "${FILESDIR}/${PN}.initd-r2" ${PN}
+	newconfd "${FILESDIR}/${PN}.confd" ${PN}
+	dodoc Changelog.txt README
+	doman minissdpd.1
+}