1 files changed, 0 insertions, 136 deletions
diff --git a/mail-mta/msmtp/msmtp-1.6.8-r2.ebuild b/mail-mta/msmtp/msmtp-1.6.8-r2.ebuild
deleted file mode 100644
index 8fadb17207e5..000000000000
--- a/mail-mta/msmtp/msmtp-1.6.8-r2.ebuild
+++ /dev/null
@@ -1,136 +0,0 @@
-# Copyright 1999-2018 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit multilib
-
-DESCRIPTION="An SMTP client and SMTP plugin for mail user agents such as Mutt"
-HOMEPAGE="https://marlam.de/msmtp/"
-SRC_URI="https://marlam.de/msmtp/releases/${P}.tar.xz"
-
-LICENSE="GPL-3"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
-IUSE="doc gnome-keyring gnutls idn libressl +mta nls sasl ssl vim-syntax"
-
-DEPEND="
-	gnome-keyring? ( app-crypt/libsecret )
-	idn? ( net-dns/libidn:= )
-	nls? ( virtual/libintl )
-	sasl? ( virtual/gsasl )
-	ssl? (
-		gnutls? ( net-libs/gnutls )
-		!gnutls? (
-			!libressl? ( dev-libs/openssl:0= )
-			libressl? ( dev-libs/libressl:0= )
-		)
-	)
-"
-
-RDEPEND="${DEPEND}
-	net-mail/mailbase
-	mta? (
-		!mail-mta/courier
-		!mail-mta/esmtp
-		!mail-mta/exim
-		!mail-mta/mini-qmail
-		!mail-mta/netqmail
-		!mail-mta/nullmailer
-		!mail-mta/postfix
-		!mail-mta/qmail-ldap
-		!mail-mta/sendmail
-		!mail-mta/opensmtpd
-		!<mail-mta/ssmtp-2.64-r2
-		!>=mail-mta/ssmtp-2.64-r2[mta]
-	)
-"
-
-BDEPEND="${DEPEND}
-	doc? ( virtual/texi2dvi )
-	nls? ( sys-devel/gettext )
-	virtual/pkgconfig
-"
-
-REQUIRED_USE="gnutls? ( ssl )"
-
-DOCS="AUTHORS ChangeLog NEWS README THANKS doc/msmtprc*"
-
-src_prepare() {
-	# Use default Gentoo location for mail aliases
-	sed -i 's:/etc/aliases:/etc/mail/aliases:' scripts/find_alias/find_alias_for_msmtp.sh || die
-
-	default
-}
-
-src_configure() {
-	local myeconfargs=(
-		$(use_enable nls)
-		$(use_with gnome-keyring libsecret)
-		$(use_with idn libidn)
-		$(use_with sasl libgsasl)
-		$(use_with ssl tls $(usex gnutls gnutls openssl))
-	)
-	econf "${myeconfargs[@]}"
-}
-
-src_compile() {
-	default
-
-	if use doc ; then
-		cd doc || die
-		emake html pdf
-	fi
-}
-
-src_install() {
-	default
-
-	if use doc ; then
-		dodoc doc/msmtp.{html,pdf}
-	fi
-
-	if use mta ; then
-		dodir /usr/sbin
-		dosym ../bin/msmtp /usr/sbin/sendmail
-		dosym msmtp /usr/bin/sendmail
-		dosym ../bin/msmtp /usr/$(get_libdir)/sendmail
-	fi
-
-	if use vim-syntax ; then
-		insinto /usr/share/vim/vimfiles/syntax
-		doins scripts/vim/msmtp.vim
-	fi
-
-	insinto /etc
-	newins doc/msmtprc-system.example msmtprc
-
-	src_install_contrib find_alias find_alias_for_msmtp.sh
-	src_install_contrib msmtpqueue "*.sh" "README ChangeLog"
-	src_install_contrib msmtpq "msmtpq msmtp-queue" README.msmtpq
-	src_install_contrib set_sendmail set_sendmail.sh set_sendmail.conf
-}
-
-pkg_postinst() {
-	if [[ -z ${REPLACING_VERSIONS} ]]; then
-		einfo "Please edit ${ROOT}etc/msmtprc before first use."
-		einfo "In addition, per user configuration files can be placed"
-		einfo "as '~/.msmtprc'.  See the msmtprc-user.example file under"
-		einfo "/usr/share/doc/${PF}/ for an example."
-	fi
-}
-
-src_install_contrib() {
-	subdir="$1"
-	bins="$2"
-	docs="$3"
-	local dir=/usr/share/${PN}/${subdir}
-	insinto ${dir}
-	exeinto ${dir}
-	for i in ${bins} ; do
-		doexe scripts/${subdir}/${i}
-	done
-	for i in ${docs} ; do
-		newdoc scripts/${subdir}/${i} ${subdir}.${i}
-	done
-}