1 files changed, 61 insertions, 0 deletions
diff --git a/media-libs/flac/flac-1.3.3-r1.ebuild b/media-libs/flac/flac-1.3.3-r1.ebuild
new file mode 100644
index 000000000000..fc6ee1ef776f
--- /dev/null
+++ b/media-libs/flac/flac-1.3.3-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit multilib-minimal
+
+DESCRIPTION="free lossless audio encoder and decoder"
+HOMEPAGE="https://xiph.org/flac/"
+SRC_URI="https://downloads.xiph.org/releases/${PN}/${P}.tar.xz"
+
+LICENSE="BSD FDL-1.2 GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~mips ppc ppc64 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="+cxx debug ogg cpu_flags_ppc_altivec cpu_flags_ppc_vsx cpu_flags_x86_sse static-libs"
+
+RDEPEND="ogg? ( >=media-libs/libogg-1.3.0[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}
+	abi_x86_32? ( dev-lang/nasm )
+"
+BDEPEND="
+	app-arch/xz-utils
+	virtual/pkgconfig
+	!elibc_uclibc? ( sys-devel/gettext )
+"
+
+PATCHES=( "${FILESDIR}/${P}-fix-zero-first-byte-md5sum-check.patch" )
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--disable-doxygen-docs
+		--disable-examples
+		--disable-xmms-plugin
+		$([[ ${CHOST} == *-darwin* ]] && echo "--disable-asm-optimizations")
+		$(use_enable cpu_flags_ppc_altivec altivec)
+		$(use_enable cpu_flags_ppc_vsx vsx)
+		$(use_enable cpu_flags_x86_sse sse)
+		$(use_enable cxx cpplibs)
+		$(use_enable debug)
+		$(use_enable ogg)
+		$(use_enable static-libs static)
+
+		# cross-compile fix (bug #521446)
+		# no effect if ogg support is disabled
+		--with-ogg
+	)
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_test() {
+	if [[ ${UID} != 0 ]]; then
+		emake -j1 check
+	else
+		ewarn "Tests will fail if ran as root, skipping."
+	fi
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	find "${ED}" -type f -name '*.la' -delete || die
+}