1 files changed, 44 insertions, 0 deletions
diff --git a/net-libs/libyang/libyang-1.0.240.ebuild b/net-libs/libyang/libyang-1.0.240.ebuild
new file mode 100644
index 000000000000..463140a483d6
--- /dev/null
+++ b/net-libs/libyang/libyang-1.0.240.ebuild
@@ -0,0 +1,44 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+CMAKE_ECLASS=cmake
+inherit cmake-multilib
+
+DESCRIPTION="YANG data modeling language library"
+HOMEPAGE="https://github.com/CESNET/libyang"
+SRC_URI="https://github.com/CESNET/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc test"
+
+RDEPEND="dev-libs/libpcre[${MULTILIB_USEDEP}]"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-devel/bison
+	sys-devel/flex
+	doc? ( app-doc/doxygen[dot] )"
+
+RESTRICT="!test? ( test )"
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DENABLE_BUILD_TESTS=$(usex test)
+		-DENABLE_LYD_PRIV=yes
+		-DGEN_LANGUAGE_BINDINGS=no
+	)
+	cmake_src_configure
+}
+
+multilib_src_compile() {
+	cmake_src_compile
+
+	multilib_is_native_abi && use doc && cmake_src_compile doc
+}
+
+multilib_src_install_all() {
+	use doc && dodoc -r doc/.
+}