1 files changed, 63 insertions, 0 deletions
diff --git a/media-video/subtitlecomposer/subtitlecomposer-0.8.0.ebuild b/media-video/subtitlecomposer/subtitlecomposer-0.8.0.ebuild
new file mode 100644
index 000000000000..b6ea7b759537
--- /dev/null
+++ b/media-video/subtitlecomposer/subtitlecomposer-0.8.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="forceoptional"
+KFMIN=5.106.0
+QTMIN=5.15.9
+inherit ecm kde.org
+
+DESCRIPTION="Text-based subtitles editor"
+HOMEPAGE="https://subtitlecomposer.kde.org/"
+
+if [[ ${KDE_BUILD_TYPE} = release ]]; then
+	PATCHSET="${PN}-0.7.1-patchset-1"
+	SRC_URI="mirror://kde/stable/${PN}/${P}.tar.xz
+	https://dev.gentoo.org/~asturm/distfiles/${PATCHSET}.tar.xz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="5"
+IUSE="unicode"
+
+DEPEND="
+	dev-libs/openssl:=
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/sonnet-${KFMIN}:5
+	media-libs/openal
+	media-video/ffmpeg:0=
+	unicode? ( dev-libs/icu:= )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${WORKDIR}/${PATCHSET}/${PN}-0.7.1-tests-optional.patch" # TODO: upstream
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_PocketSphinx=ON # bugs 616706, 610434
+		$(cmake_use_find_package unicode ICU)
+	)
+
+	ecm_src_configure
+}