4 files changed, 92 insertions, 67 deletions
diff --git a/dev-util/bear/Manifest b/dev-util/bear/Manifest
index d5b6c3e2bfaf..579c594c05c8 100644
--- a/dev-util/bear/Manifest
+++ b/dev-util/bear/Manifest
@@ -1,5 +1,5 @@
-DIST bear-2.4.3.tar.gz 49933 BLAKE2B 2a91c30d81f9d0e58a25458579f6b0c867c07d2e532bd2ed29305645e152bd564156f708c4a07a683577412b3fdab1f106685ecf1ad88eaad2f33f0bc43a5baa SHA512 a4690cfc9938d8752ca5c8322ca4c5039746ade059e4459e7f3f91b2bf3d36ea691a5d855cab7a4e7ad8ff76478c48c4394593e069a1cf8396ead41017421753
 DIST bear-2.4.4.tar.gz 50347 BLAKE2B 73fa332cf97413e55c588f8830806a26c6905299af902c6cf1f39fd576c6261690239c1b502b28b5a2aa24e5ca521c3f1dd58aacd60e00ece4fe1840f5656155 SHA512 4ee3fd5c846149029fe9e4104e2a0d0e318a15215aa80fc5dc376e22ebea510384b02d4d62765495343cab537bacd2b1b0130c00246e081feb4e543761a594e5
-EBUILD bear-2.4.3.ebuild 1634 BLAKE2B e0adf19fb18817851269ce6ee51bc32a91ecadeded8245ff8febd2e521f5cb5a3892b862186e2bf58d893a6ea63b9fde70868c338563b3347518b186ada5ec62 SHA512 80713166f3397724f34824d1498ac338b6b5cfefa39b6dc323f190e01dfbbebee031c2ada1186cfe493006abd7a9294f3d70c66583c31db7b1bf0b154acdc0e0
-EBUILD bear-2.4.4.ebuild 1633 BLAKE2B 4669f532814c4f22c80c642a95e8793ab0b58a84e0ecf651168e098ff33f0e4ec55e0a0579beddc342d6fe2cef077ded616088d9f785b11ab8d36acc80840676 SHA512 e17b6bfbe52c00cacbe4a3115e62e6976a111f93d8b40b9db99e77e70d3fc626de713dc67001ec51a7bca8e9ea5c05f8ad29add91aa99311f8e277974f3330db
+DIST bear-3.0.11.tar.gz 118678 BLAKE2B 209d904a84363a87e566798dcd65ffed96cdbf3d2e753af8dc2706adb995d2999bc112eabb88db28791cbb245c373eb330cf9c20d3d886bb2caeb5c01150e65d SHA512 6d362aede911a8ad35be30638a698579582ca5de770a7c3199bb205046f08f355387099261b8d857188d526ab62024f78e3d06a225734c5f9acca03e5dfea1ec
+EBUILD bear-2.4.4.ebuild 1640 BLAKE2B 33c75872aa47499025a9296eb7bc535206d29215040e75c31c85b9b7667b035d9aee4886423ec6f5cab80aad3d5e15f6627aa7909957014872dffa2ba8223c56 SHA512 037fdf6bf071188df0027c6deb69a402dd721d44ff0e8ccf96dacc0b7692e6e9cd71901c284c984636bfeb49f5186a6881896ddfc1832106b0ba05e617335483
+EBUILD bear-3.0.11.ebuild 2069 BLAKE2B 66cb6e2029ceb432fb8d30ad83c7bb7b0a32e4910496f0e70eb616bb011797ceca967ddcb9c52fa94e8947831ddd5d71530abec2867a1085b0764b24db5c7248 SHA512 4b05dd82325cfbbfdbe8d843682dd14dd25a10c3785b270a58738f30f176a901f574542a5e2934c93a6f65c7158973df1e2957ce60833da39075d097cfcfc537
 MISC metadata.xml 914 BLAKE2B 791cac2c9a3850bc49848ec8f6ff889a21802ddce6937783afccdda45045b3861f0c79e44028ea6df18f046c5fc1b6ad89ac1a940afc9e4d6607507a12933382 SHA512 a7b29ce47f3c9d91f2ba5d1abf5975d64a9229619737b75d38d54b3bde860a47a859e6de7a959ad67cba21b2a0ced8a9fbaf508c02cace63c4090afbac2005ba
diff --git a/dev-util/bear/bear-2.4.3.ebuild b/dev-util/bear/bear-2.4.3.ebuild
deleted file mode 100644
index 83600bfdb38f..000000000000
--- a/dev-util/bear/bear-2.4.3.ebuild
+++ /dev/null
@@ -1,61 +0,0 @@
-# Copyright 2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python3_{7,8} )
-
-inherit cmake python-single-r1
-
-DESCRIPTION="Build EAR generates a compilation database for clang tooling"
-HOMEPAGE="https://github.com/rizsotto/Bear"
-SRC_URI="https://github.com/rizsotto/Bear/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="GPL-3+"
-SLOT="0"
-KEYWORDS="~amd64 ~ppc64"
-IUSE="test"
-
-REQUIRED_USE="${PYTHON_REQUIRED_USE}"
-
-DEPEND="test? (
-	app-shells/bash
-	$(python_gen_cond_dep '
-		dev-python/lit[${PYTHON_USEDEP}]
-	')
-)"
-
-RDEPEND="${PYTHON_DEPS}"
-
-RESTRICT="!test? ( test )"
-
-S="${WORKDIR}/${P^}"
-
-src_compile() {
-	cmake_src_compile
-	# need to fix it now, before tests are run
-	python_fix_shebang "${BUILD_DIR}"/bear/bear
-	python_fix_shebang test/functional/tools/cdb_diff.py
-}
-
-src_test() {
-	if has sandbox ${FEATURES}; then
-		ewarn "\'FEATURES=sandbox\' detected"
-		ewarn "Bear overrides LD_PRELOAD and conflicts with gentoo sandbox"
-		ewarn "Skipping tests"
-	elif
-		has usersandbox ${FEATURES}; then
-		ewarn "\'FEATURES=usersandbox\' detected"
-		ewarn "Skipping tests"
-	elif
-		has_version -b 'sys-devel/gcc-config[-native-symlinks]'; then
-		ewarn "\'sys-devel/gcc-config[-native-symlinks]\' detected, tests call /usr/bin/cc directly (hardcoded)"
-		ewarn "and will fail without generic cc symlink"
-		ewarn "Skipping tests"
-	else
-		einfo "removing unwanted/unsupported/xfail tests"
-		rm -v test/functional/cases/{end-to-end/scons.ft,intercept/cuda/successful_build.fts,run_pep8.ft} || die
-		einfo "test may use optional tools if found: qmake gfortran"
-		cmake_build check
-	fi
-}
diff --git a/dev-util/bear/bear-2.4.4.ebuild b/dev-util/bear/bear-2.4.4.ebuild
index 468a104719bb..9e2aef4064b7 100644
--- a/dev-util/bear/bear-2.4.4.ebuild
+++ b/dev-util/bear/bear-2.4.4.ebuild
@@ -1,9 +1,9 @@
-# Copyright 2020 Gentoo Authors
+# Copyright 2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
 
-PYTHON_COMPAT=( python3_{7,8} )
+PYTHON_COMPAT=( python3_{7,8,9} )
 
 inherit cmake python-single-r1
 
@@ -13,7 +13,7 @@ SRC_URI="https://github.com/rizsotto/Bear/archive/${PV}.tar.gz -> ${P}.tar.gz"
 
 LICENSE="GPL-3+"
 SLOT="0"
-KEYWORDS="~amd64 ~ppc64"
+KEYWORDS="~amd64 ~ppc64 ~x86"
 IUSE="test"
 
 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
diff --git a/dev-util/bear/bear-3.0.11.ebuild b/dev-util/bear/bear-3.0.11.ebuild
new file mode 100644
index 000000000000..ec5887766693
--- /dev/null
+++ b/dev-util/bear/bear-3.0.11.ebuild
@@ -0,0 +1,86 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit cmake python-any-r1
+
+DESCRIPTION="Build EAR generates a compilation database for clang tooling"
+HOMEPAGE="https://github.com/rizsotto/Bear"
+SRC_URI="https://github.com/rizsotto/Bear/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE="test"
+
+RDEPEND="
+	>=dev-cpp/nlohmann_json-3.7:=
+	>=dev-db/sqlite-3.14:=
+	>=dev-libs/libfmt-6.2
+	>=dev-libs/spdlog-1.5
+	>=net-libs/grpc-1.26
+"
+
+DEPEND="${RDEPEND}
+	test? (
+		>=dev-cpp/gtest-1.10
+	)
+"
+
+BDEPEND="test? (
+	$(python_gen_any_dep '
+		dev-python/lit[${PYTHON_USEDEP}]
+	')
+)"
+
+RESTRICT="!test? ( test )"
+
+S="${WORKDIR}/${P^}"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	cmake_src_prepare
+	# Turn off testing before installation
+	sed -i 's/TEST_BEFORE_INSTALL/TEST_EXCLUDE_FROM_MAIN/g' CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_UNIT_TESTS="$(usex test ON OFF)"
+		-DENABLE_FUNC_TESTS="$(usex test ON OFF)"
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	if has sandbox ${FEATURES}; then
+		ewarn "\'FEATURES=sandbox\' detected"
+		ewarn "Bear overrides LD_PRELOAD and conflicts with gentoo sandbox"
+		ewarn "Skipping tests"
+	elif
+		has usersandbox ${FEATURES}; then
+		ewarn "\'FEATURES=usersandbox\' detected"
+		ewarn "Skipping tests"
+	elif
+		has network-sandbox ${FEATURES}; then
+		ewarn "\'FEATURES=network-sandbox\' detected"
+		ewarn "Skipping tests"
+	elif
+		has_version -b 'sys-devel/gcc-config[-native-symlinks]'; then
+		ewarn "\'sys-devel/gcc-config[-native-symlinks]\' detected, tests call /usr/bin/cc directly (hardcoded)"
+		ewarn "and will fail without generic cc symlink"
+		ewarn "Skipping tests"
+	else
+		einfo "test may use optional tools if found: qmake gfortran valgrind"
+		# unit tests
+		cmake_run_in "${BUILD_DIR}/subprojects/Build/BearSource" ctest --verbose
+		# functional tests
+		cmake_run_in "${BUILD_DIR}/subprojects/Build/BearTest" ctest --verbose
+	fi
+}