3 files changed, 230 insertions, 2 deletions
diff --git a/dev-util/cmake/Manifest b/dev-util/cmake/Manifest
index 22a9844ce8b9..17c67e23b8ec 100644
--- a/dev-util/cmake/Manifest
+++ b/dev-util/cmake/Manifest
@@ -17,8 +17,10 @@ DIST cmake-3.13.5.tar.gz 8618821 BLAKE2B 765678bc92821207c53bfb4ac995a791b938f20
 DIST cmake-3.14.3.tar.gz 8851085 BLAKE2B 92da2c563f7ddc3b12457f63eead850eb99b123298632b5a9e8f80f3e32db20e2b25bc60778855400261d13d4ef42600162248f4a92907a0c581e202fc6620eb SHA512 e257a96334f21f2b2f17e8d43aa32c2b069d13194604393c5ac9d3da193000d5328181c6cf861696186d022aba57679ee2d08073d8a7112727746b2b145a47e2
 DIST cmake-3.14.6.tar.gz 8861359 BLAKE2B 257a9a89fe880f8945f47a4bb1980e66f0f28ee5cebeb161012860ae8578487e50c60060ad5144ec6f5b7ea860112edd01909ebceec24b8370e3769ff2a79e99 SHA512 8cf3afadec3fe931d9f954e3148a398939cd16c1fbcb4c5303ac635e2b5029960867f317fd13a46fceebe46e7328689e847f03d7d7c74bb31e23c9cc55838f56
 DIST cmake-3.15.0.tar.gz 9266870 BLAKE2B e0ab6950d96a95c972e04dcdcecbf999262ddbd753784bec81954a85730279ef0298bdd7079d2d1095a14de7be5349749b1c5d54e022c6443e041e7e75cb0bab SHA512 f7286513a215a9b9094c1f630761995dbc7f4e33c38bc5585ddc89d9b4742630962921aff59570e0de39887e0cc66df6eebc83ab478796876364d2de5d2c0d6f
+DIST cmake-3.15.1.tar.gz 9268592 BLAKE2B 3b0dbca9203b1029922d06df9abc3bbfa6f7b8320e43b11b468cd7e129171e2bb1b645fc07bf2d46c9b3c08642f1a11741240d0029f96ac3b2d7a8bb44d398da SHA512 6900a84c7764034331fb6f00801841a7a3e667ac39813c35ceb3db983b33a5bf6addbbc8539c39a0c0be9e10204c79d6236886a9d50ce901a56275b53619ec73
 EBUILD cmake-3.13.5.ebuild 6215 BLAKE2B cfb13f69a7987ff65183910288f70cb3b0a10532af213fc9567ddf722f9aa5042235daa2fe093610b55b6b8f0c94937e452894edb7c54a2ddbe55ae053003238 SHA512 dddf1c391c2c9787f731acbc894e907118b83fcc1cffbb943338bb56a035b9220c7b4316ffb5bd4c411f6d0ac2b2631ed940a0760b0c7a5419fd49dfc8c58427
 EBUILD cmake-3.14.3.ebuild 6242 BLAKE2B f60aecf31afb3a1d18dcc73eb49a725692bbd2429398b05f9b241d82f9842b93aeece44624a50b8406355ff82bf2484bbae55ec863987b82d1e27d04e58b1d58 SHA512 22317c7a34fb11df8eedf9251520db7a956eb44306aa5c7c2d950de1aa0b2844043a84ede7122ea38fe144fea2f52760ac097b84063b1f2f5b8885c858d29c81
-EBUILD cmake-3.14.6.ebuild 6253 BLAKE2B 2b5c8c7939544f51c6b6b472e86c6e7b795b49ab9d862ebe379dbc8244903eb6821170b08e8b8bbfbf7638fda656580a2344b5acd3898aa9c4f7dd8d3fb58e33 SHA512 7a63955cd353be5138ebc8bc5ef360ecae494f0811c17dc77bf621f28f7594cc8c6619916f5d5d0f24250d891104d72521107a0beb4c35b392ef6c912d5f1066
+EBUILD cmake-3.14.6.ebuild 6242 BLAKE2B f60aecf31afb3a1d18dcc73eb49a725692bbd2429398b05f9b241d82f9842b93aeece44624a50b8406355ff82bf2484bbae55ec863987b82d1e27d04e58b1d58 SHA512 22317c7a34fb11df8eedf9251520db7a956eb44306aa5c7c2d950de1aa0b2844043a84ede7122ea38fe144fea2f52760ac097b84063b1f2f5b8885c858d29c81
 EBUILD cmake-3.15.0.ebuild 6253 BLAKE2B 4dc2e38854b99aa6b8aa80b8a044fa1e02211b9a7fb50c8f8f9161220e2313c4bc7af5d2af47f9c166ae85101313898f39603fa3bc73ad1159cda1398e012704 SHA512 9916b5c93b0a80ca38731d40a9d8d1538c4ec37563e8dcb2e9eea3ca622c09bbe119ec51a44ed3e74cc7c9d8bf27e1e46c7b0d49a2a15decf7d3ea4aa0ea010f
+EBUILD cmake-3.15.1.ebuild 6253 BLAKE2B 4dc2e38854b99aa6b8aa80b8a044fa1e02211b9a7fb50c8f8f9161220e2313c4bc7af5d2af47f9c166ae85101313898f39603fa3bc73ad1159cda1398e012704 SHA512 9916b5c93b0a80ca38731d40a9d8d1538c4ec37563e8dcb2e9eea3ca622c09bbe119ec51a44ed3e74cc7c9d8bf27e1e46c7b0d49a2a15decf7d3ea4aa0ea010f
 MISC metadata.xml 372 BLAKE2B de2835a1f98bccd88e343ab7c058b40df0e9aa4afe938770d67a6e764ac85926b369b6d9ac4851d5deec3954436d3cb8a112b5543ac1debf74205f05641ed2ee SHA512 6c457abaf6c174d6d14b77af47c4fb65b26873cbb7a5a4fbafc558ff4c5c7c6cb0200c0f69e7a492007af4b402baeaf54177f6755c3e6da0ace149eb9bcfe69a
diff --git a/dev-util/cmake/cmake-3.14.6.ebuild b/dev-util/cmake/cmake-3.14.6.ebuild
index b04b6c2e4330..01f4a37c8333 100644
--- a/dev-util/cmake/cmake-3.14.6.ebuild
+++ b/dev-util/cmake/cmake-3.14.6.ebuild
@@ -16,7 +16,7 @@ SRC_URI="https://cmake.org/files/v$(ver_cut 1-2)/${MY_P}.tar.gz"
 LICENSE="CMake"
 SLOT="0"
 [[ "${PV}" = *_rc* ]] || \
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~m68k ~mips ppc ppc64 s390 ~sh sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
 IUSE="doc emacs system-jsoncpp ncurses qt5 test"
 
 RDEPEND="
diff --git a/dev-util/cmake/cmake-3.15.1.ebuild b/dev-util/cmake/cmake-3.15.1.ebuild
new file mode 100644
index 000000000000..06184a6bfe5f
--- /dev/null
+++ b/dev-util/cmake/cmake-3.15.1.ebuild
@@ -0,0 +1,226 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+CMAKE_MAKEFILE_GENERATOR="emake"
+CMAKE_REMOVE_MODULES="no"
+inherit bash-completion-r1 elisp-common flag-o-matic toolchain-funcs virtualx xdg cmake-utils
+
+MY_P="${P/_/-}"
+
+DESCRIPTION="Cross platform Make"
+HOMEPAGE="https://cmake.org/"
+SRC_URI="https://cmake.org/files/v$(ver_cut 1-2)/${MY_P}.tar.gz"
+
+LICENSE="CMake"
+SLOT="0"
+[[ "${PV}" = *_rc* ]] || \
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc emacs system-jsoncpp ncurses qt5 test"
+
+RDEPEND="
+	app-crypt/rhash
+	>=app-arch/libarchive-3.0.0:=
+	>=dev-libs/expat-2.0.1
+	>=dev-libs/libuv-1.10.0:=
+	>=net-misc/curl-7.21.5[ssl]
+	sys-libs/zlib
+	virtual/pkgconfig
+	emacs? ( virtual/emacs )
+	ncurses? ( sys-libs/ncurses:0= )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+	)
+	system-jsoncpp? ( >=dev-libs/jsoncpp-0.6.0_rc2:0= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	doc? (
+		dev-python/requests
+		dev-python/sphinx
+	)
+"
+
+S="${WORKDIR}/${MY_P}"
+
+SITEFILE="50${PN}-gentoo.el"
+
+PATCHES=(
+	# prefix
+	"${FILESDIR}"/${PN}-3.4.0_rc1-darwin-bundle.patch
+	"${FILESDIR}"/${PN}-3.14.0_rc3-prefix-dirs.patch
+	# Next patch requires new work from prefix people
+	#"${FILESDIR}"/${PN}-3.1.0-darwin-isysroot.patch
+
+	# handle gentoo packaging in find modules
+	"${FILESDIR}"/${PN}-3.15.0_rc2-FindBLAS.patch
+	"${FILESDIR}"/${PN}-3.14.0_rc1-FindLAPACK.patch
+	"${FILESDIR}"/${PN}-3.5.2-FindQt4.patch
+
+	# respect python eclasses
+	"${FILESDIR}"/${PN}-2.8.10.2-FindPythonLibs.patch
+	"${FILESDIR}"/${PN}-3.9.0_rc2-FindPythonInterp.patch
+
+	# upstream fixes (can usually be removed with a version bump)
+)
+
+cmake_src_bootstrap() {
+	# Cleanup args to extract only JOBS.
+	# Because bootstrap does not know anything else.
+	grep -Eo '(\-j|\-\-jobs)(=?|[[:space:]]*)[[:digit:]]+' <<< "${MAKEOPTS}" > /dev/null
+	if [[ $? -eq 0 ]] ; then
+		par_arg=$(grep -Eo '(\-j|\-\-jobs)(=?|[[:space:]]*)[[:digit:]]+' <<< "${MAKEOPTS}" | tail -n1 | grep -o '[[:digit:]]+')
+		par_arg="--parallel=${par_arg}"
+	else
+		par_arg="--parallel=1"
+	fi
+
+	# disable running of cmake in boostrap command
+	sed -i \
+		-e '/"${cmake_bootstrap_dir}\/cmake"/s/^/#DONOTRUN /' \
+		bootstrap || die "sed failed"
+
+	# execinfo.h on Solaris isn't quite what it is on Darwin
+	if [[ ${CHOST} == *-solaris* ]] ; then
+		sed -i -e 's/execinfo\.h/blablabla.h/' \
+			Source/kwsys/CMakeLists.txt || die
+	fi
+
+	tc-export CC CXX LD
+
+	# bootstrap script isn't exactly /bin/sh compatible
+	${CONFIG_SHELL:-sh} ./bootstrap \
+		--prefix="${T}/cmakestrap/" \
+		${par_arg} \
+		|| die "Bootstrap failed"
+}
+
+cmake_src_test() {
+	# fix OutDir and SelectLibraryConfigurations tests
+	# these are altered thanks to our eclass
+	sed -i -e 's:^#_cmake_modify_IGNORE ::g' \
+		"${S}"/Tests/{OutDir,CMakeOnly/SelectLibraryConfigurations}/CMakeLists.txt \
+		|| die
+
+	pushd "${BUILD_DIR}" > /dev/null
+
+	local ctestargs
+	[[ -n ${TEST_VERBOSE} ]] && ctestargs="--extra-verbose --output-on-failure"
+
+	# Excluded tests:
+	#    BootstrapTest: we actualy bootstrap it every time so why test it.
+	#    BundleUtilities: bundle creation broken
+	#    CMakeOnly.AllFindModules: pthread issues
+	#    CTest.updatecvs: which fails to commit as root
+	#    Fortran: requires fortran
+	#    RunCMake.CompilerLauncher: also requires fortran
+	#    RunCMake.CPack_RPM: breaks if app-arch/rpm is installed because
+	#        debugedit binary is not in the expected location
+	#    RunCMake.CPack_DEB: breaks if app-arch/dpkg is installed because
+	#        it can't find a deb package that owns libc
+	#    TestUpload, which requires network access
+	"${BUILD_DIR}"/bin/ctest \
+		-j "$(makeopts_jobs)" \
+		--test-load "$(makeopts_loadavg)" \
+		${ctestargs} \
+		-E "(BootstrapTest|BundleUtilities|CMakeOnly.AllFindModules|CompileOptions|CTest.UpdateCVS|Fortran|RunCMake.CompilerLauncher|RunCMake.CPack_(DEB|RPM)|TestUpload)" \
+		|| die "Tests failed"
+
+	popd > /dev/null
+}
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	# disable Xcode hooks, bug #652134
+	if [[ ${CHOST} == *-darwin* ]] ; then
+		sed -i -e 's/__APPLE__/__DISABLED_APPLE__/' \
+			Source/cmGlobalXCodeGenerator.cxx || die
+	fi
+
+	# Add gcc libs to the default link paths
+	sed -i \
+		-e "s|@GENTOO_PORTAGE_GCCLIBDIR@|${EPREFIX}/usr/${CHOST}/lib/|g" \
+		-e "$(usex prefix-guest "s|@GENTOO_HOST@||" "/@GENTOO_HOST@/d")" \
+		-e "s|@GENTOO_PORTAGE_EPREFIX@|${EPREFIX}/|g" \
+		Modules/Platform/{UnixPaths,Darwin}.cmake || die "sed failed"
+	if ! has_version \>=${CATEGORY}/${PN}-3.4.0_rc1 ; then
+		CMAKE_BINARY="${S}/Bootstrap.cmk/cmake"
+		cmake_src_bootstrap
+	fi
+}
+
+src_configure() {
+	# Fix linking on Solaris
+	[[ ${CHOST} == *-solaris* ]] && append-ldflags -lsocket -lnsl
+
+	local mycmakeargs=(
+		-DCMAKE_USE_SYSTEM_LIBRARIES=ON
+		-DCMAKE_USE_SYSTEM_LIBRARY_JSONCPP=$(usex system-jsoncpp)
+		-DCMAKE_INSTALL_PREFIX="${EPREFIX}"/usr
+		-DCMAKE_DOC_DIR=/share/doc/${PF}
+		-DCMAKE_MAN_DIR=/share/man
+		-DCMAKE_DATA_DIR=/share/${PN}
+		-DSPHINX_MAN=$(usex doc)
+		-DSPHINX_HTML=$(usex doc)
+		-DBUILD_CursesDialog="$(usex ncurses)"
+		-DBUILD_TESTING=$(usex test)
+	)
+
+	if use qt5 ; then
+		mycmakeargs+=(
+			-DBUILD_QtDialog=ON
+			$(cmake-utils_use_find_package qt5 Qt5Widgets)
+		)
+	fi
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+	use emacs && elisp-compile Auxiliary/cmake-mode.el
+}
+
+src_test() {
+	virtx cmake_src_test
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	if use emacs; then
+		elisp-install ${PN} Auxiliary/cmake-mode.el Auxiliary/cmake-mode.elc
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+	fi
+
+	insinto /usr/share/vim/vimfiles/syntax
+	doins Auxiliary/vim/syntax/cmake.vim
+
+	insinto /usr/share/vim/vimfiles/indent
+	doins Auxiliary/vim/indent/cmake.vim
+
+	insinto /usr/share/vim/vimfiles/ftdetect
+	doins "${FILESDIR}/${PN}.vim"
+
+	dobashcomp Auxiliary/bash-completion/{${PN},ctest,cpack}
+
+	rm -r "${ED}"/usr/share/cmake/{completions,editors} || die
+}
+
+pkg_preinst() {
+	use qt5 && xdg_pkg_preinst
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+	use qt5 && xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+	use qt5 && xdg_pkg_postrm
+}