1 files changed, 41 insertions, 0 deletions
diff --git a/gui-apps/wf-recorder/wf-recorder-0.4.1.ebuild b/gui-apps/wf-recorder/wf-recorder-0.4.1.ebuild
new file mode 100644
index 000000000000..3a7ded597607
--- /dev/null
+++ b/gui-apps/wf-recorder/wf-recorder-0.4.1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 2020-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+DESCRIPTION="Screen recorder for wlroots-based compositors"
+HOMEPAGE="https://github.com/ammen99/wf-recorder"
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/ammen99/wf-recorder.git"
+else
+	SRC_URI="https://github.com/ammen99/wf-recorder/releases/download/v${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="pulseaudio"
+
+DEPEND="
+	dev-libs/wayland
+	media-libs/mesa[wayland]
+	media-video/ffmpeg[pulseaudio?,x264]
+	pulseaudio? ( media-libs/libpulse )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	dev-libs/wayland-protocols
+	dev-util/wayland-scanner
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature pulseaudio pulse)
+	)
+	meson_src_configure
+}