1 files changed, 64 insertions, 0 deletions
diff --git a/dev-util/gn/gn-0.1943.ebuild b/dev-util/gn/gn-0.1943.ebuild
new file mode 100644
index 000000000000..57230dc162ed
--- /dev/null
+++ b/dev-util/gn/gn-0.1943.ebuild
@@ -0,0 +1,64 @@
+# Copyright 2018-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8,9,10} )
+
+inherit ninja-utils python-any-r1 toolchain-funcs
+
+DESCRIPTION="GN is a meta-build system that generates build files for Ninja"
+HOMEPAGE="https://gn.googlesource.com/"
+SRC_URI="https://dev.gentoo.org/~sultan/distfiles/dev-util/gn/${P}.tar.xz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="vim-syntax"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-util/ninja
+"
+
+PATCHES=(
+	"${FILESDIR}"/gn-gen-r5.patch
+)
+
+pkg_setup() {
+	:
+}
+
+src_configure() {
+	python_setup
+	tc-export AR CC CXX
+	unset CFLAGS
+	set -- ${EPYTHON} build/gen.py --no-last-commit-position --no-strip --no-static-libstdc++
+	echo "$@" >&2
+	"$@" || die
+	cat >out/last_commit_position.h <<-EOF || die
+	#ifndef OUT_LAST_COMMIT_POSITION_H_
+	#define OUT_LAST_COMMIT_POSITION_H_
+	#define LAST_COMMIT_POSITION_NUM ${PV##0.}
+	#define LAST_COMMIT_POSITION "${PV}"
+	#endif  // OUT_LAST_COMMIT_POSITION_H_
+	EOF
+}
+
+src_compile() {
+	eninja -C out gn
+}
+
+src_test() {
+	eninja -C out gn_unittests
+	out/gn_unittests || die
+}
+
+src_install() {
+	dobin out/gn
+	einstalldocs
+
+	if use vim-syntax; then
+		insinto /usr/share/vim/vimfiles
+		doins -r misc/vim/{autoload,ftdetect,ftplugin,syntax}
+	fi
+}