1 files changed, 57 insertions, 0 deletions
diff --git a/gui-libs/gtk-layer-shell/gtk-layer-shell-0.9.1.ebuild b/gui-libs/gtk-layer-shell/gtk-layer-shell-0.9.1.ebuild
new file mode 100644
index 000000000000..3c1385e2ef95
--- /dev/null
+++ b/gui-libs/gtk-layer-shell/gtk-layer-shell-0.9.1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 2020-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+VALA_USE_DEPEND="vapigen"
+inherit vala meson python-any-r1
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/wmww/${PN}"
+else
+	SRC_URI="https://github.com/wmww/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+DESCRIPTION="Library to create desktop components for Wayland using the Layer Shell protocol"
+HOMEPAGE="https://github.com/wmww/gtk-layer-shell"
+
+LICENSE="MIT-with-advertising LGPL-3+"
+SLOT="0"
+IUSE="examples gtk-doc introspection test vala"
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="vala? ( introspection )"
+
+DEPEND="
+	>=x11-libs/gtk+-3.24.39:3[introspection?,wayland]
+	>=dev-libs/wayland-1.10.0
+	>=dev-libs/wayland-protocols-1.16
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	dev-util/wayland-scanner
+	virtual/pkgconfig
+	x11-base/xorg-proto
+	gtk-doc? ( dev-util/gtk-doc )
+	test? ( ${PYTHON_DEPS} )
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	default
+	use vala && vala_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use examples)
+		$(meson_use gtk-doc docs)
+		$(meson_use test tests)
+		$(meson_use introspection)
+		$(meson_use vala vapi)
+	)
+	meson_src_configure
+}