1 files changed, 47 insertions, 0 deletions
diff --git a/net-analyzer/sngrep/sngrep-1.6.0.ebuild b/net-analyzer/sngrep/sngrep-1.6.0.ebuild
new file mode 100644
index 000000000000..aedd0cf3f8d1
--- /dev/null
+++ b/net-analyzer/sngrep/sngrep-1.6.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Ncurses SIP Messages flow viewer"
+HOMEPAGE="https://github.com/irontec/sngrep"
+SRC_URI="https://github.com/irontec/sngrep/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="eep gnutls pcre ssl zlib"
+
+DEPEND="
+	net-libs/libpcap
+	sys-libs/ncurses:=[unicode(+)]
+	ssl? (
+		!gnutls? ( dev-libs/openssl:= )
+		gnutls? ( net-libs/gnutls:= )
+	)
+	pcre? ( dev-libs/libpcre2 )
+	zlib? ( sys-libs/zlib )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-ipv6
+		--enable-unicode
+
+		$(use_enable eep)
+		$(use_with pcre pcre2)
+		$(use_with ssl $(usex gnutls gnutls openssl))
+		$(use_with zlib)
+	)
+
+	econf "${myeconfargs[@]}"
+}