3 files changed, 93 insertions, 0 deletions
diff --git a/net-im/element-desktop-bin/Manifest b/net-im/element-desktop-bin/Manifest
new file mode 100644
index 000000000000..0055bfaff21d
--- /dev/null
+++ b/net-im/element-desktop-bin/Manifest
@@ -0,0 +1,3 @@
+DIST element-desktop_1.7.4_amd64.deb 65882876 BLAKE2B 8e850a6552074107307e7dea6d3200ff8213c8ea6b00c67363a2fb33aa88fc651491b1e6c05d7f9cfde9f297b3238d74dbc00800cbbf49386fea1edb21854c90 SHA512 ca9e468bfa80280bba34f119bd03a42287bddef2a8f4732db9e750a03385d9b4bd685ea45bd410182d909bd343cd7f221c734e0968e17d97e739d036ae276aed
+EBUILD element-desktop-bin-1.7.4.ebuild 1715 BLAKE2B f20abec762fcaf961702f24e8f20ed3345af3c1a5a04d87d603df356ba8c2f91d705ff7a76bf94168aa8a32b29f461ed540154b425acdd0f0398dab10f101e4f SHA512 6b57e351a46f82756215ccd32b012380e1e994c9cd850533f492bdb90ba39cfa62186cb0490554de8ce45c5c5c4da4085c80188877a2797e9ca3c8a00ecd7ef3
+MISC metadata.xml 349 BLAKE2B 28ef90d142ba536df4df0e57bc4b9dd3ea565b038bebefe71c2a2d9325761625922f928707a99833e3edb4cd2bb8083757b02ad81abc620571d4eb3620df72c1 SHA512 20596473ae86afc73bf80be067fdc7104ba8fcea6aa319e5fcc26397612dad2a724876a5748babff0f13f020d2bd246ae24f9805c8db9da70e86ae52ea3dc61e
diff --git a/net-im/element-desktop-bin/element-desktop-bin-1.7.4.ebuild b/net-im/element-desktop-bin/element-desktop-bin-1.7.4.ebuild
new file mode 100644
index 000000000000..1322035d30ac
--- /dev/null
+++ b/net-im/element-desktop-bin/element-desktop-bin-1.7.4.ebuild
@@ -0,0 +1,79 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit unpacker xdg
+
+MY_PN="element-desktop"
+
+DESCRIPTION="A glossy Matrix collaboration client for desktop (binary package)"
+HOMEPAGE="https://element.io"
+SRC_URI="https://packages.riot.im/debian/pool/main/e/element-desktop/${MY_PN}_${PV}_amd64.deb"
+S="${WORKDIR}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+emoji"
+
+RDEPEND="app-accessibility/at-spi2-atk:2
+	app-crypt/libsecret
+	dev-db/sqlcipher
+	dev-libs/atk
+	dev-libs/expat
+	dev-libs/nspr
+	dev-libs/nss
+	media-libs/alsa-lib
+	media-libs/mesa
+	net-print/cups
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/libXScrnSaver
+	x11-libs/pango
+	emoji? ( media-fonts/noto-emoji )"
+DEPEND="${RDEPEND}"
+
+QA_PREBUILT="
+	/opt/Element/chrome-sandbox
+	/opt/Element/element-desktop
+	/opt/Element/libEGL.so
+	/opt/Element/libGLESv2.so
+	/opt/Element/libffmpeg.so
+	/opt/Element/libvk_swiftshader.so
+	/opt/Element/libvulkan.so
+	/opt/Element/swiftshader/libEGL.so
+	/opt/Element/swiftshader/libGLESv2.so"
+
+src_prepare() {
+	default
+	rm opt/Element/{LICENSE.electron.txt,LICENSES.chromium.html} || die
+}
+
+src_install() {
+	mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+	gunzip usr/share/doc/${PF}/changelog.gz || die
+
+	insinto /
+	doins -r usr
+	doins -r opt
+	local f
+	for f in ${QA_PREBUILT}; do
+		fperms +x "${f}"
+	done
+	dosym ../../opt/Element/${MY_PN} /usr/bin/${MY_PN}
+	dosym ${MY_PN} /usr/bin/riot-desktop
+}
diff --git a/net-im/element-desktop-bin/metadata.xml b/net-im/element-desktop-bin/metadata.xml
new file mode 100644
index 000000000000..96ca38826cec
--- /dev/null
+++ b/net-im/element-desktop-bin/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>steils@gentoo.org</email>
+		<name>Stefan Strogin</name>
+	</maintainer>
+	<use>
+		<flag name="emoji">Use <pkg>media-fonts/noto-emoji</pkg> for displaying emoji</flag>
+	</use>
+</pkgmetadata>