4 files changed, 133 insertions, 0 deletions
diff --git a/games-action/chickens/Manifest b/games-action/chickens/Manifest
new file mode 100644
index 000000000000..b865dfc7d5cd
--- /dev/null
+++ b/games-action/chickens/Manifest
@@ -0,0 +1,6 @@
+DIST ChickensForLinux-Linux-0.2.4.tar.gz 1455207 SHA256 604dc614793b5bee2346639df14ab846cf878fed09ef695804d5aa21d85b518b SHA512 d94a70818a766fde443e86184418990d789246c239da01c6c1a2c9e7d8c1d6bb52ed28efbb4ecdb6b079c585e1ba18bc8efcd4f1cbf718ff39757831265c7a78 WHIRLPOOL 2b1d7c088dac8d975eb7b45b138f6786ae6aaa6bcaf5be1554b80f8fa397560a43d209c0fe5fd0491531b1f1e41db1706482bab23c85f00f86482db0b3070947
+EBUILD chickens-0.2.4-r1.ebuild 1468 SHA256 aa39439463f849cb0a0bd6a47eaa9ffb5331eb0f12c04bc53a5905aef372698d SHA512 20715e652c0c8554eb6a443f689e0074f2f964ad327c16a8aab466aac5e969b22c8c6745101c1eec338a0daa8969a9996a6fbf276019aa68d08900d06d7add55 WHIRLPOOL 05d540e5a1691c0b043cde15ba5863a3ec709939a444e7410dccc6c393f68ed9c796850de2ccc8a2ef8042fb375f502afb9cf5e8bc5de85eaa182acacecf3b3d
+EBUILD chickens-0.2.4.ebuild 1355 SHA256 2c37af45c60e081be7a471d2705d351f7225e6c6666856322d03fc48801826da SHA512 a10c30865121c965140026a5ce4b42bd7955b5831a73d87a61b41bf9a7535f642155ffc60feed5828079fcf242523e44b8712aa1976de5ba9f75796f78974324 WHIRLPOOL 4e2f69b42fbc964acc43e43764a760851ee48943f1ddb54f77b2da29f2ba5f33864f466a02a7c70460ce943893f8864e30f363320add0d09c73a440c224e4a85
+MISC ChangeLog 3261 SHA256 393a898ebc0f931930866d169562554411dfbfdbec0c4e3b12c0bc59803dcf90 SHA512 7b3cc06593187d744cd936b481341dd064c33abb6d84e6b2445b49c46e6c775f24f36b976eef8289937dbe8bb21477255bc6e8e931a3fd06e9e1dd4974434c7b WHIRLPOOL 7bc3f27f47d4d6f9676ea0d56b3272d1ed1e5c2554dd64b35ba6d775ad57bb89ff6f39277db5b4e0d25c43dee35f6840ea1639ae505e7903663c03ee7c77008a
+MISC ChangeLog-2015 2492 SHA256 c6486d2d03dd40260d44cb9353d3b8f693a011a17426ef98dbc785448a189016 SHA512 930a2aac2f16dd045e88d170a87f4a3d0f06bb59f94a8f9e2878ec3e2c016cde46735983959e9f4cb805004ddf8404e0fc51bdbae773b03aff573052974ab241 WHIRLPOOL 4d928d224cc36c431327973b8f04727bfa5dae35f3ca358c21aec013d52fbeedf38b7560302a5cb2d28633a8b0e4ae72ad336ce3adcab3462093a07dd0093df7
+MISC metadata.xml 249 SHA256 943b9ce0cd072229b43569ab668dd7ec741d9dfefd942c8921dabd4490b27b0c SHA512 895577c3a805c40581da03057b94e3f28f05f23012bf350c1e3575847d1a0fe40bb044a46f909012a200d991a400f6389358a60e9c2b5bef0da01fb26f846118 WHIRLPOOL b10e21575c78e201a652c8582cd16e3f7c86b13dd20a30f4cea44066fb139440b3c186147dbaae83478f11a20b6f457a99c8b29ee1239a4caaa21eee01250088
diff --git a/games-action/chickens/chickens-0.2.4-r1.ebuild b/games-action/chickens/chickens-0.2.4-r1.ebuild
new file mode 100644
index 000000000000..258e87e5303c
--- /dev/null
+++ b/games-action/chickens/chickens-0.2.4-r1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit eutils user
+
+MY_P="ChickensForLinux-Linux-${PV}"
+DESCRIPTION="Target chickens with rockets and shotguns. Funny"
+HOMEPAGE="http://www.chickensforlinux.com/"
+SRC_URI="http://www.chickensforlinux.com/${MY_P}.tar.gz"
+
+LICENSE="all-rights-reserved"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+RESTRICT="mirror bindist"
+
+DEPEND="<media-libs/allegro-5"
+RDEPEND="${DEPEND}"
+
+S=${WORKDIR}/${PN}
+
+pkg_setup(){
+	enewgroup gamestat 36
+}
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e "s:HighScores:/var/games//${PN}/HighScores:" \
+		-e "s:....\(.\)\(_\)\(.*.4x0\)\(.\):M\4\2\x42\x6Fn\1s\2:" \
+		highscore.cpp HighScores || die
+	sed -i \
+		-e "s:options.cfg:/etc/${PN}/options.cfg:" \
+		-e "s:\"sound/:\"/usr/share/${PN}/sound/:" \
+		-e "s:\"dat/:\"/usr/share/${PN}/dat/:" \
+		main.cpp README || die
+	sed -i \
+		-e '/^CPPFLAGS/d' \
+		-e 's:g++:\\$(CXX) \\$(CXXFLAGS) \\$(LDFLAGS):' \
+		configure || die
+}
+
+src_configure() {
+	# econf (sometimes) fails, see https://bugs.gentoo.org/588544
+	bash ./configure || die
+}
+
+src_install() {
+	dobin ${PN}
+	insinto /usr/share/${PN}
+	doins -r dat sound
+	dodoc AUTHOR README
+	insinto /var/games/${PN}
+	doins HighScores
+	insinto /etc/${PN}
+	doins options.cfg
+	make_desktop_entry ${PN} Chickens
+
+	fowners root:gamestat /usr/bin/${PN} /var/games/${PN}/HighScores
+	fperms 2755 /usr/bin/${PN}
+	fperms 660  /var/games/${PN}/HighScores
+}
diff --git a/games-action/chickens/chickens-0.2.4.ebuild b/games-action/chickens/chickens-0.2.4.ebuild
new file mode 100644
index 000000000000..b71e496fd44a
--- /dev/null
+++ b/games-action/chickens/chickens-0.2.4.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+inherit eutils games
+
+MY_P="ChickensForLinux-Linux-${PV}"
+DESCRIPTION="Target chickens with rockets and shotguns. Funny"
+HOMEPAGE="http://www.chickensforlinux.com/"
+SRC_URI="http://www.chickensforlinux.com/${MY_P}.tar.gz"
+
+LICENSE="all-rights-reserved"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE=""
+RESTRICT="mirror bindist"
+
+DEPEND="<media-libs/allegro-5"
+RDEPEND="${DEPEND}"
+
+S=${WORKDIR}/${PN}
+
+src_prepare() {
+	sed -i \
+		-e "s:HighScores:${GAMES_STATEDIR}/${PN}/HighScores:" \
+		-e "s:....\(.\)\(_\)\(.*.4x0\)\(.\):M\4\2\x42\x6Fn\1s\2:" \
+		highscore.cpp HighScores || die
+	sed -i \
+		-e "s:options.cfg:${GAMES_SYSCONFDIR}/${PN}/options.cfg:" \
+		-e "s:\"sound/:\"${GAMES_DATADIR}/${PN}/sound/:" \
+		-e "s:\"dat/:\"${GAMES_DATADIR}/${PN}/dat/:" \
+		main.cpp README || die
+	sed -i \
+		-e '/^CPPFLAGS/d' \
+		-e 's:g++:\\$(CXX) \\$(CXXFLAGS) \\$(LDFLAGS):' \
+		configure || die
+}
+
+src_configure() {
+	bash ./configure || die
+}
+
+src_install() {
+	dogamesbin ${PN}
+	insinto "${GAMES_DATADIR}"/${PN}
+	doins -r dat sound
+	dodoc AUTHOR README
+	insinto "${GAMES_STATEDIR}"/${PN}
+	doins HighScores
+	insinto "${GAMES_SYSCONFDIR}"/${PN}
+	doins options.cfg
+	fperms g+w "${GAMES_STATEDIR}"/${PN}/HighScores
+	make_desktop_entry ${PN} Chickens
+	prepgamesdirs
+}
diff --git a/games-action/chickens/metadata.xml b/games-action/chickens/metadata.xml
new file mode 100644
index 000000000000..78274e0fa550
--- /dev/null
+++ b/games-action/chickens/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<maintainer type="project">
+	<email>games@gentoo.org</email>
+	<name>Gentoo Games Project</name>
+</maintainer>
+</pkgmetadata>