1 files changed, 80 insertions, 0 deletions
diff --git a/net-analyzer/nsat/nsat-1.5-r6.ebuild b/net-analyzer/nsat/nsat-1.5-r6.ebuild
new file mode 100644
index 000000000000..0817289a2e6c
--- /dev/null
+++ b/net-analyzer/nsat/nsat-1.5-r6.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools toolchain-funcs
+
+DESCRIPTION="Network Security Analysis Tool, an application-level network security scanner"
+HOMEPAGE="http://nsat.sourceforge.net/"
+SRC_URI="mirror://sourceforge/nsat/${P}.tgz"
+S="${WORKDIR}/${PN}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc x86"
+IUSE="X"
+
+RDEPEND="
+	dev-libs/libmix
+	net-libs/libnsl:0=
+	net-libs/libpcap
+	net-libs/libtirpc:=
+	net-libs/rpcsvc-proto
+	X? (
+		dev-lang/tk:*
+		x11-libs/libX11
+	)
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-configure.patch
+	"${FILESDIR}"/${P}-lvalue-gcc4.patch
+	"${FILESDIR}"/${P}-strip.patch
+	"${FILESDIR}"/${P}-misc.patch
+	"${FILESDIR}"/${P}-va_list.patch
+	"${FILESDIR}"/${P}-libtirpc.patch
+	"${FILESDIR}"/${P}-amd64-compat.patch
+	"${FILESDIR}"/${P}-configure-dash.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e "s:^#CGIFile /usr/local/share/nsat/nsat.cgi$:#CGIFile /usr/share/nsat/nsat.cgi:g" \
+		nsat.conf || die
+	sed -i -e "s:/usr/local:/usr:g" tools/xnsat || die
+	sed -i \
+		-e "s:/usr/local/share/nsat/nsat.conf:/etc/nsat/nsat.conf:g" \
+		-e "s:/usr/local/share/nsat/nsat.cgi:/usr/share/nsat/nsat.cgi:g" \
+		src/lang.h || die
+
+	mv configure.{in,ac} || die
+
+	eautoreconf
+}
+
+src_configure() {
+	tc-export CC
+	econf $(use_with X x)
+}
+
+src_compile() {
+	emake MIXOBJ=-lmix++
+}
+
+src_install() {
+	dobin nsat smb-ns
+	use X && dobin tools/xnsat
+
+	insinto /usr/share/nsat
+	doins nsat.cgi
+
+	insinto /etc/nsat
+	doins nsat.conf
+
+	dodoc README doc/CHANGES
+	doman doc/nsat.8
+}