3 files changed, 199 insertions, 0 deletions
diff --git a/net-irc/Manifest.gz b/net-irc/Manifest.gz
index 09de01baa99c..6eb29e75f477 100644
--- a/net-irc/Manifest.gz
+++ b/net-irc/Manifest.gz
diff --git a/net-irc/weechat/Manifest b/net-irc/weechat/Manifest
index cf9f5cec0bd8..8c794640b48c 100644
--- a/net-irc/weechat/Manifest
+++ b/net-irc/weechat/Manifest
@@ -19,6 +19,7 @@ EBUILD weechat-4.3.2-r1.ebuild 4995 BLAKE2B 3c9df96cc33a635faa6f18264f04e7860cff
 EBUILD weechat-4.3.4.ebuild 4994 BLAKE2B b524a366982707e7211cb1737525b71630eaecd586f4a56d52390a5a40d8908584b2b15eaf522114e959e9f4706d7ed696532b73398cf53627f9d2446d0b59b1 SHA512 ea038918bb47528c19eb3c7950d9db9cf032cafc48b163ee2100157b05b5c4aff392f4b14d58df9ec69aec0ebc64f54a71f555a597c75627f53a7bbb70a7e629
 EBUILD weechat-4.3.6.ebuild 4996 BLAKE2B 9a990aa051aa62ee99a629874428361edfdef3c1befab8da4a16bbaece0499e972dc8b910b926249b68aad7651e8521ace0af9971a096dbf8832706513105ac7 SHA512 6bdc1395ba624e42de4dfe9ba6c89e1ae7ceddc4d595d28ffcc81c9f234611d45a0edf07cd7c91e3a9d9e2ffdd455e6e4dff3f88e7ea8ac3b50376da2ade403e
 EBUILD weechat-4.4.1.ebuild 4939 BLAKE2B c49c1d79450050b98243c9a3ccddc622b05a0e1fbd3ff51164123a7d871301b68e3fbf8cb50e3cfbbef95943ef338b3bca4963980a085307de7302d2394ef8c9 SHA512 dc6c36af6090334f8498459f5c6577b8e7958b802c5dd37fd04554f7bb13a0aec6f8c78f6c773739aaa659065bb460384142d1b149ef8377a10f77bdccbe535e
+EBUILD weechat-4.4.2-r100.ebuild 5143 BLAKE2B d3d31f940300c6dd6ca08370a4c9207bae29e28fbbe5a1f9f572c4ff6f49fe563a6946c0216e4cfed8b3e6b4945a726c6841cbe48e6b3935354fdbbd818264a1 SHA512 5df966142e141dd952fd01bb93e0661bd78fa96fe8e204558560e9c3e985c950f9d1293c8a4c10d95e814b0efa64813d71b65cea4737f70bbbfd5dffff2d7811
 EBUILD weechat-4.4.2.ebuild 4939 BLAKE2B c49c1d79450050b98243c9a3ccddc622b05a0e1fbd3ff51164123a7d871301b68e3fbf8cb50e3cfbbef95943ef338b3bca4963980a085307de7302d2394ef8c9 SHA512 dc6c36af6090334f8498459f5c6577b8e7958b802c5dd37fd04554f7bb13a0aec6f8c78f6c773739aaa659065bb460384142d1b149ef8377a10f77bdccbe535e
 EBUILD weechat-9999.ebuild 5143 BLAKE2B d3d31f940300c6dd6ca08370a4c9207bae29e28fbbe5a1f9f572c4ff6f49fe563a6946c0216e4cfed8b3e6b4945a726c6841cbe48e6b3935354fdbbd818264a1 SHA512 5df966142e141dd952fd01bb93e0661bd78fa96fe8e204558560e9c3e985c950f9d1293c8a4c10d95e814b0efa64813d71b65cea4737f70bbbfd5dffff2d7811
 MISC metadata.xml 1535 BLAKE2B 654e2479cf1fa904e9f91a9a1214ac4bdc17da43ae6c0f344588c68a7dc1fbf200f08911cbc673debe71c7d72488390cbb30c33f6c504e5b1a68404c86a4ee21 SHA512 82b181c67a102f7625342c933c953c6e2fef2fcaec8abb11eb2237983590db8e1947e615e806c17c73efb55f47963a69a63d56174da9b3613f20d15aa5967876
diff --git a/net-irc/weechat/weechat-4.4.2-r100.ebuild b/net-irc/weechat/weechat-4.4.2-r100.ebuild
new file mode 100644
index 000000000000..51c44dccd853
--- /dev/null
+++ b/net-irc/weechat/weechat-4.4.2-r100.ebuild
@@ -0,0 +1,198 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+GUILE_COMPAT=( 2-2 3-0 )
+LUA_COMPAT=( lua5-{1..4} )
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit cmake guile-single lua-single python-single-r1 xdg
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/weechat/weechat.git"
+else
+	inherit verify-sig
+	SRC_URI="https://weechat.org/files/src/${P}.tar.xz
+		verify-sig? ( https://weechat.org/files/src/${P}.tar.xz.asc )"
+	VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/weechat.org.asc
+	BDEPEND+="verify-sig? ( sec-keys/openpgp-keys-weechat )"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86 ~x64-macos"
+fi
+
+DESCRIPTION="Portable and multi-interface IRC client"
+HOMEPAGE="https://weechat.org/"
+
+LICENSE="GPL-3+"
+SLOT="0/${PV}"
+
+NETWORKS="+irc"
+PLUGINS="+alias +buflist +charset +exec +fifo +fset +logger +relay +scripts +spell +trigger +typing +xfer"
+# dev-lang/v8 was dropped from Gentoo so we can't enable javascript support
+# dev-lang/php eclass support is lacking, php plugins don't work. bug #705702
+SCRIPT_LANGS="guile lua +perl +python ruby tcl"
+LANGS=" cs de es fr hu it ja pl pt pt_BR ru sr tr"
+IUSE="doc enchant man nls relay-api selinux test +zstd ${SCRIPT_LANGS} ${PLUGINS} ${INTERFACES} ${NETWORKS}"
+
+REQUIRED_USE="
+	enchant? ( spell )
+	guile? ( ${GUILE_REQUIRED_USE} )
+	lua? ( ${LUA_REQUIRED_USE} )
+	python? ( ${PYTHON_REQUIRED_USE} )
+	test? ( nls )
+	relay-api? ( relay )
+"
+
+RDEPEND="
+	dev-libs/libgcrypt:0=
+	net-libs/gnutls:=
+	sys-libs/ncurses:0=
+	sys-libs/zlib:=
+	net-misc/curl[ssl]
+	charset? ( virtual/libiconv )
+	guile? ( ${GUILE_DEPS} )
+	lua? ( ${LUA_DEPS} )
+	nls? ( virtual/libintl )
+	perl? (
+		dev-lang/perl:=
+		virtual/libcrypt:=
+	)
+	python? ( ${PYTHON_DEPS} )
+	relay-api? ( dev-libs/cJSON )
+	ruby? (
+		|| (
+			dev-lang/ruby:3.3
+			dev-lang/ruby:3.2
+			dev-lang/ruby:3.1
+		)
+	)
+	selinux? ( sec-policy/selinux-irc )
+	spell? (
+		enchant? ( app-text/enchant:* )
+		!enchant? ( app-text/aspell )
+	)
+	tcl? ( >=dev-lang/tcl-8.4.15:0= )
+	zstd? ( app-arch/zstd:= )
+"
+
+DEPEND="${RDEPEND}
+	test? ( dev-util/cpputest )
+"
+
+BDEPEND+="
+	virtual/pkgconfig
+	doc? ( >=dev-ruby/asciidoctor-1.5.4 )
+	man? ( >=dev-ruby/asciidoctor-1.5.4 )
+	nls? ( >=sys-devel/gettext-0.15 )
+"
+
+DOCS="AUTHORS.md CHANGELOG.md CONTRIBUTING.md UPGRADING.md README.md"
+
+RESTRICT="!test? ( test )"
+
+pkg_setup() {
+	use guile && guile-single_pkg_setup
+	use lua && lua-single_pkg_setup
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	cmake_src_prepare
+
+	use guile && guile_bump_sources
+
+	# install only required translations
+	local i
+	for i in ${LANGS} ; do
+		if ! has ${i} ${LINGUAS-${i}} ; then
+			sed -i \
+				-e "/${i}.po/d" \
+				po/CMakeLists.txt || die
+		fi
+	done
+
+	# install only required documentation ; en always
+	local j
+	for i in $(grep -e 'set(.*en.*)$' doc/CMakeLists.txt \
+			| sed -e 's/.*set(\(\w\+\).*/\1/'); do
+		for j in $(grep set.${i} doc/CMakeLists.txt \
+				| sed -e "s/.*${i}\(.*\)).*/\1/" -e 's/ en//'); do
+			if ! has ${j} ${LINGUAS-${j}} ; then
+				sed -i \
+					-e "s/\(set(${i}.*\) ${j}/\1/" \
+					doc/CMakeLists.txt || die
+			fi
+		done
+	done
+
+	# install docs in correct directory
+	sed -i "s#\${DATAROOTDIR}/doc/\${PROJECT_NAME}#\0-${PVR}/html#" doc/CMakeLists.txt || die
+
+	if [[ ${CHOST} == *-darwin* ]]; then
+		# fix linking error on Darwin
+		sed -i "s/+ get_config_var('LINKFORSHARED')//" \
+			cmake/FindPython.cmake || die
+		# allow to find the plugins by default
+		sed -i 's/".so,.dll"/".bundle,.so,.dll"/' \
+			src/core/wee-config.c || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DLIBDIR="${EPREFIX}/usr/$(get_libdir)"
+		-DENABLE_JAVASCRIPT=OFF
+		-DENABLE_LARGEFILE=ON
+		-DENABLE_NCURSES=ON
+		-DENABLE_PHP=OFF
+		-DENABLE_ALIAS=$(usex alias)
+		-DENABLE_BUFLIST=$(usex buflist)
+		-DENABLE_CHARSET=$(usex charset)
+		# -DENABLE_DOC requires all plugins (except javascript).
+		# https://github.com/weechat/weechat/blob/v4.0.2/CMakeLists.txt#L144
+		# Impossible since php was dropped in net-irc/weechat-3.5.r1.ebuild. bug #705702
+		-DENABLE_DOC=OFF
+		-DENABLE_DOC_INCOMPLETE=$(usex doc)
+		-DENABLE_ENCHANT=$(usex enchant)
+		-DENABLE_EXEC=$(usex exec)
+		-DENABLE_FIFO=$(usex fifo)
+		-DENABLE_FSET=$(usex fset)
+		-DENABLE_GUILE=$(usex guile)
+		-DENABLE_IRC=$(usex irc)
+		-DENABLE_LOGGER=$(usex logger)
+		-DENABLE_LUA=$(usex lua)
+		-DENABLE_MAN=$(usex man)
+		-DENABLE_NLS=$(usex nls)
+		-DENABLE_PERL=$(usex perl)
+		-DENABLE_PYTHON=$(usex python)
+		-DENABLE_RELAY=$(usex relay)
+		-DENABLE_CJSON=$(usex relay-api)
+		-DENABLE_RUBY=$(usex ruby)
+		-DENABLE_SCRIPT=$(usex scripts)
+		-DENABLE_SCRIPTS=$(usex scripts)
+		-DENABLE_SPELL=$(usex spell)
+		-DENABLE_TCL=$(usex tcl)
+		-DENABLE_TESTS=$(usex test)
+		-DENABLE_TRIGGER=$(usex trigger)
+		-DENABLE_TYPING=$(usex typing)
+		-DENABLE_XFER=$(usex xfer)
+		-DENABLE_ZSTD=$(usex zstd)
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	if $(locale -a | grep -iq "en_US\.utf.*8"); then
+		cmake_src_test -V
+	else
+		eerror "en_US.UTF-8 locale is required to run ${PN}'s ${FUNCNAME}"
+		die "required locale missing"
+	fi
+}
+
+src_install() {
+	cmake_src_install
+
+	use guile && guile_unstrip_ccache
+}