1 files changed, 45 insertions, 0 deletions
diff --git a/dev-util/spirv-tools/spirv-tools-1.3.216.ebuild b/dev-util/spirv-tools/spirv-tools-1.3.216.ebuild
new file mode 100644
index 000000000000..3dd944ee727a
--- /dev/null
+++ b/dev-util/spirv-tools/spirv-tools-1.3.216.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN=SPIRV-Tools
+CMAKE_ECLASS="cmake"
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="xml(+)"
+inherit cmake-multilib python-any-r1
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/KhronosGroup/${MY_PN}.git"
+	inherit git-r3
+else
+	EGIT_COMMIT="sdk-${PV}.0"
+	SRC_URI="https://github.com/KhronosGroup/${MY_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+	S="${WORKDIR}"/${MY_PN}-${EGIT_COMMIT}
+fi
+
+DESCRIPTION="Provides an API and commands for processing SPIR-V modules"
+HOMEPAGE="https://github.com/KhronosGroup/SPIRV-Tools"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+# Tests fail upon finding symbols that do not match a regular expression
+# in the generated library. Easily hit with non-standard compiler flags
+RESTRICT="test"
+COMMON_DEPEND="~dev-util/spirv-headers-${PV}"
+DEPEND="${COMMON_DEPEND}"
+RDEPEND=""
+BDEPEND="${PYTHON_DEPS}
+	${COMMON_DEPEND}"
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		"-DSPIRV-Headers_SOURCE_DIR=${ESYSROOT}/usr/"
+		"-DSPIRV_WERROR=OFF"
+		"-DSPIRV_TOOLS_BUILD_STATIC=OFF"
+		"-DBUILD_SHARED_LIBS=ON"
+	)
+
+	cmake_src_configure
+}