1 files changed, 55 insertions, 0 deletions
diff --git a/dev-scheme/ypsilon/ypsilon-0.9.6_p3-r2.ebuild b/dev-scheme/ypsilon/ypsilon-0.9.6_p3-r2.ebuild
new file mode 100644
index 000000000000..552d06b82422
--- /dev/null
+++ b/dev-scheme/ypsilon/ypsilon-0.9.6_p3-r2.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic toolchain-funcs
+
+MY_P="${P/_p/.update}"
+
+DESCRIPTION="R6RS-compliant Scheme implementation for real-time applications"
+HOMEPAGE="http://www.littlewingpinball.com/doc/en/ypsilon"
+SRC_URI="https://storage.googleapis.com/google-code-archive-downloads/v2/code.google.com/${PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples"
+
+RDEPEND="app-arch/cpio"
+DEPEND="${RDEPEND}"
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-asneeded.patch
+	"${FILESDIR}"/${P}-clang-cflags.patch
+)
+
+src_prepare() {
+	default
+
+	append-flags -pthread
+	# fix build with >=sys-devel/gcc-11, bug #787866
+	sed -i "/^CPPFLAGS/s/=/= -DNO_TLS/" Makefile
+}
+
+src_compile() {
+	emake \
+		PREFIX="${EPREFIX}/usr" \
+		AS="$(tc-getAS)" \
+		CXX="$(tc-getCXX)" \
+		CXXFLAGS="${CXXFLAGS}" \
+		LDFLAGS="${LDFLAGS}"
+}
+
+src_install() {
+	emake \
+		PREFIX="${EPREFIX}/usr" \
+		DESTDIR="${D}" \
+		install
+
+	if use examples; then
+		docinto examples
+		dodoc example/*
+	fi
+}