1 files changed, 0 insertions, 67 deletions
diff --git a/media-libs/jbig2dec/jbig2dec-0.17.ebuild b/media-libs/jbig2dec/jbig2dec-0.17.ebuild
deleted file mode 100644
index 0a030167ed52..000000000000
--- a/media-libs/jbig2dec/jbig2dec-0.17.ebuild
+++ /dev/null
@@ -1,67 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
-
-inherit autotools python-any-r1
-
-DESCRIPTION="A decoder implementation of the JBIG2 image compression format"
-HOMEPAGE="https://jbig2dec.com/"
-SRC_URI="https://github.com/ArtifexSoftware/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz
-	test? ( http://jbig2dec.sourceforge.net/ubc/jb2streams.zip )"
-
-LICENSE="AGPL-3"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
-IUSE="png static-libs test"
-
-BDEPEND="
-	test? (
-		app-arch/unzip
-		${PYTHON_DEPS}
-	)"
-
-RDEPEND="png? ( media-libs/libpng:0= )"
-DEPEND="${RDEPEND}"
-
-DOCS=( CHANGES README )
-
-PATCHES=( "${FILESDIR}"/${PN}-0.17-fix-test_jbig2dec.py.patch )
-
-pkg_setup() {
-	use test && python-any-r1_pkg_setup
-}
-
-src_prepare() {
-	default
-
-	if use test; then
-		mkdir "${WORKDIR}/ubc" || die
-		mv -v "${WORKDIR}"/*.jb2 "${WORKDIR}/ubc/" || die
-		mv -v "${WORKDIR}"/*.bmp "${WORKDIR}/ubc/" || die
-	fi
-
-	# We only need configure.ac and config_types.h.in
-	sed -i \
-		-e '/^# do we need automake?/,/^autoheader/d' \
-		-e '/echo "  $AUTOM.*/,$d' \
-		autogen.sh \
-		|| die "failed to modify autogen.sh"
-
-	./autogen.sh || die
-
-	eautoreconf
-}
-
-src_configure() {
-	econf \
-		$(use_enable static-libs static) \
-		$(use_with png libpng)
-}
-
-src_install() {
-	default
-	find "${ED}" -name '*.la' -exec rm {} + || die
-}