1 files changed, 38 insertions, 0 deletions
diff --git a/dev-vcs/cvs-fast-export/cvs-fast-export-1.61.ebuild b/dev-vcs/cvs-fast-export/cvs-fast-export-1.61.ebuild
new file mode 100644
index 000000000000..29ba3be62c3e
--- /dev/null
+++ b/dev-vcs/cvs-fast-export/cvs-fast-export-1.61.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="fast-export history from a CVS repository or RCS collection"
+HOMEPAGE="http://www.catb.org/~esr/cvs-fast-export/"
+SRC_URI="http://www.catb.org/~esr/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+RESTRICT=test # upstream does not ship some tests in tarball
+
+BDEPEND="app-text/asciidoc"
+
+PATCHES=( "${FILESDIR}/${P}-Makefile.patch" )
+
+src_prepare() {
+	default
+	tc-export CC
+	export prefix="${EPREFIX}"/usr
+}
+
+src_compile() {
+	# '.adoc.html' rules can't be executed in parallel
+	# as they reuse the same 'docbook-xsl.css' file name.
+	emake -j1 html
+	# Allow full parallelism for the rest
+	emake
+}
+
+src_install() {
+	default
+	dodoc {NEWS,README,TODO,hacking,reporting-bugs}.adoc
+}