1 files changed, 66 insertions, 0 deletions
diff --git a/media-video/shotcut/shotcut-21.06.29.ebuild b/media-video/shotcut/shotcut-21.06.29.ebuild
new file mode 100644
index 000000000000..94b278e81817
--- /dev/null
+++ b/media-video/shotcut/shotcut-21.06.29.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit qmake-utils xdg
+
+DESCRIPTION="A free, open source, cross-platform video editor"
+HOMEPAGE="https://www.shotcut.org/ https://github.com/mltframework/shotcut/"
+if [[ ${PV} != 9999* ]] ; then
+	SRC_URI="https://github.com/mltframework/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+else
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/mltframework/shotcut/"
+fi
+
+IUSE="debug"
+
+LICENSE="GPL-3+"
+SLOT="0"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+"
+COMMON_DEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtdeclarative:5[widgets]
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtopengl:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtquickcontrols2:5
+	dev-qt/qtsql:5
+	dev-qt/qtwebsockets:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	>=media-libs/mlt-7.0.1[ffmpeg,frei0r,fftw(+),jack,opengl,qt5,sdl,xml]
+	media-video/ffmpeg
+"
+DEPEND="${COMMON_DEPEND}
+	dev-qt/qtconcurrent:5
+	dev-qt/qtx11extras:5
+"
+RDEPEND="${COMMON_DEPEND}
+	dev-qt/qtgraphicaleffects:5
+	dev-qt/qtquickcontrols:5
+	virtual/jack
+"
+
+src_configure() {
+	local myqmakeargs=(
+		PREFIX="${EPREFIX}/usr"
+		SHOTCUT_VERSION="${PV}"
+		DEFINES+=SHOTCUT_NOUPGRADE
+	)
+	use debug || myqmakeargs+=(DEFINES+=NDEBUG)
+
+	eqmake5 "${myqmakeargs[@]}"
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+	einstalldocs
+}