1 files changed, 43 insertions, 0 deletions
diff --git a/net-analyzer/multipath-tcp-tools/multipath-tcp-tools-999999.ebuild b/net-analyzer/multipath-tcp-tools/multipath-tcp-tools-999999.ebuild
new file mode 100644
index 000000000000..edabbb51709a
--- /dev/null
+++ b/net-analyzer/multipath-tcp-tools/multipath-tcp-tools-999999.ebuild
@@ -0,0 +1,43 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit git-r3 toolchain-funcs
+
+DESCRIPTION="Analysis tools for Multipath Transmission Control Protocol (MPTCP)"
+HOMEPAGE="https://github.com/nasa/multipath-tcp-tools"
+EGIT_REPO_URI="https://github.com/nasa/multipath-tcp-tools/"
+
+LICENSE="NOSA"
+SLOT="0"
+KEYWORDS=""
+
+DEPEND="
+	dev-libs/openssl:*
+	net-libs/libpcap
+"
+RDEPEND="
+	${DEPEND}
+"
+S=${WORKDIR}/${P}/network-traffic-analysis-tools
+
+src_prepare() {
+	sed -i \
+		-e 's|/man/man1|/share&|g' \
+		-e 's|$(LDLIBS)|$(LDFLAGS) &|g' \
+		Makefile || die
+
+	default
+}
+
+src_compile() {
+	emake \
+		CXX="$(tc-getCXX)" \
+		CXXFLAGS="${CXXFLAGS}"
+}
+
+src_install() {
+	emake PREFIX="${D}/${EPREFIX}/usr" install
+
+	dodoc README
+}