summaryrefslogtreecommitdiff
path: root/media-libs/mesa
diff options
context:
space:
mode:
Diffstat (limited to 'media-libs/mesa')
-rw-r--r--media-libs/mesa/Manifest10
-rw-r--r--media-libs/mesa/mesa-20.3.5.ebuild14
-rw-r--r--media-libs/mesa/mesa-21.0.3.ebuild14
-rw-r--r--media-libs/mesa/mesa-21.1.1.ebuild14
-rw-r--r--media-libs/mesa/mesa-21.1.2.ebuild553
-rw-r--r--media-libs/mesa/mesa-9999.ebuild14
6 files changed, 563 insertions, 56 deletions
diff --git a/media-libs/mesa/Manifest b/media-libs/mesa/Manifest
index 49912c2cf232..e73004f1557a 100644
--- a/media-libs/mesa/Manifest
+++ b/media-libs/mesa/Manifest
@@ -1,8 +1,10 @@
DIST mesa-20.3.5.tar.xz 14367412 BLAKE2B 7bad876ce702158e727a752eda6722e7165b497fd3a485dae4e989f22b13288a93f51bcd5e6a69b979f0bbe41599fa237c08f3bbb81cb9c6dc4c06827f8ad5f4 SHA512 481e710ed80d8f215a8d541cfe51b960862c2403c2b9e7e6932c8236b8decb5d478871d6c73559d6d795ada143803764f3a93b2329588c80f62e2e5ec98c78a9
DIST mesa-21.0.3.tar.xz 14710004 BLAKE2B f2165da4487824931d8ff90e4f13624546a297b0d3577d69b7cfd6078a965282b4a732cb720cbb08ea83a3a987603cfe67876fb18022fa444b011fcc9b7df352 SHA512 4a8aee48a8ea7f32e8aa3bbbd91db26c6053b9a43e62ff88256929e6bc147884f0fef988726b5a3d59d7008663f017c746a0352fd3fcc1c476b8190af4a2531f
DIST mesa-21.1.1.tar.xz 15169732 BLAKE2B b2c2f2fa14ebf78baeb64ca976dde2920a594bcea02b3a17820135afc169c8489f37a2869b140d637b11b618c96e37834c255ca7a92d17f70003a11e8fffd401 SHA512 79d0e2b0e1e590e7f36a082df3584010a553af0b3060bd2d3a7ace700ac7a8d1b7734ba67f2e193dd441434eeec74a16e0dbcbf8c15061b5dd5d6a1feca73d62
-EBUILD mesa-20.3.5.ebuild 15063 BLAKE2B cbf593097a3b3a98f9e658f4e5e1d2bb29e7d7f977dffbb130dfd84afbfea76e10b997ec119a65450e687c101da1de199fff987f6aacfb995f4cf7551868050a SHA512 5399d4cffa57c5b1c6b089a6a0187c1aea2ee6334e8b560a8e1a7724c636538351d8d649f84fdd0d929b6c4f47c5b58cb5ebbb413a72577ca1d46db141242e47
-EBUILD mesa-21.0.3.ebuild 14974 BLAKE2B 9e1b0d0fe9b2f0449fcd1a083bc8a01302d0cda7919fb78aa71ac2424dc06b57a1b276f51286a81a08bac86b8c6f4383cfdeb73f1fc10ac196623477d1d30487 SHA512 eeae6ca3aad46f11bea1a5d94f2d54652f5c90864b3fde1ef92fdbc379ee0c094ac197f6ac25a07235a68179d561d8794519681940c34d8d7cb165efcbc347d5
-EBUILD mesa-21.1.1.ebuild 15021 BLAKE2B 6b8ef24e6e5d64b5c22edc76157924c8189bd7be957d06bf81011ab4b8d701c1393d22ad7a5301fe280f453af6aa1191563b798e6a8ded2c67b477a1ff7532af SHA512 d57fbefed59d1328bc915fb8435457a9c09e917a86fc6c1225e7ea942ee2a41ef093965b386b8a3aa5fb1baa466162683c39ef319380e5e7c27425b958c92907
-EBUILD mesa-9999.ebuild 14981 BLAKE2B df68d9a7fa62672d81582f8a43c3ff125abdd134b83683bc5bd24c2b9c457b3fc1b925102c33777d7ba121e2be6d507febec0d7ac1a32f17b738bd1785623540 SHA512 d0385e88dd4c47e499a353beeb891fb3dad9c8008642ca325402af53bb5da42243e771fcfb8088dead4c08d6ba590cef67fa6d4b86a80e383c4fbd9a25877c40
+DIST mesa-21.1.2.tar.xz 15199892 BLAKE2B 1e1d9e0bee2eec95a38379047c050ba7e4a9ada47bb8d4f1d3faf355ec6f71ad8e792cfaf72234a3c86f254c33618883f772c0f3f7f7f97085a8c7b5a1ad90d0 SHA512 a7907fa29fdb4e137015ee5405b9c8c0769ef9354bbe963c1af80318b398c05c79db6129b583106d620c42a5e9b625611b648fd5207334eb9b588d7963defc70
+EBUILD mesa-20.3.5.ebuild 14915 BLAKE2B 73f85b8bbbbbbfba3be499ba55ffa2bcdb5e6f860049819502957e803c2760edf3e45ada1f103f58752e77177065ad12d81ea72c36f96c19c6ebc87d1fe03ab9 SHA512 0b1dd3fad90392be514da0d347efe19b35fe82d13ca02d959f56e625d00a9beb917c83c678e7d6ad419dc81b6fc32e0dd8ca6f95f5fd77484872af464f9ae52b
+EBUILD mesa-21.0.3.ebuild 14826 BLAKE2B 1c9793f1dc8b7769406d49d02fcf152c2b21a446972fb754871ec5103ddab1eb93bfc52aed895bbc74b9c7a6743c360d5cbcbc0d1ede2cd28307eb243803a77b SHA512 3b5db1497b6b99412353134139bfd2abac642989d1570d4c8d2172dd82e63aeed6ef1bc1d7ce0c2653288a6c7bd8a6315494ed152deb627fc3eb304a6d5f9be7
+EBUILD mesa-21.1.1.ebuild 14873 BLAKE2B 04fc1df71cb1520fedbfdd73a4042b4871f1bd69b7b89f7152c84de4e3d2a7da6002861ab13d9a6a40130def670d31fdfe1a577175f5916bddd95ea392e3581c SHA512 330970c7a8396a1f938e9ee395cd58425fb62b0a05e4c464e2f0963ee23c218ca7fb012b75d59aac4426c9104682c948f782ad1ba4c1704b0dcc6ff70803127a
+EBUILD mesa-21.1.2.ebuild 14873 BLAKE2B 04fc1df71cb1520fedbfdd73a4042b4871f1bd69b7b89f7152c84de4e3d2a7da6002861ab13d9a6a40130def670d31fdfe1a577175f5916bddd95ea392e3581c SHA512 330970c7a8396a1f938e9ee395cd58425fb62b0a05e4c464e2f0963ee23c218ca7fb012b75d59aac4426c9104682c948f782ad1ba4c1704b0dcc6ff70803127a
+EBUILD mesa-9999.ebuild 14833 BLAKE2B 114e3b670f928a2745a6affa18ec5ad29fc929f5397453f2b276e1a8f7448fc0664aa4057e15cf248a9ad723e48f523619cbe2b1dd39692f273971f1a8e95e1c SHA512 b00131e879ceac909e558ee182fbd50ace215db5a27849707ead338c6199b3878cef066440a51752dc4f481e87a8f87666ddbce46c383c3f46df1032dad2f3bf
MISC metadata.xml 1895 BLAKE2B abf62dda9b9eba657e310c68fdd86aaa49c550dc34ef624e8feb038e0412f0da786e1120dc16631399cb2c83961b88e78571347c3e6d464c2cf3a343bc0f1483 SHA512 7758641386100e07c1112afe04a8613de8ae1e35a8e940f0eefcfc7daa829789c42b903320339b04b44c2400f0857c180740407abd171e9773a9f51e3dd9468a
diff --git a/media-libs/mesa/mesa-20.3.5.ebuild b/media-libs/mesa/mesa-20.3.5.ebuild
index b77317562fe9..db637e1abb46 100644
--- a/media-libs/mesa/mesa-20.3.5.ebuild
+++ b/media-libs/mesa/mesa-20.3.5.ebuild
@@ -5,7 +5,7 @@ EAPI=7
PYTHON_COMPAT=( python3_{7,8,9} )
-inherit llvm meson multilib-minimal python-any-r1 linux-info
+inherit llvm meson-multilib python-any-r1 linux-info
OPENGL_DIR="xorg-x11"
@@ -526,18 +526,6 @@ multilib_src_configure() {
meson_src_configure
}
-multilib_src_compile() {
- meson_src_compile
-}
-
-multilib_src_install() {
- meson_src_install
-}
-
-multilib_src_install_all() {
- einstalldocs
-}
-
multilib_src_test() {
meson_src_test -t 100
}
diff --git a/media-libs/mesa/mesa-21.0.3.ebuild b/media-libs/mesa/mesa-21.0.3.ebuild
index cc7b3d9f036a..9d8170f4f79f 100644
--- a/media-libs/mesa/mesa-21.0.3.ebuild
+++ b/media-libs/mesa/mesa-21.0.3.ebuild
@@ -5,7 +5,7 @@ EAPI=7
PYTHON_COMPAT=( python3_{7,8,9} )
-inherit llvm meson multilib-minimal python-any-r1 linux-info
+inherit llvm meson-multilib python-any-r1 linux-info
OPENGL_DIR="xorg-x11"
@@ -524,18 +524,6 @@ multilib_src_configure() {
meson_src_configure
}
-multilib_src_compile() {
- meson_src_compile
-}
-
-multilib_src_install() {
- meson_src_install
-}
-
-multilib_src_install_all() {
- einstalldocs
-}
-
multilib_src_test() {
meson_src_test -t 100
}
diff --git a/media-libs/mesa/mesa-21.1.1.ebuild b/media-libs/mesa/mesa-21.1.1.ebuild
index c15b166a9280..b67e6c7e47f0 100644
--- a/media-libs/mesa/mesa-21.1.1.ebuild
+++ b/media-libs/mesa/mesa-21.1.1.ebuild
@@ -5,7 +5,7 @@ EAPI=7
PYTHON_COMPAT=( python3_{7,8,9} )
-inherit llvm meson multilib-minimal python-any-r1 linux-info
+inherit llvm meson-multilib python-any-r1 linux-info
OPENGL_DIR="xorg-x11"
@@ -525,18 +525,6 @@ multilib_src_configure() {
meson_src_configure
}
-multilib_src_compile() {
- meson_src_compile
-}
-
-multilib_src_install() {
- meson_src_install
-}
-
-multilib_src_install_all() {
- einstalldocs
-}
-
multilib_src_test() {
meson_src_test -t 100
}
diff --git a/media-libs/mesa/mesa-21.1.2.ebuild b/media-libs/mesa/mesa-21.1.2.ebuild
new file mode 100644
index 000000000000..b67e6c7e47f0
--- /dev/null
+++ b/media-libs/mesa/mesa-21.1.2.ebuild
@@ -0,0 +1,553 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit llvm meson-multilib python-any-r1 linux-info
+
+OPENGL_DIR="xorg-x11"
+
+MY_P="${P/_/-}"
+
+DESCRIPTION="OpenGL-like graphic library for Linux"
+HOMEPAGE="https://www.mesa3d.org/ https://mesa.freedesktop.org/"
+
+if [[ ${PV} == 9999 ]]; then
+ EGIT_REPO_URI="https://gitlab.freedesktop.org/mesa/mesa.git"
+ inherit git-r3
+else
+ SRC_URI="https://archive.mesa3d.org/${MY_P}.tar.xz"
+ KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~sparc-solaris ~x64-solaris ~x86-solaris"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+RESTRICT="
+ !test? ( test )
+"
+
+RADEON_CARDS="r100 r200 r300 r600 radeon radeonsi"
+VIDEO_CARDS="${RADEON_CARDS} freedreno i915 i965 intel iris lima nouveau panfrost v3d vc4 virgl vivante vmware"
+for card in ${VIDEO_CARDS}; do
+ IUSE_VIDEO_CARDS+=" video_cards_${card}"
+done
+
+IUSE="${IUSE_VIDEO_CARDS}
+ +classic d3d9 debug +dri3 +egl +gallium +gbm gles1 +gles2 +llvm
+ lm-sensors opencl osmesa selinux test unwind vaapi valgrind vdpau vulkan
+ vulkan-overlay wayland +X xa xvmc zink +zstd"
+
+REQUIRED_USE="
+ d3d9? ( dri3 || ( video_cards_iris video_cards_r300 video_cards_r600 video_cards_radeonsi video_cards_nouveau video_cards_vmware ) )
+ gles1? ( egl )
+ gles2? ( egl )
+ osmesa? ( gallium )
+ vulkan? ( dri3
+ video_cards_radeonsi? ( llvm ) )
+ vulkan-overlay? ( vulkan )
+ wayland? ( egl gbm )
+ video_cards_freedreno? ( gallium )
+ video_cards_intel? ( classic )
+ video_cards_i915? ( || ( classic gallium ) )
+ video_cards_i965? ( classic )
+ video_cards_iris? ( gallium )
+ video_cards_lima? ( gallium )
+ video_cards_nouveau? ( || ( classic gallium ) )
+ video_cards_panfrost? ( gallium )
+ video_cards_radeon? ( || ( classic gallium )
+ gallium? ( x86? ( llvm ) amd64? ( llvm ) ) )
+ video_cards_r100? ( classic )
+ video_cards_r200? ( classic )
+ video_cards_r300? ( gallium x86? ( llvm ) amd64? ( llvm ) )
+ video_cards_r600? ( gallium )
+ video_cards_radeonsi? ( gallium llvm )
+ video_cards_v3d? ( gallium )
+ video_cards_vc4? ( gallium )
+ video_cards_virgl? ( gallium )
+ video_cards_vivante? ( gallium gbm )
+ video_cards_vmware? ( gallium )
+ xa? ( X )
+ xvmc? ( X )
+ zink? ( gallium vulkan )
+"
+
+LIBDRM_DEPSTRING=">=x11-libs/libdrm-2.4.105"
+RDEPEND="
+ >=dev-libs/expat-2.1.0-r3:=[${MULTILIB_USEDEP}]
+ >=media-libs/libglvnd-1.3.2[X?,${MULTILIB_USEDEP}]
+ >=sys-libs/zlib-1.2.8[${MULTILIB_USEDEP}]
+ gallium? (
+ unwind? ( sys-libs/libunwind[${MULTILIB_USEDEP}] )
+ llvm? (
+ video_cards_radeonsi? (
+ virtual/libelf:0=[${MULTILIB_USEDEP}]
+ )
+ video_cards_r600? (
+ virtual/libelf:0=[${MULTILIB_USEDEP}]
+ )
+ video_cards_radeon? (
+ virtual/libelf:0=[${MULTILIB_USEDEP}]
+ )
+ )
+ lm-sensors? ( sys-apps/lm-sensors:=[${MULTILIB_USEDEP}] )
+ opencl? (
+ >=virtual/opencl-3[${MULTILIB_USEDEP}]
+ dev-libs/libclc
+ virtual/libelf:0=[${MULTILIB_USEDEP}]
+ )
+ vaapi? (
+ >=x11-libs/libva-1.7.3:=[${MULTILIB_USEDEP}]
+ )
+ vdpau? ( >=x11-libs/libvdpau-1.1:=[${MULTILIB_USEDEP}] )
+ xvmc? ( >=x11-libs/libXvMC-1.0.8:=[${MULTILIB_USEDEP}] )
+ )
+ selinux? ( sys-libs/libselinux[${MULTILIB_USEDEP}] )
+ wayland? (
+ >=dev-libs/wayland-1.18.0:=[${MULTILIB_USEDEP}]
+ >=dev-libs/wayland-protocols-1.8
+ )
+ ${LIBDRM_DEPSTRING}[video_cards_freedreno?,video_cards_nouveau?,video_cards_vc4?,video_cards_vivante?,video_cards_vmware?,${MULTILIB_USEDEP}]
+ video_cards_intel? (
+ !video_cards_i965? ( ${LIBDRM_DEPSTRING}[video_cards_intel] )
+ )
+ video_cards_i915? ( ${LIBDRM_DEPSTRING}[video_cards_intel] )
+ vulkan-overlay? ( dev-util/glslang:0=[${MULTILIB_USEDEP}] )
+ X? (
+ >=x11-libs/libX11-1.6.2:=[${MULTILIB_USEDEP}]
+ >=x11-libs/libxshmfence-1.1:=[${MULTILIB_USEDEP}]
+ >=x11-libs/libXext-1.3.2:=[${MULTILIB_USEDEP}]
+ >=x11-libs/libXxf86vm-1.1.3:=[${MULTILIB_USEDEP}]
+ >=x11-libs/libxcb-1.13:=[${MULTILIB_USEDEP}]
+ x11-libs/libXfixes:=[${MULTILIB_USEDEP}]
+ )
+ zink? ( media-libs/vulkan-loader:=[${MULTILIB_USEDEP}] )
+ zstd? ( app-arch/zstd:=[${MULTILIB_USEDEP}] )
+"
+for card in ${RADEON_CARDS}; do
+ RDEPEND="${RDEPEND}
+ video_cards_${card}? ( ${LIBDRM_DEPSTRING}[video_cards_radeon] )
+ "
+done
+RDEPEND="${RDEPEND}
+ video_cards_radeonsi? ( ${LIBDRM_DEPSTRING}[video_cards_amdgpu] )
+"
+
+# Please keep the LLVM dependency block separate. Since LLVM is slotted,
+# we need to *really* make sure we're not pulling one than more slot
+# simultaneously.
+#
+# How to use it:
+# 1. List all the working slots (with min versions) in ||, newest first.
+# 2. Update the := to specify *max* version, e.g. < 10.
+# 3. Specify LLVM_MAX_SLOT, e.g. 9.
+LLVM_MAX_SLOT="12"
+LLVM_DEPSTR="
+ || (
+ sys-devel/llvm:12[${MULTILIB_USEDEP}]
+ sys-devel/llvm:11[${MULTILIB_USEDEP}]
+ sys-devel/llvm:10[${MULTILIB_USEDEP}]
+ )
+ <sys-devel/llvm-$((LLVM_MAX_SLOT + 1)):=[${MULTILIB_USEDEP}]
+"
+LLVM_DEPSTR_AMDGPU=${LLVM_DEPSTR//]/,llvm_targets_AMDGPU(-)]}
+CLANG_DEPSTR=${LLVM_DEPSTR//llvm/clang}
+CLANG_DEPSTR_AMDGPU=${CLANG_DEPSTR//]/,llvm_targets_AMDGPU(-)]}
+RDEPEND="${RDEPEND}
+ gallium? (
+ llvm? (
+ opencl? (
+ video_cards_r600? (
+ ${CLANG_DEPSTR_AMDGPU}
+ )
+ !video_cards_r600? (
+ video_cards_radeonsi? (
+ ${CLANG_DEPSTR_AMDGPU}
+ )
+ )
+ !video_cards_r600? (
+ !video_cards_radeonsi? (
+ video_cards_radeon? (
+ ${CLANG_DEPSTR_AMDGPU}
+ )
+ )
+ )
+ !video_cards_r600? (
+ !video_cards_radeon? (
+ !video_cards_radeonsi? (
+ ${CLANG_DEPSTR}
+ )
+ )
+ )
+ )
+ !opencl? (
+ video_cards_r600? (
+ ${LLVM_DEPSTR_AMDGPU}
+ )
+ !video_cards_r600? (
+ video_cards_radeonsi? (
+ ${LLVM_DEPSTR_AMDGPU}
+ )
+ )
+ !video_cards_r600? (
+ !video_cards_radeonsi? (
+ video_cards_radeon? (
+ ${LLVM_DEPSTR_AMDGPU}
+ )
+ )
+ )
+ !video_cards_r600? (
+ !video_cards_radeon? (
+ !video_cards_radeonsi? (
+ ${LLVM_DEPSTR}
+ )
+ )
+ )
+ )
+ )
+ )
+"
+unset {LLVM,CLANG}_DEPSTR{,_AMDGPU}
+
+DEPEND="${RDEPEND}
+ valgrind? ( dev-util/valgrind )
+ X? (
+ x11-libs/libXrandr[${MULTILIB_USEDEP}]
+ x11-base/xorg-proto
+ )
+"
+BDEPEND="
+ ${PYTHON_DEPS}
+ opencl? (
+ >=sys-devel/gcc-4.6
+ )
+ sys-devel/bison
+ sys-devel/flex
+ virtual/pkgconfig
+ $(python_gen_any_dep ">=dev-python/mako-0.8.0[\${PYTHON_USEDEP}]")
+ wayland? ( dev-util/wayland-scanner[${MULTILIB_USEDEP}] )
+"
+
+S="${WORKDIR}/${MY_P}"
+EGIT_CHECKOUT_DIR=${S}
+
+QA_WX_LOAD="
+x86? (
+ usr/lib*/libglapi.so.0.0.0
+ usr/lib*/libGLESv1_CM.so.1.1.0
+ usr/lib*/libGLESv2.so.2.0.0
+ usr/lib*/libGL.so.1.2.0
+ usr/lib*/libOSMesa.so.8.0.0
+ usr/lib/libGLX_mesa.so.0.0.0
+)"
+
+llvm_check_deps() {
+ local flags=${MULTILIB_USEDEP}
+ if use video_cards_r600 || use video_cards_radeon || use video_cards_radeonsi
+ then
+ flags+=",llvm_targets_AMDGPU(-)"
+ fi
+
+ if use opencl; then
+ has_version "sys-devel/clang:${LLVM_SLOT}[${flags}]" || return 1
+ fi
+ has_version "sys-devel/llvm:${LLVM_SLOT}[${flags}]"
+}
+
+pkg_pretend() {
+ if use vulkan; then
+ if ! use video_cards_i965 &&
+ ! use video_cards_iris &&
+ ! use video_cards_radeonsi &&
+ ! use video_cards_v3d; then
+ ewarn "Ignoring USE=vulkan since VIDEO_CARDS does not contain i965, iris, radeonsi, or v3d"
+ fi
+ fi
+
+ if use opencl; then
+ if ! use video_cards_r600 &&
+ ! use video_cards_radeonsi; then
+ ewarn "Ignoring USE=opencl since VIDEO_CARDS does not contain r600 or radeonsi"
+ fi
+ fi
+
+ if use vaapi; then
+ if ! use video_cards_r600 &&
+ ! use video_cards_radeonsi &&
+ ! use video_cards_nouveau; then
+ ewarn "Ignoring USE=vaapi since VIDEO_CARDS does not contain r600, radeonsi, or nouveau"
+ fi
+ fi
+
+ if use vdpau; then
+ if ! use video_cards_r300 &&
+ ! use video_cards_r600 &&
+ ! use video_cards_radeonsi &&
+ ! use video_cards_nouveau; then
+ ewarn "Ignoring USE=vdpau since VIDEO_CARDS does not contain r300, r600, radeonsi, or nouveau"
+ fi
+ fi
+
+ if use xa; then
+ if ! use video_cards_freedreno &&
+ ! use video_cards_nouveau &&
+ ! use video_cards_vmware; then
+ ewarn "Ignoring USE=xa since VIDEO_CARDS does not contain freedreno, nouveau, or vmware"
+ fi
+ fi
+
+ if use xvmc; then
+ if ! use video_cards_r600 &&
+ ! use video_cards_nouveau; then
+ ewarn "Ignoring USE=xvmc since VIDEO_CARDS does not contain r600 or nouveau"
+ fi
+ fi
+
+ if ! use gallium; then
+ use lm-sensors && ewarn "Ignoring USE=lm-sensors since USE does not contain gallium"
+ use llvm && ewarn "Ignoring USE=llvm since USE does not contain gallium"
+ use opencl && ewarn "Ignoring USE=opencl since USE does not contain gallium"
+ use vaapi && ewarn "Ignoring USE=vaapi since USE does not contain gallium"
+ use vdpau && ewarn "Ignoring USE=vdpau since USE does not contain gallium"
+ use unwind && ewarn "Ignoring USE=unwind since USE does not contain gallium"
+ use xa && ewarn "Ignoring USE=xa since USE does not contain gallium"
+ use xvmc && ewarn "Ignoring USE=xvmc since USE does not contain gallium"
+ fi
+
+ if ! use llvm; then
+ use opencl && ewarn "Ignoring USE=opencl since USE does not contain llvm"
+ fi
+
+ if use osmesa && ! use llvm; then
+ ewarn "OSMesa will be slow without enabling USE=llvm"
+ fi
+}
+
+python_check_deps() {
+ has_version -b ">=dev-python/mako-0.8.0[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+ # warning message for bug 459306
+ if use llvm && has_version sys-devel/llvm[!debug=]; then
+ ewarn "Mismatch between debug USE flags in media-libs/mesa and sys-devel/llvm"
+ ewarn "detected! This can cause problems. For details, see bug 459306."
+ fi
+
+ if use video_cards_i965 ||
+ use video_cards_iris ||
+ use video_cards_radeonsi; then
+ if kernel_is -ge 5 11 3; then
+ CONFIG_CHECK="~KCMP"
+ elif kernel_is -ge 5 11; then
+ CONFIG_CHECK="~CHECKPOINT_RESTORE"
+ elif kernel_is -ge 5 10 20; then
+ CONFIG_CHECK="~KCMP"
+ else
+ CONFIG_CHECK="~CHECKPOINT_RESTORE"
+ fi
+ linux-info_pkg_setup
+ fi
+
+ if use gallium && use llvm; then
+ llvm_pkg_setup
+ fi
+ python-any-r1_pkg_setup
+}
+
+multilib_src_configure() {
+ local emesonargs=()
+
+ if use classic; then
+ # Intel code
+ dri_driver_enable video_cards_i915 i915
+ dri_driver_enable video_cards_i965 i965
+ if ! use video_cards_i915 && \
+ ! use video_cards_i965; then
+ dri_driver_enable video_cards_intel i915 i965
+ fi
+
+ # Nouveau code
+ dri_driver_enable video_cards_nouveau nouveau
+
+ # ATI code
+ dri_driver_enable video_cards_r100 r100
+ dri_driver_enable video_cards_r200 r200
+ if ! use video_cards_r100 && \
+ ! use video_cards_r200; then
+ dri_driver_enable video_cards_radeon r100 r200
+ fi
+ fi
+
+ local platforms
+ use X && platforms+="x11"
+ use wayland && platforms+=",wayland"
+ emesonargs+=(-Dplatforms=${platforms#,})
+
+ if use X || use egl; then
+ emesonargs+=(-Dglvnd=true)
+ else
+ emesonargs+=(-Dglvnd=false)
+ fi
+
+ if use gallium; then
+ emesonargs+=(
+ $(meson_feature llvm)
+ $(meson_feature lm-sensors lmsensors)
+ $(meson_feature unwind libunwind)
+ )
+
+ if use video_cards_iris ||
+ use video_cards_r300 ||
+ use video_cards_r600 ||
+ use video_cards_radeonsi ||
+ use video_cards_nouveau ||
+ use video_cards_vmware; then
+ emesonargs+=($(meson_use d3d9 gallium-nine))
+ else
+ emesonargs+=(-Dgallium-nine=false)
+ fi
+
+ if use video_cards_r600 ||
+ use video_cards_radeonsi ||
+ use video_cards_nouveau; then
+ emesonargs+=($(meson_feature vaapi gallium-va))
+ use vaapi && emesonargs+=( -Dva-libs-path="${EPREFIX}"/usr/$(get_libdir)/va/drivers )
+ else
+ emesonargs+=(-Dgallium-va=disabled)
+ fi
+
+ if use video_cards_r300 ||
+ use video_cards_r600 ||
+ use video_cards_radeonsi ||
+ use video_cards_nouveau; then
+ emesonargs+=($(meson_feature vdpau gallium-vdpau))
+ else
+ emesonargs+=(-Dgallium-vdpau=disabled)
+ fi
+
+ if use video_cards_freedreno ||
+ use video_cards_nouveau ||
+ use video_cards_vmware; then
+ emesonargs+=($(meson_feature xa gallium-xa))
+ else
+ emesonargs+=(-Dgallium-xa=disabled)
+ fi
+
+ if use video_cards_r600 ||
+ use video_cards_nouveau; then
+ emesonargs+=($(meson_feature xvmc gallium-xvmc))
+ else
+ emesonargs+=(-Dgallium-xvmc=disabled)
+ fi
+
+ if use video_cards_freedreno ||
+ use video_cards_lima ||
+ use video_cards_panfrost ||
+ use video_cards_v3d ||
+ use video_cards_vc4 ||
+ use video_cards_vivante; then
+ gallium_enable -- kmsro
+ fi
+
+ gallium_enable -- swrast
+ gallium_enable video_cards_lima lima
+ gallium_enable video_cards_panfrost panfrost
+ gallium_enable video_cards_v3d v3d
+ gallium_enable video_cards_vc4 vc4
+ gallium_enable video_cards_vivante etnaviv
+ gallium_enable video_cards_vmware svga
+ gallium_enable video_cards_nouveau nouveau
+ gallium_enable zink zink
+
+ # Only one i915 driver (classic vs gallium). Default to classic.
+ if ! use classic; then
+ gallium_enable video_cards_i915 i915
+ if ! use video_cards_i915 && \
+ ! use video_cards_i965; then
+ gallium_enable video_cards_intel i915
+ fi
+ fi
+
+ gallium_enable video_cards_iris iris
+
+ gallium_enable video_cards_r300 r300
+ gallium_enable video_cards_r600 r600
+ gallium_enable video_cards_radeonsi radeonsi
+ if ! use video_cards_r300 && \
+ ! use video_cards_r600; then
+ gallium_enable video_cards_radeon r300 r600
+ fi
+
+ gallium_enable video_cards_freedreno freedreno
+ gallium_enable video_cards_virgl virgl
+
+ # opencl stuff
+ emesonargs+=(
+ -Dgallium-opencl="$(usex opencl icd disabled)"
+ )
+ fi
+
+ if use vulkan; then
+ vulkan_enable video_cards_i965 intel
+ vulkan_enable video_cards_iris intel
+ vulkan_enable video_cards_radeonsi amd
+ vulkan_enable video_cards_v3d broadcom
+ fi
+
+ driver_list() {
+ local drivers="$(sort -u <<< "${1// /$'\n'}")"
+ echo "${drivers//$'\n'/,}"
+ }
+
+ emesonargs+=(
+ $(meson_use test build-tests)
+ -Dglx=$(usex X dri disabled)
+ -Dshared-glapi=enabled
+ $(meson_feature dri3)
+ $(meson_feature egl)
+ $(meson_feature gbm)
+ $(meson_feature gles1)
+ $(meson_feature gles2)
+ $(meson_use osmesa)
+ $(meson_use selinux)
+ $(meson_feature zstd)
+ -Dvalgrind=$(usex valgrind auto false)
+ -Ddri-drivers=$(driver_list "${DRI_DRIVERS[*]}")
+ -Dgallium-drivers=$(driver_list "${GALLIUM_DRIVERS[*]}")
+ -Dvulkan-drivers=$(driver_list "${VULKAN_DRIVERS[*]}")
+ $(meson_use vulkan vulkan-device-select-layer)
+ $(meson_use vulkan-overlay vulkan-overlay-layer)
+ --buildtype $(usex debug debug plain)
+ -Db_ndebug=$(usex debug false true)
+ )
+ meson_src_configure
+}
+
+multilib_src_test() {
+ meson_src_test -t 100
+}
+
+# $1 - VIDEO_CARDS flag (check skipped for "--")
+# other args - names of DRI drivers to enable
+dri_driver_enable() {
+ if [[ $1 == -- ]] || use $1; then
+ shift
+ DRI_DRIVERS+=("$@")
+ fi
+}
+
+gallium_enable() {
+ if [[ $1 == -- ]] || use $1; then
+ shift
+ GALLIUM_DRIVERS+=("$@")
+ fi
+}
+
+vulkan_enable() {
+ if [[ $1 == -- ]] || use $1; then
+ shift
+ VULKAN_DRIVERS+=("$@")
+ fi
+}
diff --git a/media-libs/mesa/mesa-9999.ebuild b/media-libs/mesa/mesa-9999.ebuild
index b57fb6ce0dfe..dd671cef87a0 100644
--- a/media-libs/mesa/mesa-9999.ebuild
+++ b/media-libs/mesa/mesa-9999.ebuild
@@ -5,7 +5,7 @@ EAPI=7
PYTHON_COMPAT=( python3_{7,8,9} )
-inherit llvm meson multilib-minimal python-any-r1 linux-info
+inherit llvm meson-multilib python-any-r1 linux-info
OPENGL_DIR="xorg-x11"
@@ -524,18 +524,6 @@ multilib_src_configure() {
meson_src_configure
}
-multilib_src_compile() {
- meson_src_compile
-}
-
-multilib_src_install() {
- meson_src_install
-}
-
-multilib_src_install_all() {
- einstalldocs
-}
-
multilib_src_test() {
meson_src_test -t 100
}
generated by cgit v1.2.3 (git 2.25.1) at 2024-07-03 00:03:51 +0000