1 files changed, 61 insertions, 0 deletions
diff --git a/kde-apps/kwrite/kwrite-22.08.0.ebuild b/kde-apps/kwrite/kwrite-22.08.0.ebuild
new file mode 100644
index 000000000000..0994c1be1f37
--- /dev/null
+++ b/kde-apps/kwrite/kwrite-22.08.0.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KDE_ORG_NAME="kate"
+ECM_HANDBOOK="optional"
+KFMIN=5.96.0
+QTMIN=5.15.5
+inherit ecm flag-o-matic gear.kde.org
+
+DESCRIPTION="Simple text editor based on KDE Frameworks"
+HOMEPAGE="https://apps.kde.org/kwrite/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE=""
+
+RDEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	~kde-apps/kate-lib-${PV}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	ecm_src_prepare
+
+	# these tests are run in kde-apps/kate-lib
+	cmake_run_in apps/lib cmake_comment_add_subdirectory autotests
+
+	# delete colliding kate translations
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		find po -type f -name "*po" -and -not -name "kwrite*" -delete || die
+		rm -rf po/*/docs/kate* || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_addons=FALSE
+		-DBUILD_kate=FALSE
+	)
+	use handbook && mycmakeargs+=( -DBUILD_katepart=FALSE )
+
+	# provided by kde-apps/kate-lib
+	append-libs -lkateprivate
+
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+
+	# provided by kde-apps/kate-lib
+	rm -v "${ED}"/usr/$(get_libdir)/libkateprivate.so.* || die
+}