1 files changed, 63 insertions, 0 deletions
diff --git a/kde-plasma/drkonqi/drkonqi-5.26.0.ebuild b/kde-plasma/drkonqi/drkonqi-5.26.0.ebuild
new file mode 100644
index 000000000000..85dd047cbb11
--- /dev/null
+++ b/kde-plasma/drkonqi/drkonqi-5.26.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KFMIN=5.99.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.5
+inherit ecm plasma.kde.org
+
+DESCRIPTION="Plasma crash handler, gives the user feedback if a program crashed"
+SRC_URI+=" https://dev.gentoo.org/~asturm/distfiles/${PN}-5.26.0-revert-add-sentry-support.patch.xz"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64"
+IUSE=""
+
+COMMON_DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kidletime-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwayland-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/syntax-highlighting-${KFMIN}:5
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+"
+RDEPEND="${COMMON_DEPEND}
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5[qml]
+	|| (
+		sys-devel/gdb
+		dev-util/lldb
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-5.25.90-unused-dep.patch" # git master
+	"${WORKDIR}/${P}-revert-add-sentry-support.patch" # bug 871759
+)
+
+src_test() {
+	# needs network access, bug #698510
+	local myctestargs=(
+		-E "(connectiontest)"
+	)
+	ecm_src_test
+}