1 files changed, 65 insertions, 0 deletions
diff --git a/net-misc/gnome-connections/gnome-connections-44_rc.ebuild b/net-misc/gnome-connections/gnome-connections-44_rc.ebuild
new file mode 100644
index 000000000000..74f7c0599466
--- /dev/null
+++ b/net-misc/gnome-connections/gnome-connections-44_rc.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson vala xdg
+
+DESCRIPTION="A remote desktop client for the GNOME desktop environment"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/connections"
+SRC_URI="https://download.gnome.org/sources/${PN}/44/${PN}-44.rc.tar.xz"
+S="${WORKDIR}/${PN}-44.rc"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	dev-libs/gobject-introspection
+	>=dev-libs/glib-2.50:2
+	>=x11-libs/gtk+-3.22:3[introspection]
+	>=net-libs/gtk-vnc-0.4.4[pulseaudio,vala]
+	>=gui-libs/libhandy-1.6.0:1[vala]
+	>=dev-libs/libxml2-2.7.8
+	app-crypt/libsecret[vala]
+
+	>=net-misc/freerdp-2.0.0:0=
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	$(vala_depend)
+	dev-libs/glib
+	dev-util/glib-utils
+	dev-util/itstool
+	sys-devel/gettext
+	virtual/pkgconfig
+
+	test? (
+		dev-libs/appstream-glib
+		dev-util/desktop-file-utils
+	)
+"
+
+src_prepare() {
+	default
+	vala_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dprofile=default
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}