summaryrefslogtreecommitdiff
path: root/net-mail/qmail-autoresponder/qmail-autoresponder-2.0-r1.ebuild
diff options
context:
space:
mode:
Diffstat (limited to 'net-mail/qmail-autoresponder/qmail-autoresponder-2.0-r1.ebuild')
-rw-r--r--net-mail/qmail-autoresponder/qmail-autoresponder-2.0-r1.ebuild54
1 files changed, 54 insertions, 0 deletions
diff --git a/net-mail/qmail-autoresponder/qmail-autoresponder-2.0-r1.ebuild b/net-mail/qmail-autoresponder/qmail-autoresponder-2.0-r1.ebuild
new file mode 100644
index 000000000000..1580fd65df44
--- /dev/null
+++ b/net-mail/qmail-autoresponder/qmail-autoresponder-2.0-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="Rate-limited autoresponder for qmail"
+HOMEPAGE="https://untroubled.org/qmail-autoresponder/"
+SRC_URI="https://untroubled.org/qmail-autoresponder/archive/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="GPL-2+"
+KEYWORDS="~alpha ~amd64 ~hppa ~mips ~ppc ~sparc ~x86"
+IUSE="mysql"
+
+DEPEND="
+ >=dev-libs/bglibs-2.04
+ mysql? ( dev-db/mysql-connector-c:0= )
+"
+RDEPEND="
+ ${DEPEND}
+ virtual/qmail
+ mysql? ( virtual/mysql )
+"
+
+PATCHES=(
+ "${FILESDIR}/${P}-clear-struct.patch"
+ "${FILESDIR}/${P}-drop-mysql.patch"
+)
+
+src_configure() {
+ echo "$(tc-getCC) ${CFLAGS}" > conf-cc || die
+ echo "$(tc-getCC) ${LDFLAGS}" > conf-ld || die
+}
+
+src_compile() {
+ emake qmail-autoresponder
+ if use mysql; then
+ emake qmail-autoresponder-mysql
+ fi
+}
+
+src_install() {
+ dobin qmail-autoresponder
+ doman qmail-autoresponder.1
+ if use mysql; then
+ dobin qmail-autoresponder-mysql
+ doman qmail-autoresponder-mysql.1
+ dodoc schema.mysql
+ fi
+
+ dodoc ANNOUNCEMENT NEWS README TODO ChangeLog procedure.txt
+}