3 files changed, 164 insertions, 3 deletions
diff --git a/media-sound/qmmp/Manifest b/media-sound/qmmp/Manifest
index fc51667a3db2..fe431b542b7d 100644
--- a/media-sound/qmmp/Manifest
+++ b/media-sound/qmmp/Manifest
@@ -1,4 +1,6 @@
 DIST qmmp-1.5.1.tar.bz2 1363593 BLAKE2B 7c344ce2d9c1bc419b17c8d3727afa6f95273e7487f539b0e2f8cb5328f0185a7aab184d9df01a023f896e8b516135fd58ebe0e2204fb1f5ca283f4e0c04d78f SHA512 4b866e7b53ea1757a94e028730dd99bab3b56917e6835b46284cce148e779e00a5fe0a396667283aa13c980a9ee33d0fe76df0198320f1897ec3b73bcd1f275e
+DIST qmmp-1.5.3.tar.bz2 1388836 BLAKE2B 90fe166204125773d888f54f7f2b044215816ca337f079a73bca708440dc011c31a17afd7070a43103374f21879932527c123d5fe3066b46331abbdc91f8c224 SHA512 135802fde0d8ec0cad4ea1968dc6a4ab418d403ce2fd8fb4f96535420c84f7c56b67491e80b700960ab7d99600657dfe661cb2fd6bec3ae3a7c8cd809f16d9ba
 EBUILD qmmp-1.5.1.ebuild 4131 BLAKE2B 9a1ad81f31602acdefc2e9c3a30d3953c61d19edc5186f796399bbb5a24e7e078d9deebb35d09594b66a56a9e396c4f141832b259c7739c8a06ca8299c78a224 SHA512 6f39f9ee519e07872d6c73eb51f78bb4c71fb1c1665d905cc511064ab86e8cf0c541e8cd4a6440682e57371bfbc30b51dba98ac309bb65fa19af7e50ffbd55b3
-EBUILD qmmp-9999.ebuild 4133 BLAKE2B 7d65727a5858560cea4992734486ef6d080c64673ff65509a6883f05dc0f21b125f84635203b2f06f4d2baebddd2b769141b7db2ac9768fe23ffa46a7f888d30 SHA512 12d3d0b02a7a221a7f6edc82e0da2d3f7c60b77013f34c734f38155abbd924a4f53c98554a58317fc71dd30be06ad158eb34e387aa9439af778f75570bdc5736
+EBUILD qmmp-1.5.3.ebuild 4112 BLAKE2B bf5c0a3724e3670be2a65a996ced8fdf7bae069fee3d6012c2008b8f53ab23ff3713806ab3d546f413f16e8215ecb44fe7a8d89056eed1559c0124af34f1b80a SHA512 7e3755425e4c04ea312512077a52e90fb5965b701d99919e14f4b8d082e874b947584cec67a2d1399e5cb28aa37dda9ed710b210a4a1c57788efcce4e31ed537
+EBUILD qmmp-9999.ebuild 4112 BLAKE2B bf5c0a3724e3670be2a65a996ced8fdf7bae069fee3d6012c2008b8f53ab23ff3713806ab3d546f413f16e8215ecb44fe7a8d89056eed1559c0124af34f1b80a SHA512 7e3755425e4c04ea312512077a52e90fb5965b701d99919e14f4b8d082e874b947584cec67a2d1399e5cb28aa37dda9ed710b210a4a1c57788efcce4e31ed537
 MISC metadata.xml 1883 BLAKE2B 8f252d3c02181fe5c7897a6f23b689dc75b507af80e765248ba856c8cd6564d162cfa60190fdd57350e1cf00229391f5057c1a51853dd2e291b3bc7311049d8f SHA512 affecdc44bc4b87cae10aba228f52b6eee63f759fa70e609206c9a4e627dab7d89741cdf51a22fe4b502f8c8d62077512494c893c7963afeb7d0cc0c23f945c0
diff --git a/media-sound/qmmp/qmmp-1.5.3.ebuild b/media-sound/qmmp/qmmp-1.5.3.ebuild
new file mode 100644
index 000000000000..ee881e5be18c
--- /dev/null
+++ b/media-sound/qmmp/qmmp-1.5.3.ebuild
@@ -0,0 +1,159 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake xdg
+
+DESCRIPTION="Qt5-based audio player with winamp/xmms skins support"
+HOMEPAGE="http://qmmp.ylsoftware.com"
+if [[ ${PV} != 9999 ]]; then
+	SRC_URI="http://qmmp.ylsoftware.com/files/${P}.tar.bz2
+		mirror://sourceforge/${PN}-dev/files/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+else
+	inherit subversion
+	QMMP_DEV_BRANCH="1.3"
+	ESVN_REPO_URI="svn://svn.code.sf.net/p/${PN}-dev/code/branches/${PN}-${QMMP_DEV_BRANCH}"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+# KEYWORDS further up
+IUSE="aac +alsa analyzer archive bs2b cdda cover crossfade cue curl +dbus enca
+ffmpeg flac game gnome jack ladspa lyrics +mad midi mms modplug mplayer musepack
+notifier opus oss pipewire projectm pulseaudio qsui qtmedia scrobbler shout sid
+sndfile soxr stereo tray udisks +vorbis wavpack"
+
+REQUIRED_USE="
+	gnome? ( dbus )
+	shout? ( soxr vorbis )
+	udisks? ( dbus )
+"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtsql:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	media-libs/taglib
+	x11-libs/libX11
+	aac? ( media-libs/faad2 )
+	alsa? ( media-libs/alsa-lib )
+	archive? ( app-arch/libarchive )
+	bs2b? ( media-libs/libbs2b )
+	cdda? (
+		dev-libs/libcdio:=
+		dev-libs/libcdio-paranoia
+	)
+	curl? ( net-misc/curl )
+	dbus? ( dev-qt/qtdbus:5 )
+	enca? ( app-i18n/enca )
+	ffmpeg? ( media-video/ffmpeg:= )
+	flac? ( media-libs/flac )
+	game? ( media-libs/game-music-emu )
+	jack? (
+		media-libs/libsamplerate
+		virtual/jack
+	)
+	ladspa? ( media-plugins/cmt-plugins )
+	mad? (
+		media-libs/libmad:=
+		media-sound/mpg123:=
+	)
+	midi? ( media-sound/wildmidi )
+	mms? ( media-libs/libmms )
+	modplug? ( >=media-libs/libmodplug-0.8.4 )
+	mplayer? ( media-video/mplayer )
+	musepack? ( >=media-sound/musepack-tools-444 )
+	opus? ( media-libs/opusfile )
+	pipewire? ( media-video/pipewire )
+	projectm? (
+		dev-qt/qtgui:5[-gles2-only]
+		dev-qt/qtopengl:5
+		media-libs/libprojectm:=
+	)
+	pulseaudio? ( >=media-sound/pulseaudio-0.9.9 )
+	qtmedia? ( dev-qt/qtmultimedia:5 )
+	scrobbler? ( net-misc/curl )
+	shout? ( media-libs/libshout )
+	sid? ( >=media-libs/libsidplayfp-1.1.0 )
+	sndfile? ( media-libs/libsndfile )
+	soxr? ( media-libs/soxr )
+	udisks? ( sys-fs/udisks:2 )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+	wavpack? ( media-sound/wavpack )
+"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+"
+
+DOCS=( AUTHORS ChangeLog README )
+
+src_prepare() {
+	if has_version dev-libs/libcdio-paranoia ; then
+		sed -i \
+			-e 's:cdio/cdda.h:cdio/paranoia/cdda.h:' \
+			src/plugins/Input/cdaudio/decoder_cdaudio.cpp || die
+	fi
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DUSE_AAC="$(usex aac)"
+		-DUSE_ALSA="$(usex alsa)"
+		-DUSE_ANALYZER="$(usex analyzer)"
+		-DUSE_ARCHIVE="$(usex archive)"
+		-DUSE_BS2B="$(usex bs2b)"
+		-DUSE_CDA="$(usex cdda)"
+		-DUSE_COVER="$(usex cover)"
+		-DUSE_CROSSFADE="$(usex crossfade)"
+		-DUSE_CUE="$(usex cue)"
+		-DUSE_CURL="$(usex curl)"
+		-DUSE_KDENOTIFY="$(usex dbus)"
+		-DUSE_MPRIS="$(usex dbus)"
+		-DUSE_ENCA="$(usex enca)"
+		-DUSE_FFMPEG="$(usex ffmpeg)"
+		-DUSE_FILEWRITER="$(usex vorbis)"
+		-DUSE_FLAC="$(usex flac)"
+		-DUSE_GME="$(usex game)"
+		-DUSE_GNOMEHOTKEY="$(usex gnome)"
+		-DUSE_HAL=OFF
+		-DUSE_JACK="$(usex jack)"
+		-DUSE_LADSPA="$(usex ladspa)"
+		-DUSE_LYRICS="$(usex lyrics)"
+		-DUSE_MAD="$(usex mad)"
+		-DUSE_MIDI="$(usex midi)"
+		-DUSE_MMS="$(usex mms)"
+		-DUSE_MODPLUG="$(usex modplug)"
+		-DUSE_MPLAYER="$(usex mplayer)"
+		-DUSE_MPC="$(usex musepack)"
+		-DUSE_NOTIFIER="$(usex notifier)"
+		-DUSE_OPUS="$(usex opus)"
+		-DUSE_OSS="$(usex oss)"
+		-DUSE_PIPEWIRE="$(usex pipewire)"
+		-DUSE_PROJECTM="$(usex projectm)"
+		-DUSE_PULSE="$(usex pulseaudio)"
+		-DUSE_QSUI="$(usex qsui)"
+		-DUSE_QTMULTIMEDIA="$(usex qtmedia)"
+		-DUSE_SCROBBLER="$(usex scrobbler)"
+		-DUSE_SHOUT="$(usex shout)"
+		-DUSE_SID="$(usex sid)"
+		-DUSE_SNDFILE="$(usex sndfile)"
+		-DUSE_SOXR="$(usex soxr)"
+		-DUSE_STEREO="$(usex stereo)"
+		-DUSE_STATICON="$(usex tray)"
+		-DUSE_UDISKS2="$(usex udisks)"
+		-DUSE_VORBIS="$(usex vorbis)"
+		-DUSE_WAVPACK="$(usex wavpack)"
+	)
+
+	cmake_src_configure
+}
diff --git a/media-sound/qmmp/qmmp-9999.ebuild b/media-sound/qmmp/qmmp-9999.ebuild
index 2fe547a222c2..ee881e5be18c 100644
--- a/media-sound/qmmp/qmmp-9999.ebuild
+++ b/media-sound/qmmp/qmmp-9999.ebuild
@@ -1,10 +1,9 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
 
 inherit cmake xdg
-[[ ${PV} = 9999 ]] && inherit subversion
 
 DESCRIPTION="Qt5-based audio player with winamp/xmms skins support"
 HOMEPAGE="http://qmmp.ylsoftware.com"
@@ -13,6 +12,7 @@ if [[ ${PV} != 9999 ]]; then
 		mirror://sourceforge/${PN}-dev/files/${P}.tar.bz2"
 	KEYWORDS="~amd64 ~x86"
 else
+	inherit subversion
 	QMMP_DEV_BRANCH="1.3"
 	ESVN_REPO_URI="svn://svn.code.sf.net/p/${PN}-dev/code/branches/${PN}-${QMMP_DEV_BRANCH}"
 fi